R_TrdgDocItemBasic

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
   }

@ObjectModel: {
   compositionRoot: false,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   }

}
@ObjectModel.semanticKey: ['TradingDocument', 'TradingDocumentItem']
@Metadata.allowExtensions: false
@EndUserText.label: 'Trading Document Item'
@Metadata.ignorePropagatedAnnotations: true

/* Basic Layer */
define view entity R_TrdgDocItemBasic
  as select from wbhi

  //Association

  association [0..1] to R_TrdgDocItemCategory      as _TrdgDocItemCategory        on  $projection.TrdgDocItemCategory = _TrdgDocItemCategory.TrdgDocItemCategory
  association [0..1] to I_Product                  as _Product                    on  $projection.Product = _Product.Product
  association [0..1] to I_Plant                    as _Plant                      on  $projection.Plant = _Plant.Plant
  association [0..1] to I_StorageLocation          as _StorageLocation            on  $projection.Plant           = _StorageLocation.Plant
                                                                                  and $projection.StorageLocation = _StorageLocation.StorageLocation
  association [0..1] to I_Batch                    as _Batch                      on  $projection.Plant   = _Batch.Plant
                                                                                  and $projection.Product = _Batch.Material
                                                                                  and $projection.Batch   = _Batch.Batch
  association [0..1] to I_UnitOfMeasure            as _TrdgDocPurgQuantityUnit    on  $projection.TrdgDocPurgQuantityUnit = _TrdgDocPurgQuantityUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure            as _TrdgDocSlsQuantityUnit     on  $projection.TrdgDocSlsQuantityUnit = _TrdgDocSlsQuantityUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure            as _TrdgDocSlsWeightUnit       on  $projection.TrdgDocSlsWeightUnit = _TrdgDocSlsWeightUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure            as _TrdgDocSlsVolumeUnit       on  $projection.TrdgDocSlsVolumeUnit = _TrdgDocSlsVolumeUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure            as _BaseUnit                   on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure
  association [0..1] to I_Division                 as _Division                   on  $projection.OrganizationDivision = _Division.Division
  association [0..1] to I_BusinessArea             as _BusinessArea               on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_User                     as _CreatedByUser              on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_MaterialGroup            as _ProductGroup               on  $projection.ProductGroup = _ProductGroup.MaterialGroup
  association [0..1] to I_SalesDocumentRjcnReason  as _SalesDocumentRjcnReason    on  $projection.SalesDocumentRjcnReason = _SalesDocumentRjcnReason.SalesDocumentRjcnReason
  association [0..1] to I_ProductHierarchyNode     as _ProductHierarchyNode       on  $projection.ProductHierarchyNode = _ProductHierarchyNode.ProductHierarchyNode
  association [0..1] to I_SalesSpcfcProductGroup1  as _SalesSpcfcProductGroup1    on  $projection.SalesSpcfcProductGroup1 = _SalesSpcfcProductGroup1.SalesSpcfcProductGroup1
  association [0..1] to I_SalesSpcfcProductGroup2  as _SalesSpcfcProductGroup2    on  $projection.SalesSpcfcProductGroup2 = _SalesSpcfcProductGroup2.SalesSpcfcProductGroup2
  association [0..1] to I_SalesSpcfcProductGroup3  as _SalesSpcfcProductGroup3    on  $projection.SalesSpcfcProductGroup3 = _SalesSpcfcProductGroup3.SalesSpcfcProductGroup3
  association [0..1] to I_SalesSpcfcProductGroup4  as _SalesSpcfcProductGroup4    on  $projection.SalesSpcfcProductGroup4 = _SalesSpcfcProductGroup4.SalesSpcfcProductGroup4
  association [0..1] to I_SalesSpcfcProductGroup5  as _SalesSpcfcProductGroup5    on  $projection.SalesSpcfcProductGroup5 = _SalesSpcfcProductGroup5.SalesSpcfcProductGroup5
  association [0..1] to I_BillingBlockReason       as _ItemBillingBlockReason     on  $projection.ItemBillingBlockReason = _ItemBillingBlockReason.BillingBlockReason
  association [0..1] to I_ShippingPoint            as _TrdgDocSlsShippingPoint    on  $projection.TrdgDocSlsShippingPoint = _TrdgDocSlsShippingPoint.ShippingPoint
  association [0..1] to I_Route                    as _TradingDocumentSalesRoute  on  $projection.TradingDocumentSalesRoute = _TradingDocumentSalesRoute.Route
  association [0..1] to I_ShippingCondition        as _TrdgDocPurgShipgCondition  on  $projection.TrdgDocPurgShippingCondition = _TrdgDocPurgShipgCondition.ShippingCondition
  association [0..1] to I_ShippingPoint            as _TrdgDocPurgShippingPoint   on  $projection.TrdgDocPurgShippingPoint = _TrdgDocPurgShippingPoint.ShippingPoint
  association [0..1] to I_PurgDocumentItemCategory as _PurgDocumentItemCategory   on  $projection.PurchasingDocumentItemCategory = _PurgDocumentItemCategory.PurchasingDocumentItemCategory
  association [0..1] to R_TrdgDocHeaderBasic       as _TrdgDocRefDocument         on  $projection.TrdgDocRefDocument = _TrdgDocRefDocument.TradingDocument
  association [0..1] to R_TrdgDocHeaderBasic       as _TrdgDocAddlRefDocument     on  $projection.TrdgDocAddlRefDocument = _TrdgDocAddlRefDocument.TradingDocument
  association [0..1] to R_TrdgDocItemBasic         as _TrdgDocRefDocItem          on  $projection.TrdgDocRefDocument = _TrdgDocRefDocItem.TradingDocument
                                                                                  and $projection.TrdgDocRefDocItem  = _TrdgDocRefDocItem.TradingDocumentItem
  association [0..1] to R_TrdgDocItemBasic         as _TrdgDocAddlRefDocItem      on  $projection.TrdgDocAddlRefDocument = _TrdgDocAddlRefDocItem.TradingDocument
                                                                                  and $projection.TrdgDocAddlRefDocItem  = _TrdgDocAddlRefDocItem.TradingDocumentItem
  association [0..1] to R_TrdgDocType              as _TrdgDocRefDocumentType     on  $projection.TrdgDocReferenceDocumentType = _TrdgDocRefDocumentType.TradingDocumentType
  association [0..1] to R_TrdgDocType              as _TrdgDocAddlRefDocumentType on  $projection.TrdgDocAddlRefDocumentType = _TrdgDocAddlRefDocumentType.TradingDocumentType
  association [0..1] to I_Product                  as _OriginallyRequestedProduct on  $projection.TrdgDocOriglReqdProd = _OriginallyRequestedProduct.Product
  association [0..1] to I_Currency                 as _TrdgDocPurgCurrency        on  $projection.TrdgDocPurgCurrency = _TrdgDocPurgCurrency.Currency

  association [0..1] to R_TrdgDocCndnCnsldtnCat    as _TrdgDocCndnCnsldtnCat      on  $projection.TrdgDocCndnCnsldtnCat = _TrdgDocCndnCnsldtnCat.TrdgDocCndnCnsldtnCat
  association [0..1] to R_TrdgDocIsHdggRlvt        as _TrdgDocIsHdggRlvt          on  $projection.TrdgDocHdggRlvt = _TrdgDocIsHdggRlvt.TrdgDocIsHdggRlvt
  association [0..1] to R_TrdgDocPrcDetnIsIncmplt  as _TrdgDocPrcDetnIsIncmplt    on  $projection.TrdgDocPrcDetnIsIncomplete = _TrdgDocPrcDetnIsIncmplt.TrdgDocPrcDetnIsIncomplete
  association [0..1] to R_TrdgDocItemBlockCode     as _TrdgDocItemBlockCode       on  $projection.TrdgDocItemBlockCode = _TrdgDocItemBlockCode.TrdgDocItemBlockCode
  association [0..1] to R_TrdgDocPurgRskRelevancy  as _TrdgDocPurgRskRelevancy    on  $projection.TrdgDocPurgRiskRelevancy = _TrdgDocPurgRskRelevancy.TrdgDocPurgRiskRelevancy
  association [0..1] to R_TrdgDocSettlementMode    as _TrdgDocSettlementMode      on  $projection.TrdgDocSettlementMode = _TrdgDocSettlementMode.TrdgDocSettlementMode
  association [0..1] to R_TrdgDocPrdcssrDocType    as _TrdgDocPrdcssrDocType      on  $projection.TrdgDocPrdcssrDocumentType = _TrdgDocPrdcssrDocType.TrdgDocPrdcssrDocumentType
  association [0..1] to R_TrdgDocIsComplete        as _TrdgDocItemIsComplete      on  $projection.TrdgDocItemIsComplete = _TrdgDocItemIsComplete.TrdgDocIsComplete
  association [0..1] to I_ControllingArea          as _ControllingArea            on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_CostCenter               as _CostCenter                 on  $projection.CostCenter      =  _CostCenter.CostCenter
                                                                                  and $projection.ControllingArea =  _CostCenter.ControllingArea
                                                                                  and $projection.CreationDate    <= _CostCenter.ValidityEndDate




{
  key tkonn                                                            as TradingDocument,
  key tposn                                                            as TradingDocumentItem,
      @ObjectModel.foreignKey.association: '_TrdgDocItemCategory'
      hkpstp                                                           as TrdgDocItemCategory,
      @ObjectModel.foreignKey.association: '_Product'
      cast( matnr as wb2_product preserving type )                     as Product,
      arktx                                                            as TrdgDocItemText,
      @ObjectModel.foreignKey.association: '_ProductGroup'
      cast( matkl as wb2_product_group preserving type )               as ProductGroup,
      bwtar                                                            as TrdgDocReltdDocItmValnType,
      @ObjectModel.foreignKey.association: '_Plant'
      werks                                                            as Plant,
      @ObjectModel.foreignKey.association: '_StorageLocation'
      lgort                                                            as StorageLocation,
      @ObjectModel.foreignKey.association: '_Batch'
      charg                                                            as Batch,
      @ObjectModel.foreignKey.association: '_Division'
      spart                                                            as OrganizationDivision,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      gsber                                                            as BusinessArea,
      @Semantics.user.createdBy: true
      ernam                                                            as CreatedByUser,
      @Semantics.systemDate.createdAt: true
      erdat                                                            as CreationDate,
      cast( erzet as wb2_created_at preserving type )                  as CreationTime,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocPurgQuantityUnit'
      @DefaultAggregation: #NONE
      menge                                                            as TrdgDocPurgQuantity,
      @ObjectModel.foreignKey.association: '_TrdgDocPurgQuantityUnit'
      meins                                                            as TrdgDocPurgQuantityUnit,
      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'TrdgDocSlsQuantityUnit'
      kwmeng                                                           as TrdgDocSalesQuantity,
      @ObjectModel.foreignKey.association: '_TrdgDocSlsQuantityUnit'
      vrkme                                                            as TrdgDocSlsQuantityUnit,
      umvkz                                                            as TrdgDocSlsToBaseQtyNmrtr,
      cast( umvkn as wb2_sls_base_uom_dnmntr preserving type )         as TrdgDocSlsToBaseQtyDnmntr,
      @ObjectModel.foreignKey.association: '_BaseUnit'
      basis_meins                                                      as BaseUnit,
      umrez_mm                                                         as TrdgDocPurgToBaseQtyNmrtr,
      cast( umren_mm as wb2_purg_base_uom_dnmntr preserving type )     as TrdgDocPurgToBaseQtyDnmntr,
      cast( bpumz_mm as wb2_purg_to_ordrqty_nmrtr preserving type )    as TrdgDocPurgToOrdQtyNmrtr,
      cast( bpumn_mm as wb2_purg_to_ordrqty_dnmntr preserving type )   as TrdgDocPurgToOrdQtyDnmntr,
      cast( bpumz_sd as wb2_sls_to_ordrqty_nmrtr preserving type )     as TrdgDocSlsToOrdQtyNmrtr,
      cast( bpumn_sd as wb2_sls_to_ordrqty_dnmntr preserving type )    as TrdgDocSlsToOrdQtyDnmntr,
      waers_mm                                                         as TrdgDocPurgCurrency,
      sdwrs                                                            as TrdgDocSalesCurrency,
      @ObjectModel.foreignKey.association: '_TrdgDocSlsWeightUnit'
      gewei                                                            as TrdgDocSlsWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocSlsWeightUnit'
      cast( brgew as wb2_sls_gross_weight preserving type )            as TrdgDocSlsGrossWeight,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocSlsWeightUnit'
      cast( ntgew as wb2_sls_net_weight preserving type )              as TrdgDocSlsNetWeight,
      @ObjectModel.foreignKey.association: '_TrdgDocSlsVolumeUnit'
      voleh                                                            as TrdgDocSlsVolumeUnit,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocSlsVolumeUnit'
      cast( volum as wb2_sales_item_volume preserving type )           as TrdgDocSlsVolume,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocSlsWeightUnit'
      cast( brgew_mm as wb2_purg_gross_weight preserving type )        as TrdgDocPurgGrossWeight,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocSlsWeightUnit'
      cast( ntgew_mm as wb2_purg_net_weight preserving type )          as TrdgDocPurgNetWeight,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocSlsVolumeUnit'
      cast( volum_mm as wb2_purg_volume preserving type )              as TrdgDocPurgVolume,
      cast( kmein_sd as wb2_sls_price_unit preserving type )           as TrdgDocSlsPriceUnit,
      bprme_mm                                                         as TrdgDocPurgPriceUnit,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocPurgPriceUnit'
      peinh_mm                                                         as TrdgDocPurgNetPriceQuantity,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocSlsPriceUnit'
      cast( kpein_sd as wb2_sls_net_price_qty preserving type )        as TrdgDocSlsNetPriceQuantity,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      netpr_sd                                                         as TrdgDocSalesNetPriceAmount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      netpr_mm                                                         as TrdgDocPurgNetPriceAmount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      netwrt_sd                                                        as TrdgDocSlsItemNetAmount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      netwrt_mm                                                        as TrdgDocPurgItemNetAmount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( netwrt_in_sdwrs as wb2_sls_netwrt preserving type )        as TrdgDocSlsItmNetAmtInSlsCrcy,
      @Semantics.amount.currencyCode: 'TrdgDocPurgCurrency'
      netwrt_in_waers                                                  as TrdgDocPurgItmNetAmtInPOCrcy,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi1 as wb2_purg_subtotal1_amt preserving type )          as TrdgDocPurgSubtotal1Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi2 as wb2_purg_subtotal2_amt preserving type )          as TrdgDocPurgSubtotal2Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi3 as wb2_purg_subtotal3_amt preserving type )          as TrdgDocPurgSubtotal3Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi4 as wb2_purg_subtotal4_amt preserving type )          as TrdgDocPurgSubtotal4Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi5 as wb2_purg_subtotal5_amt preserving type )          as TrdgDocPurgSubtotal5Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi6 as wb2_purg_subtotal6_amt preserving type )          as TrdgDocPurgSubtotal6Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi1d as wb2_sls_subtotal1_amt preserving type )          as TrdgDocSlsSubtotal1Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi2d as wb2_sls_subtotal2_amt preserving type )          as TrdgDocSlsSubtotal2Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi3d as wb2_sls_subtotal3_amt preserving type )          as TrdgDocSlsSubtotal3Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi4d as wb2_sls_subtotal4_amt preserving type )          as TrdgDocSlsSubtotal4Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi5d as wb2_sls_subtotal5_amt preserving type )          as TrdgDocSlsSubtotal5Amount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( kzwi6d as wb2_sls_subtotal6_amt preserving type )          as TrdgDocSlsSubtotal6Amount,
      cast( uebtk_sd as wb2_sls_unlmtd_allwd preserving type )         as SlsUnlmtdOvrdelivIsAllwd,
      cast( uebto_sd as wb2_sls_ovrdeliv_tol preserving type )         as SlsOvrdelivTolLmtRatioInPct,
      untto_sd                                                         as SlsUndrdelivTolLmtRatioInPct,
      cast( uebtk_mm as wb2_purg_unlmtd_allwd preserving type )        as PurgUnlmtdOvrdelivIsAllwd,
      cast( uebto_mm as wb2_purg_ovrdeliv_tol preserving type )        as PurgOvrdelivTolLmtRatioInPct,
      cast( untto_mm as wb2_purg_undrdeliv_tol preserving type )       as PurgUndrdelivTolLmtRatioInPct,
      @ObjectModel.foreignKey.association: '_SalesDocumentRjcnReason'
      abgru                                                            as SalesDocumentRjcnReason,
      @ObjectModel.foreignKey.association: '_ProductHierarchyNode'
      prodh                                                            as ProductHierarchyNode,
      cast( kdmat as wb2_product_cust preserving type )                as ProductUsedByCustomer,
      cast( taxm1 as wb2_product_tax_classfctn_1 preserving type )     as ProductTaxClassification1,
      cast( taxm2 as wb2_product_tax_classfctn_2 preserving type )     as ProductTaxClassification2,
      cast( taxm3 as wb2_product_tax_classfctn_3 preserving type )     as ProductTaxClassification3,
      cast( taxm4 as wb2_product_tax_classfctn_4 preserving type )     as ProductTaxClassification4,
      cast( taxm5 as wb2_product_tax_classfctn_5 preserving type )     as ProductTaxClassification5,
      cast( taxm6 as wb2_product_tax_classfctn_6 preserving type )     as ProductTaxClassification6,
      cast( taxm7 as wb2_product_tax_classfctn_7 preserving type )     as ProductTaxClassification7,
      cast( taxm8 as wb2_product_tax_classfctn_8 preserving type )     as ProductTaxClassification8,
      cast( taxm9 as wb2_product_tax_classfctn_9 preserving type )     as ProductTaxClassification9,
      ean11                                                            as InternationalArticleNumber,
      prctr                                                            as ProfitCenter,
      @ObjectModel.foreignKey.association: '_CostCenter'
      kostl                                                            as CostCenter,
      @ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup1'
      cast( mvgr1 as wb2_sales_product_group1 preserving type )        as SalesSpcfcProductGroup1,
      @ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup2'
      cast( mvgr2 as wb2_sales_product_group2 preserving type )        as SalesSpcfcProductGroup2,
      @ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup3'
      cast( mvgr3 as wb2_sales_product_group3 preserving type )        as SalesSpcfcProductGroup3,
      @ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup4'
      cast( mvgr4 as wb2_sales_product_group4 preserving type )        as SalesSpcfcProductGroup4,
      @ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup5'
      cast( mvgr5 as wb2_sales_product_group5 preserving type )        as SalesSpcfcProductGroup5,
      @ObjectModel.foreignKey.association: '_ItemBillingBlockReason'
      faksp_sd                                                         as ItemBillingBlockReason,
      antlf_sd                                                         as MaxNmbrOfPartialDelivery,
      kztlf_sd                                                         as PartialDeliveryIsAllowed,
      @ObjectModel.foreignKey.association: '_TrdgDocSlsShippingPoint'
      cast( vstel_sd as wb2_sls_shipg_point preserving type )          as TrdgDocSlsShippingPoint,
      cast( route_mm as wb2_purg_route preserving type )               as TradingDocumentPurchasingRoute,
      @ObjectModel.foreignKey.association: '_TradingDocumentSalesRoute'
      cast( route_sd as wb2_route_sd preserving type )                 as TradingDocumentSalesRoute,
      @ObjectModel.foreignKey.association: '_TrdgDocPurgShipgCondition'
      cast( vsbed_mm as wb2_purg_shipg_cndn preserving type )          as TrdgDocPurgShippingCondition,
      @ObjectModel.foreignKey.association: '_TrdgDocPurgShippingPoint'
      cast( vstel_mm as wb2_purg_shipg_point preserving type )         as TrdgDocPurgShippingPoint,
      mwskz_mm                                                         as TrdgDocPurgTaxCode,
      bwtty_mm                                                         as ValuationCategory,
      @ObjectModel.foreignKey.association: '_PurgDocumentItemCategory'
      cast( pstyp_mm as wb2_purg_doc_itm_cat preserving type )         as PurchasingDocumentItemCategory,
      knttp_mm                                                         as AccountAssignmentCategory,
      lewed_mm                                                         as GoodsReceiptLatestCreationDate,
      cuobj_ch                                                         as BatchClassification,
      cast( wbhd_tposn as wb2_bus_data_item preserving type )          as TradingDocumentBusinessItem,
      @Semantics.booleanIndicator:true
      dummy_wbhi_incl_eew_ps                                           as TrdgDocItemIsExtended,
      loekz                                                            as TrdgDocItemIsDeleted,
      cast( portfolio as wb2_internal_portfolio_no preserving type )   as TrdgPortfolioInternalID,
      portfolio_date                                                   as TrdgDocItmPrtfloDetnDate,
      tkonn_from                                                       as TrdgDocRefDocument,
      tposn_from                                                       as TrdgDocRefDocItem,
      cast(tctyp_from  as wb2_ref_doc_type preserving type )           as TrdgDocReferenceDocumentType,
      tkonn_from_2                                                     as TrdgDocAddlRefDocument,
      tposn_from_2                                                     as TrdgDocAddlRefDocItem,
      cast( tctyp_from_2 as wb2_addl_ref_doc_type preserving type )    as TrdgDocAddlRefDocumentType,
      scenario                                                         as TrdgDocBusinessScenario,
      assoc_group                                                      as TrdgDocAssociationGroup,
      cast( idnlf as wb2_suplr_prod preserving type )                  as SupplierProductID,
      @ObjectModel.foreignKey.association: '_OriginallyRequestedProduct'
      cast( matwa   as wb2_reqd_product preserving type )              as TrdgDocOriglReqdProd,
      uepos                                                            as TradingDocumentHigherLevelItem,
      @ObjectModel.foreignKey.association: '_TrdgDocPrcDetnIsIncmplt'
      @Semantics.booleanIndicator:true
      wuvprs                                                           as TrdgDocPrcDetnIsIncomplete,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocPurgQuantityUnit'
      cast( kmpmg as wb2_purg_bom_itm_qty preserving type )            as TrdgDocPurgBOMItmQty,
      @Semantics.quantity.unitOfMeasure: 'TrdgDocSlsQuantityUnit'
      cast( kmpmg_sd as wb2_sls_bom_itm_qty preserving type )          as TrdgDocSlsBOMItmQty,
      fmeng                                                            as QuantityIsFixed,
      stdat                                                            as TrdgDocBOMKeyDate,
      stlty                                                            as BillOfMaterialCategory,

      stkey                                                            as BillOfMaterialVariantUsage,
      cast( pmatn as wb2_prcg_ref_product preserving type )            as TrdgDocPrcgRefProduct,
      cast( vkaus as wb2_prod_usage_ind preserving type )              as TrdgDocProdUsgeCat,

      @Semantics.amount.currencyCode: 'TrdgDocSalesCurrency'
      cast( effwr_sd as wb2_sls_itm_effctv_amt preserving type )       as TrdgDocSlsItmEffctvAmount,
      @Semantics.amount.currencyCode: 'TrdgDocPurgCurrency'
      cast( effwr_mm as wb2_purg_itm_effctv_amt preserving type )      as TrdgDocPurgItmEffctvAmount,
      cast( sktof_sd as wb2_sls_cash_disc preserving type )            as TrdgDocSlsIsCshDiscGrntd,
      cast( sktof_mm as wb2_purg_cash_disc preserving type )           as TrdgDocPurgIsCshDiscGrntd,
      pred_number                                                      as TrdgDocPredecessorDocument,
      pred_item_number                                                 as TrdgDocPredecessorItem,

      @ObjectModel.foreignKey.association: '_TrdgDocPrdcssrDocType'
      cast( pred_doc_type as wb2_precdg_doc_type preserving type )     as TrdgDocPrdcssrDocumentType,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( mwsbp_mm as wb2_purg_tax_amt preserving type )             as TrdgDocPurgTaxAmount,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      cast( mwsbp_sd as wb2_sls_tax_amt preserving type )              as TrdgDocSlsTaxAmount,

      @ObjectModel.foreignKey.association: '_TrdgDocIsHdggRlvt'
      hedging_relevant                                                 as TrdgDocHdggRlvt,
      @ObjectModel.foreignKey.association: '_TrdgDocCndnCnsldtnCat'
      cast(cond_con_alg  as wb2_cndn_cnsldtn_cat preserving type)      as TrdgDocCndnCnsldtnCat,

      @Semantics.booleanIndicator:true
      consolidated                                                     as TrdgDocCndnIsCnsldtd,

      ccomp                                                            as TrdgDocSTOPostingLogic,
      @ObjectModel.foreignKey.association: '_TrdgDocSettlementMode'
      sett_mode                                                        as TrdgDocSettlementMode,
      reslo                                                            as IssuingStorageLocation,
      cast( txjcd_mm as wb2_purg_tax_jx preserving type )              as TrdgDocPurgTaxJurisdiction,
      abfor                                                            as PaymentGuaranteeForm,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      dpamt_item                                                       as DownPaymentAmount,
      @Semantics.amount.currencyCode: 'TrdgDocPurgCurrency'
      brtwr_mm                                                         as SupplierTotalGrossAmount,
      bom_profile                                                      as TrdgDocBOMProfile,
      alt_bom                                                          as AlternativeBillOfMaterial,
      @ObjectModel.foreignKey.association: '_TrdgDocPurgRskRelevancy'
      cast( trmrisk_rel_mm as wb2_purg_rsk_relevancy preserving type ) as TrdgDocPurgRiskRelevancy,
      cast( trmrisk_rel_sd as wb2_sls_rsk_relevancy preserving type )  as TrdgDocSlsRiskRelevancy,
      cuobj_sd                                                         as TrdgDocSlsClfnObjInternalID,
      cuobj_mm                                                         as TrdgDocPurgClfnObjInternalID,
      groes                                                            as TrdgDocProdSizeOrDimnDesc,
      @ObjectModel.foreignKey.association: '_TrdgDocItemIsComplete'
      @Semantics.booleanIndicator:true
      cast( complete as wb2_document_complete preserving type )        as TrdgDocItemIsComplete,
      cast( aufnr as wb2_internal_order preserving type )              as TradingDocumentInternalOrder,
      @ObjectModel.foreignKey.association: '_TrdgDocItemBlockCode'
      block_code                                                       as TrdgDocItemBlockCode,
      cast( tax_country_mm as wb2_purg_tax_ctryreg preserving type )   as TrdgDocPurgTaxCountry,
      cast( txdat_mm as wb2_purg_tax_date preserving type )            as TrdgDocPurgTaxDate,
      cast( waers_purch as wb2_purg_currency_key preserving type )     as TrdgDocCurrency,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      _TrdgDocRefDocument.ControllingArea                              as ControllingArea,
      cast( stlnr as wb2_bill_of_material preserving type)             as TrdgDocBillOfMaterial,
      cast( posex as wb2_purchase_order_item preserving type)          as TrdgDocPurchaseOrderItem,
      cast( commodity as wb2_commodity_definition preserving type)     as TrdgDocCommodityDefinition,
      cast( item_relevancy as wb2_is_item_relevant  preserving type)   as TrdgDocIsItemRelevant,


      //Associations

      _CostCenter,
      _ControllingArea,
      _TrdgDocItemCategory,
      _Product,
      _Plant,
      _StorageLocation,
      _Batch,
      _TrdgDocPurgQuantityUnit,
      _TrdgDocSlsQuantityUnit,
      _TrdgDocSlsWeightUnit,
      _TrdgDocSlsVolumeUnit,
      _BaseUnit,
      _Division,
      _BusinessArea,
      _CreatedByUser,
      _ProductGroup,
      _SalesDocumentRjcnReason,
      _ProductHierarchyNode,
      _SalesSpcfcProductGroup1,
      _SalesSpcfcProductGroup2,
      _SalesSpcfcProductGroup3,
      _SalesSpcfcProductGroup4,
      _SalesSpcfcProductGroup5,
      _ItemBillingBlockReason,
      _TrdgDocSlsShippingPoint,
      _TradingDocumentSalesRoute,
      _TrdgDocPurgShipgCondition,
      _TrdgDocPurgShippingPoint,
      _PurgDocumentItemCategory,
      _TrdgDocRefDocument,
      _TrdgDocAddlRefDocument,
      _TrdgDocRefDocItem,
      _TrdgDocAddlRefDocItem,
      _TrdgDocRefDocumentType,
      _TrdgDocAddlRefDocumentType,
      _OriginallyRequestedProduct,
      _TrdgDocPurgCurrency,
      _TrdgDocCndnCnsldtnCat,
      _TrdgDocIsHdggRlvt,
      _TrdgDocPrcDetnIsIncmplt,
      _TrdgDocItemBlockCode,
      _TrdgDocPrdcssrDocType,
      _TrdgDocPurgRskRelevancy,
      _TrdgDocSettlementMode,
      _TrdgDocItemIsComplete


}
where
  tposn_sub = '000000';