R_ProjNetworkActivityElementTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Data for Network Activity Element – TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.sapObjectNodeType.name:'ProjectNetworkActivityElement'
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
define view entity R_ProjNetworkActivityElementTP
  as select from I_NtwkActyByInternalKeyData
  association        to parent R_ProjectNetworkActivityTP as _NetworkActivity          on  $projection.ProjectNetworkInternalID       = _NetworkActivity.ProjectNetworkInternalID
                                                                                       and $projection.SuperiorNtwkActivityInternalID = _NetworkActivity.ProjNetworkActivityInternalID
  association [1..1] to R_ProjectNetworkTP                as _ProjectNetwork           on  $projection.ProjectNetwork = _ProjectNetwork.ProjectNetwork
  association [0..1] to I_WBSElementData_2                as _WBSElement               on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [1..*] to I_ProjNtwkObjPurReqGrpgInd        as _ProjNtwkObjPurReqGrpgInd on  _ProjNtwkObjPurReqGrpgInd.ProjectNetworkComponentID = '00000000000000E'
                                                                                       and $projection.ProjectNetwork                          = _ProjNtwkObjPurReqGrpgInd.ProjectNetwork
                                                                                       and $projection.SuperiorNtwkActivityExternalID          = _ProjNtwkObjPurReqGrpgInd.NetworkActivity
                                                                                       and $projection.NetworkActivity                         = _ProjNtwkObjPurReqGrpgInd.OrderSuboperation
                                                                                       and $projection.PurchaseRequisition                     = _ProjNtwkObjPurReqGrpgInd.PurchaseRequisition
  association [1..1] to E_NetworkActivity                 as _Extension                on  $projection.ProjectNetworkInternalID      = _Extension.ProjectNetworkInternalID
                                                                                       and $projection.ProjNetworkActivityInternalID = _Extension.NetworkActivityInternalID
  composition [0..*] of R_ProjNtwkActyElmntConfTP     as _NtwkActElementConfirmation
{
  key ProjectNetworkInternalID,
  key NetworkActivityInternalID                 as ProjNetworkActivityInternalID,
      ProjectNetwork,
      NetworkActivity,
      @Semantics.text: true
      _ActivityShortText.LanguageBasedShortText as NtwkActyLangBsdDescription,
      @Semantics.text: true
      NetworkActivityDescription,
      NetworkActivityObject,
      SuperiorNtwkActivityInternalID,
      SuperiorNtwkActivityExternalID,
      WBSElementInternalID,
      case _WBSElement.WBSElementExternalID
      when ''
      then cast( _WBSElement.WBSElement as ps_posid_edit preserving type )
      else _WBSElement.WBSElementExternalID
      end                                       as WBSElementExternalID,
      WorkCenterInternalID,
      _WorkCenter.WorkCenter,
      Plant,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
      _NtwkActivityDatesQuantity.PlannedWorkQuantity,
      _NtwkActivityDatesQuantity.StandardWorkQuantityUnit1,
      OperationCalculationControl,
      CostCtrActivityType,
      NetworkActivityControlProfile,
      ActyIsTakenAcctForProjSmmry,
      CapacityRequirementDistrKey,
      NumberOfCapacities,
      OperationWorkPercent,
      StandardTextInternalID,
      StandardDurationIsFlexible,
      FactoryCalendar,
      @Semantics.booleanIndicator
      ExtProcgOperationHasSubcontrg,
      PurchasingInfoRecord,
      PurchasingOrganization,
      Supplier,
      PurchasingGroup,
      OpPurchaseOutlineAgreement,
      OpPurchaseOutlineAgreementItem,
      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      ExternalProcessingPrice,
      NetworkActivityCurrency,
      @Semantics.quantity.unitOfMeasure: 'OperationQuantityUnit'
      NetworkActivityPriceBaseQty,
      CostElement,
      PurgInfoRecdDataIsFixed,
      _NtwkActivityDatesQuantity.PlannedDeliveryDurationInDays,
      @Semantics.quantity.unitOfMeasure: 'OperationQuantityUnit'
      _NtwkActivityDatesQuantity.OperationQuantity,
      _NtwkActivityDatesQuantity.OperationQuantityUnit,
      PurchaseRequisition,
      PurchaseRequisitionItem,
      MaterialGroup,
      PurchasingInfoRecdAddlGrpgName,
      RequisitionerUser,
      GoodsRecipientName,
      OperationTrackingNumber,
      UnloadingPointName,
      _NtwkActivityDatesQuantity.SchedldBasicEarliestStartDate,
      _NtwkActivityDatesQuantity.SchedldBasicEarliestStartTime,
      _NtwkActivityDatesQuantity.SchedldBasicEarliestEndDate,
      _NtwkActivityDatesQuantity.SchedldBasicEarliestEndTime,
      _NtwkActivityDatesQuantity.SchedldBasicLatestStartDate,
      _NtwkActivityDatesQuantity.SchedldBasicLatestStartTime,
      _NtwkActivityDatesQuantity.ScheduledBasicLatestEndDate,
      _NtwkActivityDatesQuantity.SchedldBasicLatestEndTime,
      _NtwkActivityDatesQuantity.ActualStartDate,
      _NtwkActivityDatesQuantity.ActualExecutionStartTime,
      _NtwkActivityDatesQuantity.ActualEndDate,
      _NtwkActivityDatesQuantity.ActualExecutionEndTime,
      _NtwkActivityDatesQuantity.ActyConfFcstdEndDate,
      _NtwkActivityDatesQuantity.ActyConfFcstdEndTime,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
      _NtwkActivityDatesQuantity.ActualWorkQuantity,
      @Semantics.quantity.unitOfMeasure: 'ActivityConfFcstdDurationUnit'
      _NtwkActivityDatesQuantity.ActivityConfFcstdDuration,
      _NtwkActivityDatesQuantity.ActivityConfFcstdDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
      _NtwkActivityDatesQuantity.ForecastedWorkQty,
      _NtwkActivityDatesQuantity.SchedldFcstdEarliestStartDate,
      _NtwkActivityDatesQuantity.SchedldFcstdEarliestStartTime,
      _NtwkActivityDatesQuantity.SchedldFcstdEarliestEndDate,
      _NtwkActivityDatesQuantity.SchedldFcstdEarliestEndTime,
      _NtwkActivityDatesQuantity.LatestSchedldFcstdStartDate,
      _NtwkActivityDatesQuantity.SchedldFcstdLatestStartTime,
      _NtwkActivityDatesQuantity.LatestSchedldFcstdEndDate,
      _NtwkActivityDatesQuantity.SchedldFcstdLatestEndTime,
      CompanyCode,
      BusinessArea,
      NetworkActivityObjectCurrency,
      TaxJurisdictionCalcProcedure,
      ProfitCenter,
      OverheadCode,
      ChangeNumber,
      TaxJurisdiction,
      FunctionalArea,
      ControllingObjectClass,
      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      _NetworkActivityUserFields.FreeDefinedTableFieldSemantic,
      _NetworkActivityUserFields.FreeDefinedAttribute01,
      _NetworkActivityUserFields.FreeDefinedAttribute02,
      _NetworkActivityUserFields.FreeDefinedAttribute03,
      _NetworkActivityUserFields.FreeDefinedAttribute04,
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity1Unit'
      _NetworkActivityUserFields.FreeDefinedQuantity1,
      _NetworkActivityUserFields.FreeDefinedQuantity1Unit,
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity2Unit'
      _NetworkActivityUserFields.FreeDefinedQuantity2,
      _NetworkActivityUserFields.FreeDefinedQuantity2Unit,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
      _NetworkActivityUserFields.FreeDefinedAmount1,
      _NetworkActivityUserFields.FreeDefinedAmount1Currency,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      _NetworkActivityUserFields.FreeDefinedAmount2,
      _NetworkActivityUserFields.FreeDefinedAmount2Currency,
      _NetworkActivityUserFields.FreeDefinedDate1,
      _NetworkActivityUserFields.FreeDefinedDate2,
      _NetworkActivityUserFields.FreeDefinedIndicator1,
      _NetworkActivityUserFields.FreeDefinedIndicator2,
      ProgressAnlysAggregationWeight,
      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      NetworkActivityCost,
      PartnerCostCenter,
      Language,
      NtwkAccountAssignmentCode,
      IsMarkedForDeletion,

      cast (case
        when ProjNtwkIsRlvtForMatlPlng = ' ' then '3'
        when ProjNtwkIsRlvtForMatlPlng = 'X' then '2'
        when ProjNtwkIsRlvtForMatlPlng = '1' then '1'
        when ProjNtwkIsRlvtForMatlPlng = 'B' then '4'
      end as abap.char( 1 ) )                   as PurReqnOrResvnGeneration,

      _NetworkActivityUserFields.JointVenture,
      _NetworkActivityUserFields.JointVentureRecoveryCode,
      _NetworkActivityUserFields.JointVentureEquityType,
      _NetworkActivityUserFields.JointVentureObjectType,
      _NetworkActivityUserFields.JointVentureClass,
      _NetworkActivityUserFields.JointVentureSubClass,
      _NetworkActivityUserFields.JntVentureOriglCostObjectType,
      _NtwkActivityDatesQuantity.StandardWorkQuantityUnit,
      //new variable to maintain scheduling for different sets of dates in case of updating offset

      cast ( '' as char1 )                      as SetOfDatesForOffsets,
      _NtwkActivityDatesQuantity.StartDateOffsetDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'StartDateOffsetDurationUnit'
      _NtwkActivityDatesQuantity.StartDateOffsetDuration,
      @Semantics.quantity.unitOfMeasure: 'EndDateOffsetDurationUnit'
      _NtwkActivityDatesQuantity.EndDateOffsetDuration,
      _NtwkActivityDatesQuantity.EndDateOffsetDurationUnit,
      @Semantics.amount.currencyCode: 'ControllingAreaCurrency'
      MatPlanningPrimaryCost,
      ReferenceElement,
      _ControllingArea.ControllingAreaCurrency  as ControllingAreaCurrency,
      _ProjNtwkObjPurReqGrpgInd.PurReqnCollectiveIndicatorCode,

      //For Cross BO

      _ProjectNetwork.ProjectInternalID,

      // Associations

      _NetworkActivity,
      _ProjectNetwork,
      _ProjectNetworkBasicData,
      _FactoryCalendarText,
      _WBSElement,
      _WorkCenter,
      _NetworkActivityWorkCenter,
      _NtwkActivityDatesQuantity,
      _NetworkActivityUserFields,
      _Superior,
      _OperationControlProfileText,
      _NtwkActElementConfirmation
}
where
  SuperiorNtwkActivityInternalID is not initial