I_BANKACCOUNT

@AbapCatalog.sqlViewName: 'IFIBANKACCOUNT'
@AccessControl.authorizationCheck: #CHECK
@Analytics: { dataCategory: #DIMENSION }
@VDM.viewType: #BASIC
@EndUserText.label: 'Bank Account'
@ObjectModel: { supportedCapabilities:
[ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY ],
 modelingPattern: #ANALYTICAL_DIMENSION,
 representativeKey: 'BankAccountInternalID'}
@ObjectModel.usageType: {
dataClass: #MASTER,
sizeCategory: #M,
serviceQuality: #C }
@Metadata.allowExtensions:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.privilegedAssociations:  [ '_Text' ]
@AbapCatalog.preserveKey:true
@Search.searchable: true

define view I_BankAccount
  as select from I_BankAccountBasicData
  //inner join I_CompanyCode on CompanyCode = I_CompanyCode.CompanyCode

  association [0..1] to I_Bank_2                   as _Bank                     on  $projection.BankCountry = _Bank.BankCountry
                                                                                and $projection.Bank        = _Bank.BankInternalID
  association [0..1] to I_CompanyCode              as _CompanyCode              on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..*] to I_ProfitCenter             as _ProfitCenter             on  $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                                                and $projection.ControllingArea = _ProfitCenter.ControllingArea
  association [0..1] to I_ControllingArea          as _ControllingArea          on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_BusinessArea             as _BusinessArea             on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_Segment                  as _Segment                  on  $projection.Segment = _Segment.Segment
  association [0..*] to I_BankAccountText          as _Text                     on  $projection.BankAccountInternalID = _Text.BankAccountInternalID
  //                                                                                and _Text.Language                    = $session.system_language

  association [0..1] to I_BankAccountCurrency      as _BankAccountCurrency      on  $projection.BankAccountInternalID = _BankAccountCurrency.BankAccountInternalID
  association [0..*] to I_BankAccountHierarchyNode as _BankAccountHierarchyNode on  $projection.BankAccountInternalID = _BankAccountHierarchyNode.BankAccountInternalID
{
       -- @ObjectModel.hierarchy.association: '_BankAccountHierarchyNode'
       @ObjectModel.text.association: '_Text'
  key  BankAccountInternalID,
       @ObjectModel.foreignKey.association: '_BankCountry'
       BankCountry,
       //--[ GENERATED:012:E6ExH29r7kY4hHBW6NEXPW

       @Consumption.valueHelpDefinition: [
         { entity:  { name:    'I_BankStdVH',
                      element: 'BankInternalID' },
           additionalBinding: [{ localElement: 'BankCountry',
                                 element: 'BankCountry' }]
         }]
       // ]--GENERATED

       @ObjectModel.foreignKey.association: '_Bank'
       Bank,
       BankAccountNumber,
       //       _Text.BankAccountDescription as BankAccountDescription,

       BankAccountType,
       BankAccountContractType,
       ValidityStartDate,
       ValidityEndDate,
       //    valid_from           as BankAccountOpeningDate,   // Global Field is not verified by CASH team

       //    valid_to             as BankAccountClosingDate,   // Global Field is not verified by CASH team

       IBAN,
       BankAccountStatus,
       //--[ GENERATED:012:E6ExH29r7kY4hHBW6NEXPW

       @Consumption.valueHelpDefinition: [
         { entity:  { name:    'I_CompanyCodeStdVH',
                      element: 'CompanyCode' }
         }]
       // ]--GENERATED

       @ObjectModel.foreignKey.association: '_CompanyCode' //Inserted by VDM CDS Suite Plugin

       CompanyCode,
       _CompanyCode.Country         as Country,
       //    @ObjectModel.foreignKey.association: '_ProfitCenter' //Inserted by VDM CDS Suite Plugin

       //--[ GENERATED:012:E6ExH29r7kY4hHBW6NEXPW

       @Consumption.valueHelpDefinition: [
         { entity:  { name:    'I_ProfitCenterStdVH',
                      element: 'ProfitCenter' },
           additionalBinding: [{ localElement: 'ControllingArea',
                                 element: 'ControllingArea' }]
         }]
       // ]--GENERATED

       @ObjectModel.foreignKey.association: '_ProfitCenter' //Inserted by VDM CDS Suite Plugin

       ProfitCenter,
       //--[ GENERATED:012:E6ExH29r7kY4hHBW6NEXPW

       @Consumption.valueHelpDefinition: [
         { entity:  { name:    'I_BusinessAreaStdVH',
                      element: 'BusinessArea' }
         }]
       // ]--GENERATED

       @ObjectModel.foreignKey.association: '_BusinessArea' //Inserted by VDM CDS Suite Plugin

       BusinessArea,
       //--[ GENERATED:012:E6ExH29r7kY4hHBW6NEXPW

       @Consumption.valueHelpDefinition: [
         { entity:  { name:    'I_SegmentStdVH',
                      element: 'Segment' }
         }]
       // ]--GENERATED

       @ObjectModel.foreignKey.association: '_Segment' //Inserted by VDM CDS Suite Plugin

       Segment,
       BankAccountHolderName,
       BankContactPerson,
       BankRelationshipManager,
       CompanyContactPerson,
       BankAccountSupervisor,
       CreatedByUser,
       OpenedByUser,
       LastChangedByUser,
       ReviewedByUser,
       ClosedByUser,
       IsMarkedForDeletion,
       DomesticCutOffTime,
       CrossBorderCutOffTime,
       PlannedClosingDate, // Global Field is not verified by CASH team

       CreationDate,
       CreationTime,
       OpenedDate, // Global Field is not verified by CASH team

       OpenedTime, // Global Field is not verified by CASH team

       LastChangeDate,
       LastChangeTime,
       ClosedDate, // Global Field is not verified by CASH team

       ClosedTime, // Global Field is not verified by CASH team

       BankControlKey,
       IBANValidityStartDate,
       //    @ObjectModel.foreignKey.association: '_ControllingArea' //Inserted by VDM CDS Suite Plugin

       //I_CompanyCode.ControllingArea,

       //   TransactionCode,

       PaymentTransactionTypeGroup,
       BankAccountCurrency,
       LeadingCashPoolID,
       ParticipantCashPoolID,

       MaxTargetAmount,

       MinTransferAmount,
       LeadingPaymentMethod,
       ParticipantPaymentMethod,
       PaymentServiceProvider,
       CashToleranceGroup,
       IntradayIsReconciled,
       TreasuryFinancialObject,
       //--[ GENERATED:012:E6ExH29r7kY4hHBW6NEXPW

       @Consumption.valueHelpDefinition: [
         { entity:  { name:    'I_ControllingArea',
                      element: 'ControllingArea' }
         }]
       // ]--GENERATED

       @ObjectModel.foreignKey.association: '_ControllingArea'
       _CompanyCode.ControllingArea as ControllingArea,
       BankStatementCheckTime,
       BankStatementImportMethod,
       IntraDayBankStateImportMethod,
       BankStatementImportChannel,
       IsUploadOfIntraDayStatement,
       EndOfDayIsReconciled,
       IHBAccountHolder,
       _Bank,
       _CompanyCode,
       _ProfitCenter,
       _BusinessArea,
       _Segment,
       _BankCountry,
       _ControllingArea,
       _Text,
       _BankAccountCurrency,
       _BankAccountHierarchyNode,
       I_BankAccountBasicData._BankAccountType
}  where BankAccountStatus <> '28'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANKACCOUNTBASICDATA",
"I_COMPANYCODE"
],
"ASSOCIATED":
[
"I_BANKACCOUNTCURRENCY",
"I_BANKACCOUNTHIERARCHYNODE",
"I_BANKACCOUNTTEXT",
"I_BANKACCOUNTTYPE",
"I_BANK_2",
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COUNTRY",
"I_PROFITCENTER",
"I_SEGMENT"
],
"BASE":
[
"I_BANKACCOUNTBASICDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/