A_Project_3

@AccessControl: {
    authorizationCheck:     #CHECK,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}
@EndUserText.label: 'Project data details'
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel: {
    usageType: {
      dataClass:       #MIXED,
      serviceQuality:  #C,
      sizeCategory:    #XL
    }
}
@VDM: {
    viewType: #COMPOSITE,
    lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@OData.entitySet.name : 'Project'
@OData.entityType.name:'Project_Type'
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
define root view entity A_Project_3
  provider contract transactional_query
  as projection on R_ProjectTP_2 as _Project
  association [1..*] to A_ProjectStatus               as _ProjectStatus               on _Project.ProjectInternalID = _ProjectStatus.ProjectInternalID
  association [1..*] to A_ProjPurReqGroupingIndicator as _ProjPurReqGroupingIndicator on _Project.ProjectInternalID = _ProjPurReqGroupingIndicator.ProjectInternalID
  association [0..*] to A_ProjectPartner              as _ProjectPartner              on _Project.ProjectInternalID = _ProjectPartner.ProjectInternalID
  ---Extension Association
  association [1..1] to E_Project_2                   as _Extension                   on $projection.ProjectInternalID = _Extension.ProjectInternalID
{
  key ProjectInternalID,
      ProjectExternalID,
      ProjectDescription,
      ProjectLangBsdDescription,
      @ObjectModel.sapObjectNodeTypeReference: 'ProjectProfileCode'
      ProjectProfileCode,
      CompanyCode,
      ControllingArea,
      FunctionalArea,
      ProfitCenter,
      PlannedStartDate,
      PlannedEndDate,
      WorkCenterLocation,
      TaxJurisdiction,
      ResponsiblePerson,
      ResponsiblePersonName,
      ApplicantCode,
      ApplicantName,
      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      BasicDatesLastScheduledDate,
      FcstdDatesLastScheduledDate,
      FactoryCalendar,
      SchedulingDurationUnit,
      ForecastedStartDate,
      ForecastedEndDate,
      BusinessArea,
      Plant,
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      Currency,
      BudgetProfile,
      PlanningProfile,
      InvestmentProfile,
      ProjInterestCalcProfile,
      ResultAnalysisInternalID,
      ControllingObjectClass,
      @ObjectModel.sapObjectNodeTypeReference: 'ProjectNetworkProfile'
      NetworkProfile,
      WBSSchedulingProfile,
      PlanningMethForProjBasicDate,
      PlanningMethForProjFcstdDate,
      NetworkAssignmentType,
      WBSIsStatisticalWBSElement,
      WBSIsMarkedForIntegratedPlng,
      @Semantics.booleanIndicator: true
      ProjectHasOwnStock,
      InventorySpecialStockValnType,
      WBSIsMarkedForAutomReqmtGrpg,
      SalesOrganization,
      DistributionChannel,
      Language,
      WBSElementMaskID,
      @ObjectModel.sapObjectNodeTypeReference: 'Division'
      Division,
      DynItemProcessorPrfl,
      JointVenture,
      JointVentureCostRecoveryCode,
      JointVentureEquityType,
      JointVentureObjectType,
      JntIntrstBillgClass,
      JntIntrstBillgSubClass,
      StatusProfile,
      WBSStatusProfile,
      SimulationProfile,
      SchedulingScenario,
      DistributionProfile,
      PartnerDeterminationProcedure,
      FreeDefinedTableFieldSemantic,
      FreeDefinedAttribute01,
      FreeDefinedAttribute02,
      FreeDefinedAttribute03,
      FreeDefinedAttribute04,
      @Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity1Unit'
      FreeDefinedQuantity1,
      FreeDefinedQuantity1Unit,
      @Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity2Unit'
      FreeDefinedQuantity2,
      FreeDefinedQuantity2Unit,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
      @EndUserText.label: 'User field value 1 for Project'
      FreeDefinedAmount1,
      FreeDefinedAmount1Currency,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      @EndUserText.label: 'User field value 2 for Project'
      FreeDefinedAmount2,
      FreeDefinedAmount2Currency,
      FreeDefinedDate1,
      FreeDefinedDate2,
      FreeDefinedIndicator1,
      FreeDefinedIndicator2,
      StatusCombinationCode,

      //Association

      @Consumption.hidden: true
      _ResponsiblePerson,
      @Consumption.hidden: true
      _ProjectApplicant,
      _ProjectStatus,
      _ProjPurReqGroupingIndicator,
      _ProjectPartner,
      _WBSElement : redirected to composition child A_WBSElement_3,

      _ProjectNetwork                : redirected to A_ProjectNetwork,
      _ProjectNetworkUpdate          : redirected to A_ProjectNetwork,
      _ProjectNetworkDelete          : redirected to A_ProjectNetwork,

      _ProjectNetworkActivity        : redirected to A_ProjectNetworkActivity,
      _ProjectNetworkActivityUpdate  : redirected to A_ProjectNetworkActivity,
      _ProjectNetworkActivityDelete  : redirected to A_ProjectNetworkActivity,

      _ProjNtwkActivityElement       : redirected to A_ProjNetworkActivityElement,
      _ProjNtwkActivityElementUpdate : redirected to A_ProjNetworkActivityElement,
      _ProjNtwkActivityElementDelete : redirected to A_ProjNetworkActivityElement,

      _ProjNtwkActyMatlComp          : redirected to A_ProjNtwkActyMatlComp,
      _ProjNtwkActyMatlCompUpdate    : redirected to A_ProjNtwkActyMatlComp,
      _ProjNtwkActyMatlCompDelete    : redirected to A_ProjNtwkActyMatlComp,

      _ProjNtwkActyMilestone         : redirected to A_ProjNtwkActivityMilestone,
      _ProjNtwkActyMilestoneUpdate   : redirected to A_ProjNtwkActivityMilestone,
      _ProjNtwkActyMilestoneDelete   : redirected to A_ProjNtwkActivityMilestone,

      _ProjNtwkActyRelshp            : redirected to A_ProjNtwkActyRelationship,
      _ProjNtwkActyRelshpDelete      : redirected to A_ProjNtwkActyRelationship

}