R_TrdgDocHeaderBasic

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_CreatedByUser', '_LastChangedByUser' ]
}
@ObjectModel: {
   compositionRoot: false,
   representativeKey: 'TradingDocument',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   }
}
@Analytics: {
    dataExtraction.enabled: false,
    internalName: #LOCAL
}
@Metadata.allowExtensions: false
@EndUserText.label: 'Header of Trading Document'
@Metadata.ignorePropagatedAnnotations: true

/* Basic Layer */
define view entity R_TrdgDocHeaderBasic
  as select from wbhk

  //Association

  association [0..1] to R_TrdgDocType               as _TradingDocumentType        on  $projection.TradingDocumentType = _TradingDocumentType.TradingDocumentType
  association [0..1] to R_TrdgDocCategory           as _TrdgDocCategory            on  $projection.TrdgDocCategory = _TrdgDocCategory.TrdgDocCategory
  association [0..1] to R_TrdgDocApplicationStatus  as _TrdgDocApplStatus          on  $projection.TrdgDocApplicationStatus = _TrdgDocApplStatus.TrdgDocApplicationStatus
  association [0..1] to R_TrdgDocProcgStatus        as _TrdgDocProcgStatus         on  $projection.TrdgDocProcgStatus = _TrdgDocProcgStatus.TrdgDocProcgStatus
  association [0..1] to R_TrdgDocSuccssrArchived    as _TrdgDocSuccssrArchived     on  $projection.TrdgDocSuccessorArchived = _TrdgDocSuccssrArchived.TrdgDocSuccessorArchived
  association [0..1] to R_TrdgDocLastChgdCat        as _TrdgDocLastChgdCat         on  $projection.TrdgDocLastChangedCategory = _TrdgDocLastChgdCat.TrdgDocLastChangedCategory
  association [0..1] to R_TrdgDocVarContrSettlmt    as _TrdgDocVarContrSettlmt     on  $projection.TrdgDocVarContrSettlmt = _TrdgDocVarContrSettlmt.TrdgDocVarContrSettlmt
  association [0..1] to R_TrdgDocHasCnsldtdItem     as _TrdgDocHasCnsldtdItem      on  $projection.TrdgDocHasCnsldtdItem = _TrdgDocHasCnsldtdItem.TrdgDocHasCnsldtdItem
  association [0..1] to R_TrdgDocPricingType        as _TrdgDocPricingType         on  $projection.TrdgDocPricingType = _TrdgDocPricingType.TrdgDocPricingType
  association [0..1] to I_SalesDocumentType         as _SalesDocumentType          on  $projection.SalesDocumentType = _SalesDocumentType.SalesDocumentType
  association [0..1] to I_SDDocumentCategory        as _SDDocumentCategory         on  $projection.SDDocumentCategory = _SDDocumentCategory.SDDocumentCategory
  association [0..1] to I_User                      as _CreatedByUser              on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                      as _LastChangedByUser          on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_SalesOrganization         as _SalesOrganization          on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization
  association [0..1] to I_DistributionChannel       as _DistributionChannel        on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
  association [0..1] to I_Division                  as _OrganizationDivision       on  $projection.OrganizationDivision = _OrganizationDivision.Division
  association [0..1] to I_SalesGroup                as _SalesGroup                 on  $projection.SalesGroup = _SalesGroup.SalesGroup
  association [0..1] to I_SalesOffice               as _SalesOffice                on  $projection.SalesOffice = _SalesOffice.SalesOffice
  association [0..1] to I_Customer                  as _SoldToParty                on  $projection.SoldToParty = _SoldToParty.Customer
  association [0..1] to I_AdditionalCustomerGroup1  as _AdditionalCustomerGroup1   on  $projection.AdditionalCustomerGroup1 = _AdditionalCustomerGroup1.AdditionalCustomerGroup1
  association [0..1] to I_AdditionalCustomerGroup2  as _AdditionalCustomerGroup2   on  $projection.AdditionalCustomerGroup2 = _AdditionalCustomerGroup2.AdditionalCustomerGroup2
  association [0..1] to I_AdditionalCustomerGroup3  as _AdditionalCustomerGroup3   on  $projection.AdditionalCustomerGroup3 = _AdditionalCustomerGroup3.AdditionalCustomerGroup3
  association [0..1] to I_AdditionalCustomerGroup4  as _AdditionalCustomerGroup4   on  $projection.AdditionalCustomerGroup4 = _AdditionalCustomerGroup4.AdditionalCustomerGroup4
  association [0..1] to I_AdditionalCustomerGroup5  as _AdditionalCustomerGroup5   on  $projection.AdditionalCustomerGroup5 = _AdditionalCustomerGroup5.AdditionalCustomerGroup5
  association [0..1] to I_CreditControlArea         as _CreditControlArea          on  $projection.CreditControlArea = _CreditControlArea.CreditControlArea
  association [0..1] to I_SDDocumentReason          as _SalesOrderReason           on  $projection.SalesOrderReason = _SalesOrderReason.SDDocumentReason
  association [0..1] to I_CustomerPurchaseOrderType as _CustomerPurchaseOrderType  on  $projection.CustomerPurchaseOrderType = _CustomerPurchaseOrderType.CustomerPurchaseOrderType
  association [0..1] to I_Currency                  as _TrdgDocCurrency            on  $projection.TrdgDocCurrency = _TrdgDocCurrency.Currency
  association [0..1] to I_Currency                  as _TrdgDocSalesCurrency       on  $projection.TrdgDocSalesCurrency = _TrdgDocSalesCurrency.Currency
  association [0..1] to I_ShippingCondition         as _ShippingCondition          on  $projection.ShippingCondition = _ShippingCondition.ShippingCondition
  association [0..1] to I_DeliveryBlockReason       as _DeliveryBlockReason        on  $projection.DeliveryBlockReason = _DeliveryBlockReason.DeliveryBlockReason
  association [0..1] to I_CompanyCode               as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_BillingBlockReason        as _HeaderBillingBlockReason   on  $projection.HeaderBillingBlockReason = _HeaderBillingBlockReason.BillingBlockReason
  association [0..1] to I_ExchangeRateType          as _TrdgDocExchangeRateType    on  $projection.TrdgDocExchangeRateType = _TrdgDocExchangeRateType.ExchangeRateType
  association [0..1] to I_ExchangeRateType          as _TrdgDocSlsExchangeRateType on  $projection.TrdgDocSalesExchangeRateType = _TrdgDocSlsExchangeRateType.ExchangeRateType
  association [0..1] to I_SlsPricingProcedure       as _TrdgDocSlsPricingProcedure on  $projection.TrdgDocSalesPricingProcedure = _TrdgDocSlsPricingProcedure.PricingProcedure
  association [0..1] to I_ControllingArea           as _ControllingArea            on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..*] to I_SalesArea                 as _SalesArea                  on  $projection.SalesOrganization = _SalesArea.SalesOrganization
  association [0..1] to I_Customer                  as _CustomerCreditAccount      on  $projection.CustomerCreditAccount = _CustomerCreditAccount.Customer
  association [0..1] to I_Currency                  as _ControllingAreaCurrency    on  $projection.ControllingAreaCurrency = _ControllingAreaCurrency.Currency
  association [0..1] to I_CustomerSalesArea         as _CustomerSalesArea          on  $projection.SoldToParty          = _CustomerSalesArea.Customer
                                                                                   and $projection.SalesOrganization    = _CustomerSalesArea.SalesOrganization
                                                                                   and $projection.DistributionChannel  = _CustomerSalesArea.DistributionChannel
                                                                                   and $projection.OrganizationDivision = _CustomerSalesArea.Division
  association [0..1] to R_TrdgDocReleaseStatus      as _TrdgDocReleaseStatus       on  $projection.TrdgDocReleaseStatus = _TrdgDocReleaseStatus.TrdgDocReleaseStatus
  association [0..1] to R_TrdgDocBusProcCategory    as _TrdgDocBusProcCategory     on  $projection.TrdgDocBusProcessCategory = _TrdgDocBusProcCategory.TrdgDocBusProcessCategory
  association [0..1] to R_TrdgProcessVariantType    as _TradingProcessVariantType  on  $projection.TradingProcessVariantType = _TradingProcessVariantType.TradingProcessVariantType
  association [0..1] to I_WBSElementBasicData       as _WBSElementInternalID       on  $projection.WBSElementInternalID = _WBSElementInternalID.WBSElementInternalID
  association [0..1] to R_TrdgDocPurpose            as _TrdgDocPurpose             on  $projection.TrdgDocPurpose = _TrdgDocPurpose.TrdgDocPurpose
  association [0..1] to R_TrdgDocSrceDocType        as _TrdgDocSrceDocType         on  $projection.TrdgDocSrceDocType = _TrdgDocSrceDocType.TrdgDocSrceDocType
  association [0..1] to R_TrdgDocIsComplete         as _TrdgDocIsComplete          on  $projection.TrdgDocIsComplete = _TrdgDocIsComplete.TrdgDocIsComplete
  association [0..1] to I_SalesOrderType            as _SalesOrderType             on  $projection.SalesDocumentType = _SalesOrderType.SalesOrderType //TODO

  association [0..1] to I_MatlUsageIndicator        as _MatlUsageIndicator         on  $projection.TrdgDocProdUsgeCat = _MatlUsageIndicator.MatlUsageIndicator //TODO

  association [0..1] to I_Country                   as _TaxDepartureCountry        on  $projection.TaxDepartureCountry = _TaxDepartureCountry.Country //TODO

  association [0..1] to I_Country                   as _VATRegistrationCountry     on  $projection.VATRegistrationCountry = _VATRegistrationCountry.Country //TODO

  association [0..1] to I_TrdgDocAddlExpnsBlkRsnVH  as _TrdgDocAddlExpnsBlkRsn     on  $projection.TrdgDocAddlExpnsBlkRsn = _TrdgDocAddlExpnsBlkRsn.TrdgDocAddlExpnsBlkRsn //TODO


  association [0..1] to I_TrdgDocSuplrBillgBlkRsn   as _TrdgDocSuplrBillgBlkRsn    on  $projection.TrdgDocSuplrBillgBlkRsn = _TrdgDocSuplrBillgBlkRsn.TrdgDocSuplrBillgBlkRsn //TODO: Deprecate


{
  key tkonn                                                            as TradingDocument,

      @ObjectModel.foreignKey.association: '_TradingDocumentType'
      tctyp                                                            as TradingDocumentType,
      @ObjectModel.foreignKey.association: '_TrdgDocCategory'
      tccat                                                            as TrdgDocCategory,
      @ObjectModel.foreignKey.association: '_TrdgDocApplStatus'
      btbsta                                                           as TrdgDocApplicationStatus,
      @ObjectModel.foreignKey.association: '_SalesDocumentType'
      auart                                                            as SalesDocumentType,
      @Semantics.user.createdBy: true
      ernam                                                            as CreatedByUser,
      @Semantics.user.lastChangedBy: true
      aenam                                                            as LastChangedByUser,
      @Semantics.user.responsible: true
      tksachb                                                          as TrdgDocPersonResponsible,
      @Semantics.systemDate.createdAt: true
      erdat                                                            as CreationDate,
      cast( erzeit as wb2_created_at preserving type )                 as CreationTime,
      @Semantics.systemDate.lastChangedAt: true
      aedat                                                            as LastChangeDate,

      aezeit                                                           as LastChangeTime,
      budat                                                            as TrdgDocDate,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      vkorg                                                            as SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      vtweg                                                            as DistributionChannel,
      @ObjectModel.foreignKey.association: '_OrganizationDivision'
      spart                                                            as OrganizationDivision,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      vkgrp                                                            as SalesGroup,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      vkbur                                                            as SalesOffice,
      @ObjectModel.foreignKey.association: '_SoldToParty'
      kunnr                                                            as SoldToParty,
      @ObjectModel.foreignKey.association: '_AdditionalCustomerGroup1'
      kvgr1_sd                                                         as AdditionalCustomerGroup1,
      @ObjectModel.foreignKey.association: '_AdditionalCustomerGroup2'
      kvgr2_sd                                                         as AdditionalCustomerGroup2,
      @ObjectModel.foreignKey.association: '_AdditionalCustomerGroup3'
      kvgr3_sd                                                         as AdditionalCustomerGroup3,
      @ObjectModel.foreignKey.association: '_AdditionalCustomerGroup4'
      kvgr4_sd                                                         as AdditionalCustomerGroup4,
      @ObjectModel.foreignKey.association: '_AdditionalCustomerGroup5'
      kvgr5_sd                                                         as AdditionalCustomerGroup5,
      @ObjectModel.foreignKey.association: '_CreditControlArea'
      kkber                                                            as CreditControlArea,
      @ObjectModel.foreignKey.association: '_SDDocumentCategory'
      vbtyp_sd                                                         as SDDocumentCategory,
      cast (audat as wb2_sales_document_date preserving type )         as SalesDocumentDate,
      @ObjectModel.foreignKey.association: '_SalesOrderReason'
      augru                                                            as SalesOrderReason,
      submi_sd                                                         as SDDocumentCollectiveNumber,
      @ObjectModel.foreignKey.association: '_CustomerPurchaseOrderType'
      bsark_sd                                                         as CustomerPurchaseOrderType,
      bstzd_sd                                                         as CustomerPurchaseOrderSuplmnt,
      angdt_sd                                                         as BindingPeriodValidityStartDate,
      bnddt_sd                                                         as BindingPeriodValidityEndDate,
      cast( guebg as wb2_sls_valdty_start_dte preserving type )        as TrdgDocSlsValidityStartDate,
      cast( gueen as wb2_sls_valdty_end_dte preserving type )          as TrdgDocSlsValidityEndDate,
      cast( abrvw as wb2_prod_usge_cat preserving type )               as TrdgDocProdUsgeCat,
      exnum                                                            as ForeignTrade,
      bname_sd                                                         as TrdgDocSlsPersonName,
      cast( telf1_sd as wb2_cust_tel preserving type )                 as PhoneNumber1,
      cast( mahza_sd as wb2_sls_nrof_contacts preserving type )        as TrdgDocSlsNrOfFollowUps,
      xblnr_sd                                                         as DocumentReferenceID,
      @ObjectModel.foreignKey.association: '_TrdgDocPricingType'
      pricing_type                                                     as TrdgDocPricingType,
      @ObjectModel.foreignKey.association: '_TrdgDocCurrency'
      tkwaers                                                          as TrdgDocCurrency,
      @Semantics.amount.currencyCode: 'TrdgDocCurrency'
      netwr_sd                                                         as TrdgDocTotalNetAmount,
      cast( tkrate as wb2_tkrate_no_cnext preserving type )            as TrdgDocExchangeRate,
      @ObjectModel.foreignKey.association: '_TrdgDocExchangeRateType'
      kurst                                                            as TrdgDocExchangeRateType,
      wkurs_dat                                                        as TrdgDocExchangeRateDate,
      @ObjectModel.foreignKey.association: '_TrdgDocSalesCurrency'
      sdwrs                                                            as TrdgDocSalesCurrency,
      cast( tkrate_sd as wb2_sls_exch_rate_no_cnext preserving type )  as TrdgDocSalesExchangeRate,
      @ObjectModel.foreignKey.association: '_TrdgDocSlsExchangeRateType'
      cast( kurst_sd as wb2_sls_exch_rate_type preserving type )       as TrdgDocSalesExchangeRateType,
      cast( prsdt_sd as wb2_sls_prcg_dte preserving type )             as TrdgDocSalesPricingDate,
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_TrdgDocSlsPricingProcedure'
      cast( kalsm_sd as wb2_sls_prcg_proced preserving type )          as TrdgDocSalesPricingProcedure,
      taxk1_sd                                                         as CustomerTaxClassification1,
      taxk2_sd                                                         as CustomerTaxClassification2,
      taxk3_sd                                                         as CustomerTaxClassification3,
      taxk4_sd                                                         as CustomerTaxClassification4,
      taxk5_sd                                                         as CustomerTaxClassification5,
      taxk6_sd                                                         as CustomerTaxClassification6,
      taxk7_sd                                                         as CustomerTaxClassification7,
      taxk8_sd                                                         as CustomerTaxClassification8,
      taxk9_sd                                                         as CustomerTaxClassification9,
      @ObjectModel.foreignKey.association: '_ShippingCondition'
      vsbed_sd                                                         as ShippingCondition,
      autlf_sd                                                         as CompleteDeliveryIsDefined,
      @ObjectModel.foreignKey.association: '_DeliveryBlockReason'
      lifsk_sd                                                         as DeliveryBlockReason,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      company_code                                                     as CompanyCode,
      @ObjectModel.foreignKey.association: '_HeaderBillingBlockReason'
      faksk_sd                                                         as HeaderBillingBlockReason,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      kokrs                                                            as ControllingArea,
      @ObjectModel.foreignKey.association: '_CustomerCreditAccount'
      knkli                                                            as CustomerCreditAccount,
      grupp                                                            as CustomerCreditGroup,
      sbgrp                                                            as CreditRepresentativeGroup,
      ctlpc                                                            as CustomerRiskCategory,
      @ObjectModel.foreignKey.association: '_ControllingAreaCurrency'
      cmwae                                                            as ControllingAreaCurrency,
      cmfre                                                            as CreditBlockReleaseDate,
      cmnup                                                            as NextCreditCheckDate,
      cmngv                                                            as NextShippingDate,
      @Semantics.amount.currencyCode: 'ControllingAreaCurrency'
      amtbl                                                            as ReleasedCreditAmount,
      @ObjectModel.foreignKey.association: '_TrdgDocLastChgdCat'
      cast( wbpch as wb2_tc_last_changed_cat preserving type )         as TrdgDocLastChangedCategory,
      cast( kurrf as wb2_acc_exchange_rate preserving type )           as AccountingExchangeRate,
      ihrez_sd                                                         as TrdgDocSlsExternalReference,
      @ObjectModel.foreignKey.association: '_TrdgDocIsComplete'
      cast( complete as wb2_doc_is_complete preserving type )          as TrdgDocIsComplete,
      mahdt_sd                                                         as LastCustomerContactDate,
      quan_complete                                                    as TrdgDocQuantityIsComplete,
      @ObjectModel.foreignKey.association: '_TrdgDocReleaseStatus'
      tc_released                                                      as TrdgDocReleaseStatus,
      tkonn_ex                                                         as TrdgDocExternalIdentifier,
      @ObjectModel.foreignKey.association: '_TrdgDocBusProcCategory'
      cast( use_case as wb2_bus_proc_cat preserving type )             as TrdgDocBusProcessCategory,
      cast( we_kunnr  as wb2_goods_receiver preserving type )          as TradingDocumentGoodsReceiver,
      stceg_l                                                          as VATRegistrationCountry,
      landtx                                                           as TaxDepartureCountry,
      xegdr                                                            as IsEUTriangularDeal,
      @Semantics.booleanIndicator:true
      dummy_wbhk_incl_eew_ps                                           as TrdgDocHdrIsExtended,
      @ObjectModel.foreignKey.association: '_TrdgDocSuccssrArchived'
      succ_arch                                                        as TrdgDocSuccessorArchived,
      @Semantics.booleanIndicator:true
      @ObjectModel.foreignKey.association: '_TrdgDocHasCnsldtdItem'
      cast( consol_it_exist as wb2_consol_item_exist preserving type ) as TrdgDocHasCnsldtdItem,
      @ObjectModel.foreignKey.association: '_TrdgDocVarContrSettlmt'
      set_variant                                                      as TrdgDocVarContrSettlmt,
      in_approval                                                      as TrdgDocIsInApproval,
      kalsm_ch                                                         as TrdgDocBatDetnProcedure,
      @ObjectModel.foreignKey.association: '_TrdgDocProcgStatus'
      cast( pf_status as wb2_tc_procg_status preserving type )         as TrdgDocProcgStatus,
      pf_last_action                                                   as TrdgDocProcessingLastAction,
      pf_last_order                                                    as TrdgDocProcgLastSequence,
      @ObjectModel.foreignKey.association: '_TradingProcessVariantType'
      tew_type                                                         as TradingProcessVariantType,
      @ObjectModel.foreignKey.association: '_WBSElementInternalID'
      cast ( ps_psp_pnr as ps_s4_pspnr preserving type )               as WBSElementInternalID,
      @ObjectModel.foreignKey.association: '_TrdgDocSrceDocType'
      created_from                                                     as TrdgDocSrceDocType,
      @ObjectModel.foreignKey.association: '_TrdgDocPurpose'
      purpose                                                          as TrdgDocPurpose,

      cast( bstnk as wb2_po_by_customer preserving type)               as TrdgDocPOByCustomer,
      cast( bstdk as wb2_cust_purch_order_date preserving type )       as CustomerPurchaseOrderDate,
      abssc                                                            as PaymentGuaranteeProcedure,
      lcnum                                                            as InternalFinancialDocument,
      akprz                                                            as DepreciationPercentage,
      logsys                                                           as LogicalSystem,

      cast( lfspg as wb2_addl_expns_blk_rsn preserving type )          as TrdgDocAddlExpnsBlkRsn,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'TrdgDocAddlExpnsBlkRsn'
      cast( lfspg as wb2_suplr_billg_blk_rsn preserving type )         as TrdgDocSuplrBillgBlkRsn,

      cast( knumv_sd as wb2_sls_doc_cndn preserving type )             as SalesDocumentCondition,
      output_control                                                   as TrdgDocOutputControl,

      //Associations

      _TradingDocumentType,
      _TrdgDocCategory,
      _TrdgDocApplStatus,
      _TrdgDocHasCnsldtdItem,
      _TrdgDocLastChgdCat,
      _SalesDocumentType,
      _CreatedByUser,
      _TrdgDocVarContrSettlmt,
      _LastChangedByUser,
      _SalesOrganization,
      _DistributionChannel,
      _OrganizationDivision,
      _SalesGroup,
      _SalesOffice,
      _SoldToParty,
      _TrdgDocProcgStatus,
      _AdditionalCustomerGroup1,
      _AdditionalCustomerGroup2,
      _AdditionalCustomerGroup3,
      _AdditionalCustomerGroup4,
      _AdditionalCustomerGroup5,
      _CreditControlArea,
      _SalesOrderReason,
      _SDDocumentCategory,
      _CustomerPurchaseOrderType,
      _TrdgDocCurrency,
      _TrdgDocSalesCurrency,
      _TrdgDocPricingType,
      _ShippingCondition,
      _DeliveryBlockReason,
      _CompanyCode,
      _HeaderBillingBlockReason,
      _TrdgDocExchangeRateType,
      _TrdgDocSlsExchangeRateType,
      _TrdgDocSlsPricingProcedure,
      _ControllingArea,
      _SalesArea,
      _CustomerCreditAccount,
      _ControllingAreaCurrency,
      _TrdgDocReleaseStatus,
      _TrdgDocBusProcCategory,
      _TradingProcessVariantType,
      _TrdgDocSrceDocType,
      _TrdgDocPurpose,
      _TrdgDocSuccssrArchived,
      _WBSElementInternalID,
      _TrdgDocIsComplete,
      _CustomerSalesArea,
      _SalesOrderType,
      _MatlUsageIndicator,
      _TaxDepartureCountry,
      _VATRegistrationCountry,
      _TrdgDocAddlExpnsBlkRsn,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_TrdgDocAddlExpnsBlkRsn'
      _TrdgDocSuplrBillgBlkRsn //Deprecate in the future

};