I_CashPosition

@EndUserText.label: 'Cash Position'
@Analytics: { dataCategory: #CUBE, dataExtraction.enabled: true }
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'ICASHPOSITION'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.ignorePropogatedAnnotations: true
@Metadata.allowExtensions: true
define view I_CashPosition
  with parameters
    P_StartDate : vdm_v_start_date,
    P_KeyDate   : sydate
  as select from P_CashPosition( P_StartDate: $parameters.P_StartDate, P_KeyDate: $parameters.P_KeyDate) as pos
  --inner join I_BankAccount as bam
  --on pos.BankAccountInternalID = bam.BankAccountInternalID

  association [1..1] to I_CompanyCode        as _CompanyCode on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_BankAccount        as _BankAccount on  $projection.BankAccountInternalID = _BankAccount.BankAccountInternalID
  association [0..1] to I_Currency           as _Currency    on  $projection.Currency = _Currency.Currency
  association [0..1] to I_Bank               as _Bank        on  $projection.Bank        = _Bank.BankInternalID
                                                             and $projection.BankCountry = _Bank.BankCountry
  association [0..1] to I_Country            as _Country     on  $projection.BankCountry = _Country.Country
  association [0..1] to I_BankAccountWithBGN as _BankGroup   on  $projection.BankAccountInternalID = _BankGroup.BankAccountInternalID
  association [0..1] to I_CertaintyLevelText as _Text        on  $projection.CertaintyLevel = _Text.CertaintyLevel
                                                             and _Text.Language = $session.system_language
  
{
      @ObjectModel.foreignKey.association: '_CompanyCode' //Inserted by VDM CDS Suite Plugin

  key pos.CompanyCode,
  --key pos.TransactionDate,
      @ObjectModel.foreignKey.association: '_BankAccount'
  key pos.BankAccountInternalID,     
  key pos.CertaintyLevel,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_Currency' //Inserted by VDM CDS Suite Plugin

  key pos.Currency,
  --key pos.HouseBank,
  --key pos.HouseBankAccount,
      @ObjectModel.foreignKey.association: '_Bank'
      pos.Bank,
      @ObjectModel.foreignKey.association: '_Country'
      pos.BankCountry,
      pos.BankAccount,
      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      cast(pos.Amount as fclm_amount_bnkcrcy) as AmountInBankAccountCurrency,

      /* Associations */
      _CompanyCode,
      _BankAccount,
      _Currency,
      _Bank,
      _Country,
      _BankGroup,
      _Text
}  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_CASHPOSITION"
],
"ASSOCIATED":
[
"I_BANK",
"I_BANKACCOUNT",
"I_BANKACCOUNTWITHBGN",
"I_CERTAINTYLEVELTEXT",
"I_COMPANYCODE",
"I_COUNTRY",
"I_CURRENCY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/