I_BankAccountAnalysisCube

@AbapCatalog.sqlViewName: 'IFIBKACCTANLYSC'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #D
@Metadata.ignorePropagatedAnnotations:true
@Metadata.allowExtensions:true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #CUBE
@Analytics.internalName:#LOCAL
@Analytics.dataExtraction.enabled: true
@EndUserText.label: 'Bank Account Analysis - Cube'
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_PROVIDER,
                                      #EXTRACTION_DATA_SOURCE ]
define view I_BankAccountAnalysisCube
  as select from I_BankAccount
  association [0..1] to I_CompanyCode              as _CompanyCode   on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Bank                     as _Bank          on  $projection.Bank        = _Bank.BankInternalID
                                                                     and $projection.BankCountry = _Bank.BankCountry
  association [0..1] to I_Country                  as _Country       on  $projection.BankCountry = _Country.Country
  association [0..1] to I_BankRating               as _BankRating    on  $projection.Bank        = _BankRating.Bank
                                                                     and $projection.BankCountry = _BankRating.BankCountry
  association [0..1] to I_BankHierBankGroupMapping as _BankHierarchy on  $projection.BankAccountInternalID = _BankHierarchy.BankAccountInternalID
  association [0..1] to I_BusinessPartner          as _BankGroup     on  $projection.BankGroup = _BankGroup.BusinessPartner
{
  key BankAccountInternalID,
      @ObjectModel.foreignKey.association: '_Bank'
      Bank,
      @ObjectModel.foreignKey.association: '_Country'
      BankCountry,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode,
      @ObjectModel.foreignKey.association: '_BankGroup'
      cast( _BankHierarchy.BankGroup as fclm_bank_group preserving type )             as BankGroup,
      @ObjectModel.foreignKey.association: '_BPCreditWorthinessRating'
      _BankRating.CreditRating,
      cast(_BankRating.BusinessPartnerNumber as fclm_bank_in_bnkgrp preserving type ) as BankInBankGroup,
      @DefaultAggregation: #SUM
      cast( 1 as farp_bnk_account_count )                                             as NumberOfBankAccounts,
      _CompanyCode,
      _Bank,
      _Country,
      _BankRating._BPCreditWorthinessRating,
      _BankHierarchy,
      _BankGroup

}
where
     BankAccountStatus = '02'
  or BankAccountStatus = '10'
  or BankAccountStatus = '09';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANKACCOUNT",
"I_BANKHIERBANKGROUPMAPPING",
"I_BANKRATING"
],
"ASSOCIATED":
[
"I_BANK",
"I_BANKHIERBANKGROUPMAPPING",
"I_BANKRATING",
"I_BPCREDITWORTHINESSRATING",
"I_BUSINESSPARTNER",
"I_COMPANYCODE",
"I_COUNTRY"
],
"BASE":
[
"I_BANKRATING"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/