C_BusinessPartnerCustomerRole

@AbapCatalog.sqlViewName: 'CBUPACUSROLE'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'Consumption view for Customer BP Roles'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel: {
    semanticKey: ['BusinessPartner', 'BusinessPartnerRoleForEdit'],
    createEnabled,
    updateEnabled,
    deleteEnabled
}
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Role',
  typeNamePlural: 'Roles',
  title:  { label:'Role Description', value: '_BPRoleText.RoleText' }
  }

@VDM.viewType: #CONSUMPTION

define view C_BusinessPartnerCustomerRole
  as select from I_BusinessPartnerRoleTP as BusinessPartnerRole
  association [1..1] to C_BusinessPartner            as _BusinessPartner         on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [1..1] to C_BusinessPartnerCustomer    as _BusinessPartnerCustomer on  $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner
  association [0..1] to I_BusinessPartnerCustRoleTxt as _BPRoleText              on  $projection.BusinessPartnerRoleForEdit = _BPRoleText.Role
                                                                                 and _BPRoleText.Language                   = $session.system_language
  association [0..1] to I_BusinessPartnerRole        as _BPRoleValueHelp         on  $projection.BusinessPartnerRoleForEdit = _BPRoleValueHelp.BusinessPartnerRole

{
  key BusinessPartnerRole.BusinessPartner,
  key BusinessPartnerRole.BusinessPartnerRole,
      BusinessPartnerRole.BusinessPartnerForEdit,
      @ObjectModel: {
                text.association: '_BPRoleText'
                 }
      BusinessPartnerRole.BusinessPartnerRoleForEdit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerRole.ValidityStartDate,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerRole.ValidityEndDate,
      
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartnerCustomer,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartner,
      _BPRoleText,
      _BPRoleValueHelp // used for value help for multiple search on role selection field

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERROLETP"
],
"ASSOCIATED":
[
"C_BUSINESSPARTNER",
"C_BUSINESSPARTNERCUSTOMER",
"I_BUSINESSPARTNERCUSTROLETXT",
"I_BUSINESSPARTNERROLE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/