C_BusinessPartnerRole

@AbapCatalog.sqlViewName: 'CBUPAROLE'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Consumption view for Business Partner Role'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel: {
    semanticKey: ['BusinessPartner', 'BusinessPartnerRoleForEdit'],
    createEnabled,
    updateEnabled,
    deleteEnabled
}
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Role',
  typeNamePlural: 'Roles',
  title:  { label:'Role Description', value: '_BPRoleText.RoleText' }
  }

@VDM.viewType: #CONSUMPTION

define view C_BusinessPartnerRole
  as select from I_BusinessPartnerRoleTP as BusinessPartnerRole
  association [1..1] to C_BusinessPartner         as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_BusinessPartnerRole     as _BPRoleValueHelp on  $projection.BusinessPartnerRoleForEdit = _BPRoleValueHelp.BusinessPartnerRole
  association [0..1] to I_BusinessPartnerRoleText as _BPRoleText      on  $projection.BusinessPartnerRoleForEdit = _BPRoleText.BusinessPartnerRole
                                                                      and _BPRoleText.Language                   = $session.system_language

{
  key BusinessPartnerRole.BusinessPartner,
  key BusinessPartnerRole.BusinessPartnerRole,
      BusinessPartnerRole.BusinessPartnerForEdit,
      @ObjectModel: {
                text.association: '_BPRoleText'
                 }
      BusinessPartnerRole.BusinessPartnerRoleForEdit,
      @EndUserText.label: 'Role Validity Start Date'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerRole.ValidityStartDate,
      @EndUserText.label: 'Role Validity End Date'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerRole.ValidityEndDate,
      
      BusinessPartnerRole.RoleCategory,

      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartner,
      _BPRoleValueHelp, // used for value help for multiple search on role selection field 

      _BPRoleText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERROLETP"
],
"ASSOCIATED":
[
"C_BUSINESSPARTNER",
"I_BUSINESSPARTNERROLE",
"I_BUSINESSPARTNERROLETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/