R_ProjectTP_2

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'TP for I view I ProjectData 2'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel: {
   sapObjectNodeType:{
      name: 'Project'},
   usageType: {
      dataClass:       #TRANSACTIONAL,
      serviceQuality:  #C,
      sizeCategory:    #L
    }
}
define root view entity R_ProjectTP_2
  as select from I_ProjectData_2
  composition [1..*] of R_WBSElementTP_2               as _WBSElement
  ---Project short text
  association [0..1] to I_ProjectText                  as _ProjectText                   on  $projection.ProjectObject = _ProjectText.ProjectObject
                                                                                         and _ProjectText.Language     = $session.system_language
  ---Extension Association
  association [1..1] to E_Project_2                    as _Extension                     on  $projection.ProjectInternalID = _Extension.ProjectInternalID

  // Cross BO start -->

  association [0..*] to R_ProjectNetworkTP             as _ProjectNetwork                on  $projection.ProjectInternalID = _ProjectNetwork.ProjectInternalID
  association [0..*] to R_ProjectNetworkTP             as _ProjectNetworkUpdate          on  $projection.ProjectInternalID = _ProjectNetworkUpdate.ProjectInternalID
  association [0..*] to R_ProjectNetworkTP             as _ProjectNetworkDelete          on  $projection.ProjectInternalID = _ProjectNetworkDelete.ProjectInternalID

  association [0..*] to R_ProjectNetworkActivityTP     as _ProjectNetworkActivity        on  $projection.ProjectInternalID = _ProjectNetworkActivity.ProjectInternalID
  association [0..*] to R_ProjectNetworkActivityTP     as _ProjectNetworkActivityUpdate  on  $projection.ProjectInternalID = _ProjectNetworkActivityUpdate.ProjectInternalID
  association [0..*] to R_ProjectNetworkActivityTP     as _ProjectNetworkActivityDelete  on  $projection.ProjectInternalID = _ProjectNetworkActivityDelete.ProjectInternalID

  association [0..*] to R_ProjNetworkActivityElementTP as _ProjNtwkActivityElement       on  $projection.ProjectInternalID = _ProjNtwkActivityElement.ProjectInternalID
  association [0..*] to R_ProjNetworkActivityElementTP as _ProjNtwkActivityElementUpdate on  $projection.ProjectInternalID = _ProjNtwkActivityElementUpdate.ProjectInternalID
  association [0..*] to R_ProjNetworkActivityElementTP as _ProjNtwkActivityElementDelete on  $projection.ProjectInternalID = _ProjNtwkActivityElementDelete.ProjectInternalID

  association [0..*] to R_ProjNtwkActyMatlCompTP       as _ProjNtwkActyMatlComp          on  $projection.ProjectInternalID = _ProjNtwkActyMatlComp.ProjectInternalID
  association [0..*] to R_ProjNtwkActyMatlCompTP       as _ProjNtwkActyMatlCompUpdate    on  $projection.ProjectInternalID = _ProjNtwkActyMatlCompUpdate.ProjectInternalID
  association [0..*] to R_ProjNtwkActyMatlCompTP       as _ProjNtwkActyMatlCompDelete    on  $projection.ProjectInternalID = _ProjNtwkActyMatlCompDelete.ProjectInternalID

  association [0..*] to R_ProjNtwkActivityMilestoneTP  as _ProjNtwkActyMilestone         on  $projection.ProjectInternalID = _ProjNtwkActyMilestone.ProjectInternalID
  association [0..*] to R_ProjNtwkActivityMilestoneTP  as _ProjNtwkActyMilestoneUpdate   on  $projection.ProjectInternalID = _ProjNtwkActyMilestoneUpdate.ProjectInternalID
  association [0..*] to R_ProjNtwkActivityMilestoneTP  as _ProjNtwkActyMilestoneDelete   on  $projection.ProjectInternalID = _ProjNtwkActyMilestoneDelete.ProjectInternalID

  association [0..*] to R_ProjNtwkActyRelationshipTP   as _ProjNtwkActyRelshp            on  $projection.ProjectInternalID = _ProjNtwkActyRelshp.ProjectInternalID
  association [0..*] to R_ProjNtwkActyRelationshipTP   as _ProjNtwkActyRelshpDelete      on  $projection.ProjectInternalID = _ProjNtwkActyRelshpDelete.ProjectInternalID

  // Cross BO <-- end


{
  key ProjectInternalID,
      case ProjectExternalID
      when ''
      then cast( Project as ps_pspid_edit preserving type )
      else
      ProjectExternalID
      end as ProjectExternalID,
      @Semantics.text: true
      ProjectDescription,
      @Semantics.text: true
      _ProjectText.ProjectLangBsdDescription,
      ProjectProfileCode,
      CompanyCode,
      ControllingArea,
      FunctionalArea,
      ProfitCenter,
      PlannedStartDate,
      PlannedEndDate,
      WorkCenterLocation,
      TaxJurisdiction,
      ResponsiblePerson,
      ResponsiblePersonName,
      ApplicantCode,
      ApplicantName,
      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      BasicDatesLastScheduledDate,
      FcstdDatesLastScheduledDate,
      FactoryCalendar,
      SchedulingDurationUnit,
      ForecastedStartDate,
      ForecastedEndDate,
      BusinessArea,
      Plant,
      Currency,
      BudgetProfile,
      PlanningProfile,
      InvestmentProfile,
      ProjInterestCalcProfile,
      ResultAnalysisInternalID,
      ControllingObjectClass,
      NetworkProfile,
      WBSSchedulingProfile,
      PlanningMethForProjBasicDate,
      PlanningMethForProjFcstdDate,
      NetworkAssignmentType,
      WBSIsStatisticalWBSElement,
      WBSIsMarkedForIntegratedPlng,
      ProjectHasOwnStock,
      InventorySpecialStockValnType,
      WBSIsMarkedForAutomReqmtGrpg,
      SalesOrganization,
      DistributionChannel,
      Language,
      WBSElementMaskID,
      Division,
      DynItemProcessorPrfl,
      JointVenture,
      JointVentureCostRecoveryCode,
      JointVentureEquityType,
      JointVentureObjectType,
      JntIntrstBillgClass,
      JntIntrstBillgSubClass,
      StatusProfile,
      WBSStatusProfile,
      SimulationProfile,
      SchedulingScenario,
      DistributionProfile,
      PartnerDeterminationProcedure,
      FreeDefinedTableFieldSemantic,
      FreeDefinedAttribute01,
      FreeDefinedAttribute02,
      FreeDefinedAttribute03,
      FreeDefinedAttribute04,
      FreeDefinedQuantity1,
      FreeDefinedQuantity1Unit,
      FreeDefinedQuantity2,
      FreeDefinedQuantity2Unit,
      FreeDefinedAmount1,
      FreeDefinedAmount1Currency,
      FreeDefinedAmount2,
      FreeDefinedAmount2Currency,
      FreeDefinedDate1,
      FreeDefinedDate2,
      FreeDefinedIndicator1,
      FreeDefinedIndicator2,
      ProjectObject,
      StatusCombinationCode,

      //Associataions

      _WBSElement,
      @Consumption.hidden: true
      _ResponsiblePerson,
      @Consumption.hidden: true
      _ProjectApplicant,

      _ProjectNetwork,
      _ProjectNetworkUpdate,
      _ProjectNetworkDelete,

      _ProjectNetworkActivity,
      _ProjectNetworkActivityUpdate,
      _ProjectNetworkActivityDelete,

      _ProjNtwkActivityElement,
      _ProjNtwkActivityElementUpdate,
      _ProjNtwkActivityElementDelete,

      _ProjNtwkActyMatlComp,
      _ProjNtwkActyMatlCompUpdate,
      _ProjNtwkActyMatlCompDelete,

      _ProjNtwkActyMilestone,
      _ProjNtwkActyMilestoneUpdate,
      _ProjNtwkActyMilestoneDelete,

      _ProjNtwkActyRelshp,
      _ProjNtwkActyRelshpDelete

}