R_ProcessOrderComponentTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#TRANSACTIONAL_PROVIDER]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Process Order Component - TP'
//

//      ************************  DO NOT USE  ************************

//      *            This RAP BO is for testing purpose only         *

//      **************************************************************


define view entity R_ProcessOrderComponentTP
  as select from I_ManufacturingOrderComponent as Component
    inner join   I_OrderOperationBasic         as Operation on  Operation.OrderInternalID          = Component.OrderInternalID
                                                            and Operation.OrderOperationInternalID = Component.OrderOperationInternalID

  // BO relation

  association        to parent R_ProcessOrderTP   as _Order        on  $projection.ProcessOrder = _Order.ProcessOrder

  association [0..1] to R_ProcessOrderPhaseTP     as _Phase        on  _Phase.ProcessOrder         = $projection.ProcessOrder
                                                                   and _Phase.OrderPhaseInternalID = $projection.OrderPhaseInternalID

  association [0..1] to R_ProcessOrderOperationTP as _Operation    on  _Operation.ProcessOrder             = $projection.ProcessOrder
                                                                   and _Operation.OrderOperationInternalID = $projection.OrderOperationInternalID

  // Extension association

  association [1..1] to E_ProcessOrderComponent   as _Extension    on  $projection.Reservation           = _Extension.Reservation
                                                                   and $projection.ReservationItem       = _Extension.ReservationItem
                                                                   and $projection.ReservationRecordType = _Extension.ReservationRecordType
{
      // Key

  key Component.Reservation,
  key Component.ReservationItem,
  key Component.ReservationRecordType,

      //Material data

      cast(Component.MaterialGroup as matkl preserving type )                                                   as MaterialGroup,
      cast(Component.Material as matnr preserving type )                                                        as Material,
      Component.Plant,

      // Order and Operation data

      cast(Component.ManufacturingOrder as co_bord preserving type)                                             as ProcessOrder,
//      Component.ManufacturingOrderSequence                                                                      as ProcessOrderSequence,

//      Component.MfgOrderSequenceCategory                                                                        as SequenceCategory,


      //      Component.ManufacturingOrderOperation                                                                     as ProcessOrderOperation,

      case Operation.MfgOrderOperationIsPhase when 'X' then Component.ManufacturingOrderOperation else ' ' end  as ProcessOrderPhase,
      case Operation.MfgOrderOperationIsPhase when ' ' then Component.ManufacturingOrderOperation else ' ' end  as ProcessOrderOperation,
      //      case when _Phase.OrderPhaseInternalID is not null then Component.ManufacturingOrderOperation else null end         as ProcessOrderPhase1,

      //      case when _Operation.OrderOperationInternalID is not null then Component.ManufacturingOrderOperation else null end as ProcessOrderOperation1,


      Component.OrderInternalID                                                                                 as OrderInternalID,

      //      Component.OrderOperationInternalID,

      case Operation.MfgOrderOperationIsPhase when 'X' then Component.OrderOperationInternalID else null end    as OrderPhaseInternalID,
      case Operation.MfgOrderOperationIsPhase when ' ' then Component.OrderOperationInternalID else null end    as OrderOperationInternalID,

      //      case when _Phase.OrderPhaseInternalID is not null then Component.OrderOperationInternalID else null end            as OrderPhaseInternalID1,

      //      case when _Operation.OrderOperationInternalID is not null then Component.OrderOperationInternalID else null end    as OrderOperationInternalID1,


      // Date and Time

      @Semantics.businessDate.at: true
      Component.MatlCompRequirementDate,
      Component.MatlCompRequirementTime,
      Component.LatestRequirementDate,

      // Attributes

      Component.ReservationItemCreationCode,
      Component.ReservationIsFinallyIssued,
      @Semantics.booleanIndicator
      Component.MatlCompIsMarkedForDeletion,
      Component.MaterialComponentIsMissing,
      Component.IsBulkMaterialComponent,
      Component.MatlCompIsMarkedForBackflush,
      Component.MaterialCompIsAlternativeItem,
      Component.MatlCompIsTextItem,
      Component.MaterialProvisionType,
      Component.MaterialPlanningRelevance,
      Component.MatlCompDiscontinuationType,
      Component.MatlCompIsConfigurable,
      Component.MaterialCompCostingRelevancy,
      Component.MaterialComponentIsClassified,
      Component.MaterialCompIsIntraMaterial,
      Component.UsageProbabilityPercent,
      Component.MaterialIsDirectlyProduced,
      Component.MaterialIsDirectlyProcured,

      // Long Text

      Component.LongTextLanguage,
      Component.MaterialComponentHasLongText,

      // Assignments

      Component.RequirementType,
      Component.SalesOrder,
      Component.SalesOrderItem,
      cast(Component.WBSElementInternalID as ps_s4_pspnr preserving type)                                       as WBSElementInternalID,
      Component.ProductConfiguration,
      Component.ChangeNumber,
      Component.EffectivityParameterVariant,
      Component.MatlCompFreeDefinedAttribute,

      // Assignments BOM

      Component.BillOfMaterialCategory,
      Component.BillOfMaterialInternalID,
      Component.BillOfMaterialVariant,
      Component.BillOfMaterialItemNodeNumber,
      Component.BillOfMaterialVersion,
      Component.BOMItemInternalChangeCount,
      Component.InheritedBOMItemNode,
      Component.BillOfMaterialItemCategory,
      Component.BillOfMaterialItemNumber,
      @Semantics.text: true
      Component.MaterialComponentText,
      @Semantics.text: true
      Component.MaterialComponentSecondText,
      Component.BOMExplosionDateID,

      // Assignments Purchasing

      Component.PurchasingInfoRecord,
      Component.PurchasingGroup,
      Component.PurchaseRequisition,
      Component.PurchaseRequisitionItem,
      Component.PurchaseOrder,
      Component.PurchaseOrderItem,
      Component.Supplier,
      Component.DeliveryDurationInDays,
      Component.MaterialGoodsReceiptDuration,
      -- Price
      @Semantics.amount.currencyCode: 'Currency'
      Component.ExternalProcessingPrice,
      Component.NumberOfOperationPriceUnits                                                                     as NumberOfPriceUnits,

      // Goods Movement data

      Component.GoodsMovementIsAllowed,
      Component.StorageLocation,
      cast(Component.Batch as charg_d preserving type)                                                          as Batch,
      Component.BatchSplitType,
      Component.DebitCreditCode,
      Component.GoodsMovementType,
      Component.InventorySpecialStockType,
      Component.InventorySpecialStockValnType,
      Component.ConsumptionPosting,
      Component.SupplyArea,
      @Semantics.text: true
      Component.GoodsRecipientName,
      @Semantics.text: true
      Component.UnloadingPointName,
      Component.StockSegment,
      Component.RequirementSegment,

      // Assignments FI/CO

      Component.BusinessArea,
      Component.GLAccount,
      Component.FunctionalArea,
//      Component.ControllingArea,

      Component.AccountAssignmentCategory,

      // Variable-size comp. data

      Component.MaterialCompIsVariableSized,
      Component.VariableSizeItemUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeItemUnit'
      Component.VariableSizeItemQuantity,

      Component.VariableSizeComponentUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      Component.VariableSizeComponentQuantity,
      Component.VariableSizeDimensionUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      Component.VariableSizeDimension1,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      Component.VariableSizeDimension2,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      Component.VariableSizeDimension3,
      Component.VariableSizeCompFormulaKey,

      // Phantom assembly

      Component.MaterialComponentIsPhantomItem,
      Component.OrderPathValue,
      Component.OrderLevelValue,

      // Lead-Time offset

      Component.LeadTimeOffset,
      case Operation.MfgOrderOperationIsPhase when 'X' then Component.OperationLeadTimeOffsetUnit else null end as PhaseLeadTimeOffsetUnit,
      case Operation.MfgOrderOperationIsPhase when 'X' then Component.OperationLeadTimeOffset else null end     as PhaseLeadTimeOffset,

      // Quantities and UoM

      Component.QuantityIsFixed,
      Component.IsNetScrap,
      Component.ComponentScrapInPercent,
      // scrap limited to phases in PI

      case Operation.MfgOrderOperationIsPhase when 'X' then Component.OperationScrapInPercent else null end     as PhaseScrapPercent,
      Component.MaterialQtyToBaseQtyNmrtr,
      Component.MaterialQtyToBaseQtyDnmntr,
      Component.BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Component.RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Component.WithdrawnQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Component.ConfirmedAvailableQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Component.MaterialCompOriginalQuantity,

      Component.EntryUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      Component.GoodsMovementEntryQty,

      // Amount and Currency

      Component.Currency,
      @Semantics.amount.currencyCode: 'Currency'
      Component.WithdrawnQuantityAmount,

      // Associations

      _Order,
      _Phase,
      _Operation,

      @Consumption.hidden: true
      Component._Supplier,              // for DCLS

      @Consumption.hidden: true
      Component._SupplierCompanyByPlant // for DCLS

}
where
  Component.ManufacturingOrderCategory = '40';