I_InspPlnMatlAssgmtVersion

@AbapCatalog.sqlViewName: 'IINSPPLMASSGV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Version of Plan-Material assignment'
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@ObjectModel.representativeKey: 'InspPlanMatlAssgmtIntVersion'
define view I_InspPlnMatlAssgmtVersion
  as select from I_BOOMaterialAssgmtChangeState
  association [1..1] to I_InspectionPlan        as _InspectionPlan        on  $projection.InspectionPlanGroup = _InspectionPlan.InspectionPlanGroup
                                                                          and $projection.InspectionPlan      = _InspectionPlan.InspectionPlan
  /*+[hideWarning] { "IDS" :  [ "CARDINALITY_CHECK" ] } */
  association [1..1] to I_InspectionPlanVersion as _InspectionPlanVersion on  $projection.InspectionPlanGroup =  _InspectionPlanVersion.InspectionPlanGroup
                                                                          and $projection.InspectionPlan      =  _InspectionPlanVersion.InspectionPlan
                                                                          and $projection.ValidityStartDate   >= _InspectionPlanVersion.ValidityStartDate
                                                                          and $projection.ValidityStartDate   <= _InspectionPlanVersion.ValidityEndDate
  association [1..1] to I_BillOfOperationsGroup as _BillOfOperationsGroup on  $projection.BillOfOperationsType = _BillOfOperationsGroup.BillOfOperationsType
                                                                          and $projection.InspectionPlanGroup  = _BillOfOperationsGroup.BillOfOperationsGroup
  association [1..1] to I_InspPlnMatlAssignment as _InspPlnMatlAssignment on  $projection.Material               = _InspPlnMatlAssignment.Material
                                                                          and $projection.Plant                  = _InspPlnMatlAssignment.Plant
                                                                          and $projection.InspectionPlanGroup    = _InspPlnMatlAssignment.InspectionPlanGroup
                                                                          and $projection.InspectionPlan         = _InspPlnMatlAssignment.InspectionPlan
                                                                          and $projection.InspPlanMatlAssignment = _InspPlnMatlAssignment.InspPlanMatlAssignment
  association [1..1] to I_MltplSpecObject       as _MltplSpecObject       on  $projection.MultipleSpecificationObject = _MltplSpecObject.MultipleSpecificationObject
  association [1..1] to I_MltplSpecObjectType   as _MltplSpecObjectType   on  $projection.MultipleSpecificationObjType = _MltplSpecObjectType.MultipleSpecificationObjType
{
  key Material,
  key Plant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key BillOfOperationsGroup         as InspectionPlanGroup,
      @ObjectModel.foreignKey.association: '_InspectionPlan'
  key BillOfOperationsVariant       as InspectionPlan,
      @ObjectModel.foreignKey.association: '_InspPlnMatlAssignment'
  key BOOToMaterialInternalID       as InspPlanMatlAssignment,
  key BOOMatlInternalVersionCounter as InspPlanMatlAssgmtIntVersion,
      BillOfOperationsType,
      ValidityStartDate,
      ValidityEndDate,
      ChangeNumber,
      CreationDate,
      CreatedByUser,
      LastChangeDate,
      LastChangedByUser,
      IsDeleted,
      IsImplicitlyDeleted,
      Supplier,
      Customer,
      BOOSearchText,
      @ObjectModel.foreignKey.association: '_MltplSpecObject'
      MultipleSpecificationObject,
      @ObjectModel.foreignKey.association: '_MltplSpecObjectType'
      MultipleSpecificationObjType,
      _InspPlnMatlAssignment,
      _InspectionPlan,
      _InspectionPlanVersion,
      _Material,
      _Plant,
      _Supplier,
      _Customer,
      _MltplSpecObject,
      _MltplSpecObjectType,
      _ChangeMaster,
      _BillOfOperationsGroup
}
where
  BillOfOperationsType = 'Q'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BOOMATERIALASSGMTCHANGESTATE"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_CHANGEMASTER",
"I_CUSTOMER",
"I_INSPECTIONPLAN",
"I_INSPECTIONPLANVERSION",
"I_INSPPLNMATLASSIGNMENT",
"I_MATERIAL",
"I_MLTPLSPECOBJECT",
"I_MLTPLSPECOBJECTTYPE",
"I_PLANT",
"I_SUPPLIER"
],
"BASE":
[
"I_BOOMATERIALASSGMTCHANGESTATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/