I_InspPlnMatlAssgmtVersion_2

@EndUserText.label: 'Version of Material Assgmt in Insp Plan'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
    
// This CDS is similar to I_InspPlnMatlAssgmtVersion but C1 released

define view entity I_InspPlnMatlAssgmtVersion_2 
  as select from I_BOOMaterialAssgmtChangeState

  association [1..1] to I_BillOfOperationsType  as _BillOfOperationsType  on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
     
  association [1..1] to I_BillOfOperationsGroup as _BillOfOperationsGroup on  $projection.BillOfOperationsType = _BillOfOperationsGroup.BillOfOperationsType
                                                                          and $projection.InspectionPlanGroup  = _BillOfOperationsGroup.BillOfOperationsGroup
  /*+[hideWarning] { "IDS" :  [ "CARDINALITY_CHECK" ] } */
  association [1..1] to I_InspectionPlanVersion as _InspectionPlanVersion on  $projection.InspectionPlanGroup  =  _InspectionPlanVersion.InspectionPlanGroup
                                                                          and $projection.InspectionPlan       =  _InspectionPlanVersion.InspectionPlan
                                                                          and $projection.ValidityStartDate   >= _InspectionPlanVersion.ValidityStartDate
                                                                          and $projection.ValidityStartDate   <= _InspectionPlanVersion.ValidityEndDate
  association [0..1] to I_Supplier              as _Supplier              on  $projection.Supplier             = _Supplier.Supplier
  association [0..1] to I_Customer              as _Customer              on  $projection.Customer             = _Customer.Customer
{
  key I_BOOMaterialAssgmtChangeState.Material,
  key I_BOOMaterialAssgmtChangeState.Plant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key I_BOOMaterialAssgmtChangeState.BillOfOperationsGroup         as InspectionPlanGroup,
  key I_BOOMaterialAssgmtChangeState.BillOfOperationsVariant       as InspectionPlan,
  key I_BOOMaterialAssgmtChangeState.BOOToMaterialInternalID       as InspPlanMatlAssignment,
  key I_BOOMaterialAssgmtChangeState.BOOMatlInternalVersionCounter as InspPlanMatlAssgmtIntVersion,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      I_BOOMaterialAssgmtChangeState.BillOfOperationsType,
      I_BOOMaterialAssgmtChangeState.ValidityStartDate,
      I_BOOMaterialAssgmtChangeState.ValidityEndDate,
      I_BOOMaterialAssgmtChangeState.ChangeNumber,   
      I_BOOMaterialAssgmtChangeState.CreationDate,
      I_BOOMaterialAssgmtChangeState.CreatedByUser,
      I_BOOMaterialAssgmtChangeState.LastChangeDate,
      I_BOOMaterialAssgmtChangeState.LastChangedByUser,
      I_BOOMaterialAssgmtChangeState.IsDeleted, 
      I_BOOMaterialAssgmtChangeState.IsImplicitlyDeleted,
      I_BOOMaterialAssgmtChangeState.Supplier, 
      I_BOOMaterialAssgmtChangeState.Customer,
      I_BOOMaterialAssgmtChangeState.BOOSearchText,
      
//     Associations

      _BillOfOperationsGroup,
      _BillOfOperationsType,
      _InspectionPlanVersion,
      _Supplier,
      _Customer
}
where
  BillOfOperationsType = 'Q'

  
  
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BOOMATERIALASSGMTCHANGESTATE"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_CUSTOMER",
"I_INSPECTIONPLANVERSION",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/