I_BOOMATERIALASSGMTCHANGESTATE
Change State of Material Assgmt. to BOO
I_BOOMATERIALASSGMTCHANGESTATE is a CDS View in S/4HANA. Change State of Material Assgmt. to BOO. It contains 23 fields. 10 CDS views read from this table.
CDS Views using this table (10)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_BOOPlngBOMAssignment | view | from | BASIC | PBOM assigned to Planning Routing |
| I_CapEvalByAreaOfRespy | view | inner | COMPOSITE | Work Center By Area Of Responsibility |
| I_EvaltCapWrkCtrGrpAreaOfRespy | view_entity | inner | COMPOSITE | Work Center Group Area of Responsibility |
| I_InspPlnMatlAssgmtVersion | view | from | BASIC | Version of Plan-Material assignment |
| I_InspPlnMatlAssgmtVersion_2 | view_entity | from | BASIC | Version of Material Assgmt in Insp Plan |
| I_MfgBOOMaterialAssgmtChgSt | view | from | BASIC | Change State of Material Assgmt to Manufacturing BOO |
| I_ProdnVersTaskListVH | view | left_outer | BASIC | Task List |
| I_SchedProdnWrkCtrAreaOfRespy | view | inner | COMPOSITE | Work Centers By Area of Responsibilty |
| I_WrkCtrCapByAreaOfRespy | view | inner | COMPOSITE | Work Center By Area Of Responsibility |
| P_WrkCtrMntrAlternateWrkCtr | view | inner | CONSUMPTION |
Fields (23)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | BillOfOperationsGroup | BillOfOperationsGroup,InspectionPlanGroup | 3 |
| KEY | BillOfOperationsType | BillOfOperationsType | 3 |
| KEY | BillOfOperationsVariant | BillOfOperationsVariant,InspectionPlan | 3 |
| KEY | BOOMatlInternalVersionCounter | BOOMatlInternalVersionCounter,InspPlanMatlAssgmtIntVersion | 2 |
| KEY | BOOToMaterialInternalID | BOOToMaterialInternalID,InspPlanMatlAssignment | 3 |
| KEY | Material | Material,Product | 4 |
| KEY | Plant | Plant | 4 |
| BOOSearchText | BOOSearchText | 2 | |
| ChangeNumber | ChangeNumber | 3 | |
| CreatedByUser | CreatedByUser | 2 | |
| CreationDate | CreationDate | 2 | |
| Customer | Customer | 2 | |
| IsDeleted | IsDeleted | 3 | |
| IsImplicitlyDeleted | IsImplicitlyDeleted | 2 | |
| LastChangeDate | LastChangeDate | 2 | |
| LastChangedByUser | LastChangedByUser | 2 | |
| SalesOrder | SalesOrder | 1 | |
| SalesOrderItem | SalesOrderItem | 1 | |
| Supplier | Supplier | 2 | |
| ValidityEndDate | ValidityEndDate | 3 | |
| ValidityStartDate | ValidityStartDate | 3 | |
| WBSElementInternalID | WBSElementInternalID | 1 | |
| WBSElementInternalID_2 | WBSElementInternalID_2 | 1 |
@AbapCatalog.sqlViewName: 'IBOOMATASSIGNCS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.representativeKey: 'BOOMatlInternalVersionCounter'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@VDM.viewType: #BASIC
@EndUserText.label: 'Change State of Material Assgmt. to BOO'
define view I_BOOMaterialAssgmtChangeState
as select from mapl
association [1..1] to I_BillOfOperationsType as _BillOfOperationsType on $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
association [1..1] to I_BillOfOperationsGroup as _BillOfOperationsGroup on $projection.BillOfOperationsType = _BillOfOperationsGroup.BillOfOperationsType
and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
association [1..1] to I_BillOfOperations as _BillOfOperations on $projection.BillOfOperationsType = _BillOfOperations.BillOfOperationsType
and $projection.BillOfOperationsGroup = _BillOfOperations.BillOfOperationsGroup
and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
association [1..1] to I_BOOMaterialAssignment as _BOOMaterialAssignment on $projection.Plant = _BOOMaterialAssignment.Plant
and $projection.Material = _BOOMaterialAssignment.Material
and $projection.BillOfOperationsType = _BOOMaterialAssignment.BillOfOperationsType
and $projection.BillOfOperationsGroup = _BOOMaterialAssignment.BillOfOperationsGroup
and $projection.BillOfOperationsVariant = _BOOMaterialAssignment.BillOfOperationsVariant
and $projection.BOOToMaterialInternalID = _BOOMaterialAssignment.BOOToMaterialInternalID
association [1..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [1..1] to I_Material as _Material on $projection.Material = _Material.Material
association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [0..1] to I_Customer as _Customer on $projection.Customer = _Customer.Customer
association [0..1] to I_SalesOrder as _SalesOrder on $projection.SalesOrder = _SalesOrder.SalesOrder
association [0..1] to I_SalesOrderItem as _SalesOrderItem on $projection.SalesOrder = _SalesOrderItem.SalesOrder
and $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
association [0..1] to I_WBSElementByInternalKey as _WBSElement on $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
association [0..1] to I_WBSElementBasicData as _WBSElementBasic on $projection.WBSElementInternalID_2 = _WBSElementBasic.WBSElementInternalID
association [0..1] to I_ChangeMaster as _ChangeMaster on $projection.ChangeNumber = _ChangeMaster.ChangeNumber
association [1..1] to I_MltplSpecObject as _MltplSpecObject on $projection.MultipleSpecificationObject = _MltplSpecObject.MultipleSpecificationObject
association [1..1] to I_MltplSpecObjectType as _MltplSpecObjectType on $projection.MultipleSpecificationObjType = _MltplSpecObjectType.MultipleSpecificationObjType
{
@ObjectModel.foreignKey.association: '_Material'
key mapl.matnr as Material,
@ObjectModel.foreignKey.association: '_Plant'
key mapl.werks as Plant,
@ObjectModel.foreignKey.association: '_BillOfOperationsType'
key mapl.plnty as BillOfOperationsType,
@ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
key mapl.plnnr as BillOfOperationsGroup,
@ObjectModel.foreignKey.association: '_BillOfOperations'
key mapl.plnal as BillOfOperationsVariant,
@ObjectModel.foreignKey.association: '_BOOMaterialAssignment'
key mapl.zkriz as BOOToMaterialInternalID,
key mapl.zaehl as BOOMatlInternalVersionCounter,
-- Validity
@Semantics.businessDate.from: true
mapl.datuv as ValidityStartDate,
@Semantics.businessDate.to: true
mapl.valid_to as ValidityEndDate,
-- Admin
@ObjectModel.foreignKey.association: '_ChangeMaster'
mapl.aennr as ChangeNumber,
@Semantics.systemDate.createdAt: true
mapl.andat as CreationDate,
@Semantics.user.createdBy: true
cast(mapl.annam as vdm_createdbyuserid preserving type) as CreatedByUser,
@Semantics.systemDate.lastChangedAt: true
mapl.aedat as LastChangeDate,
@Semantics.user.lastChangedBy: true
cast(mapl.aenam as vdm_lastchangedbyuserid preserving type) as LastChangedByUser,
mapl.loekz as IsDeleted,
mapl.loekz_inherited as IsImplicitlyDeleted,
@ObjectModel.foreignKey.association: '_Supplier'
mapl.lifnr as Supplier,
@ObjectModel.foreignKey.association: '_Customer'
mapl.kunr as Customer,
@ObjectModel.foreignKey.association: '_SalesOrder'
mapl.vbeln as SalesOrder,
@ObjectModel.foreignKey.association: '_SalesOrderItem'
mapl.posnr as SalesOrderItem,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'WBSElementInternalID_2'
@ObjectModel.foreignKey.association: '_WBSElement'
cast(mapl.pspnr as pph_pspel preserving type) as WBSElementInternalID, // with exit ABPSP
@ObjectModel.foreignKey.association: '_WBSElementBasic'
cast(mapl.pspnr as ps_s4_pspnr preserving type) as WBSElementInternalID_2, // w/o conv. exit
suchfeld as BOOSearchText,
@ObjectModel.foreignKey.association: '_MltplSpecObject'
ms_object as MultipleSpecificationObject,
@ObjectModel.foreignKey.association: '_MltplSpecObjectType'
ms_objtype as MultipleSpecificationObjType,
mapl.versn as BillOfOperationsVersion,
-- Associations
_Material,
_Plant,
_BillOfOperationsType,
_BillOfOperationsGroup,
_BillOfOperations,
_BOOMaterialAssignment,
_Supplier,
_Customer,
_SalesOrder,
_SalesOrderItem,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: '_WBSElementBasic'
_WBSElement,
_WBSElementBasic,
_MltplSpecObject,
_MltplSpecObjectType,
_ChangeMaster
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MAPL"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_BOOMATERIALASSIGNMENT",
"I_CHANGEMASTER",
"I_CUSTOMER",
"I_MATERIAL",
"I_MLTPLSPECOBJECT",
"I_MLTPLSPECOBJECTTYPE",
"I_PLANT",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_SUPPLIER",
"I_WBSELEMENTBASICDATA",
"I_WBSELEMENTBYINTERNALKEY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/