I_MANUFACTURINGORDERCOMPONENT

@AbapCatalog.sqlViewName: 'IMFGORDERCOMP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AccessControl.privilegedAssociations: ['_AssemblyMRPController', '_ProductionSupervisor', '_LongText']
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'ReservationItem'
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order Component'

// In later releases this view shall be C1-released as successor of I_MfgOrderOperationComponent


/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_ManufacturingOrderComponent
  as select from I_OrderComponent    as resb
    inner join I_LogisticsOrderBasic as afko on afko.OrderID = resb.OrderID

  association [1..1] to I_ReservationDocumentHeader   as _Reservation                 on  $projection.Reservation = _Reservation.Reservation
  association [1..1] to I_ReservationDocumentItem     as _ReservationItem             on  $projection.Reservation           = _ReservationItem.Reservation
                                                                                      and $projection.ReservationItem       = _ReservationItem.ReservationItem
                                                                                      and $projection.ReservationRecordType = _ReservationItem.RecordType
  association [0..1] to I_ReservationDocRecordType    as _ReservationRecordType       on  $projection.ReservationRecordType = _ReservationRecordType.RecordType
  association [1..1] to I_MfgOrderOperationBySemKey   as _MfgOrderOperationBySemKey   on  $projection.ManufacturingOrder          = _MfgOrderOperationBySemKey.ManufacturingOrder
                                                                                      and $projection.ManufacturingOrderSequence  = _MfgOrderOperationBySemKey.ManufacturingOrderSequence
                                                                                      and $projection.ManufacturingOrderOperation = _MfgOrderOperationBySemKey.ManufacturingOrderOperation
  association [1..1] to I_MfgOrderCategory            as _MfgOrderCategory            on  $projection.ManufacturingOrderCategory = _MfgOrderCategory.ManufacturingOrderCategory
  association [1..1] to I_MfgOrderType                as _MfgOrderType                on  $projection.ManufacturingOrderType = _MfgOrderType.ManufacturingOrderType
  association [0..1] to I_ProductSupplyPlanning       as _ProductSupplyPlanning       on  $projection.Material = _ProductSupplyPlanning.Product
                                                                                      and $projection.Plant    = _ProductSupplyPlanning.Plant                                                                                        
  association [1..*] to I_ProductUnitsOfMeasure       as _ProductUnitsOfMeasure       on  $projection.Material = _ProductUnitsOfMeasure.Product
  association [0..1] to I_MRPController               as _AssemblyMRPController       on  $projection.Plant                 = _AssemblyMRPController.Plant
                                                                                      and $projection.AssemblyMRPController = _AssemblyMRPController.MRPController
  association [0..1] to I_ProductionSupervisor        as _ProductionSupervisor        on  $projection.Plant                = _ProductionSupervisor.Plant
                                                                                      and $projection.ProductionSupervisor = _ProductionSupervisor.ProductionSupervisor
  association [0..1] to I_SupplierCompanyByPlant      as _SupplierCompanyByPlant      on  $projection.Plant    = _SupplierCompanyByPlant.Plant
                                                                                      and $projection.Supplier = _SupplierCompanyByPlant.Supplier

  -- to root
  association [1..1] to I_ManufacturingOrder          as _MfgOrder                    on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  -- to parents
  association [0..1] to I_ManufacturingOrderSequence  as _MfgOrderSequence            on  $projection.ManufacturingOrder         = _MfgOrderSequence.ManufacturingOrder
                                                                                      and $projection.ManufacturingOrderSequence = _MfgOrderSequence.ManufacturingOrderSequence
  association [0..1] to I_ManufacturingOrderOperation as _MfgOrderOperation           on  $projection.OrderInternalID          = _MfgOrderOperation.MfgOrderInternalID 
                                                                                      and $projection.OrderOperationInternalID = _MfgOrderOperation.OrderOperationInternalID
  -- to child
  association [0..1] to I_MfgOrderComponentLongText   as _MfgOrderComponentLongText   on  $projection.Reservation           = _MfgOrderComponentLongText.Reservation
                                                                                      and $projection.ReservationItem       = _MfgOrderComponentLongText.ReservationItem
                                                                                      and $projection.ReservationRecordType = _MfgOrderComponentLongText.RecordType
                                                                                      and $projection.LongTextLanguage      = _MfgOrderComponentLongText.LongTextLanguage
  -- to extension
  association [1..1] to E_ReservationDocumentItem     as _Extension                   on  $projection.Reservation           = _Extension.Reservation
                                                                                      and $projection.ReservationItem       = _Extension.ReservationItem
                                                                                      and $projection.ReservationRecordType = _Extension.RecordType
{
      // Key

      @ObjectModel.foreignKey.association: '_Reservation'
  key resb.Reservation,
      @ObjectModel.text.element: ['MaterialComponentText']
  key resb.ReservationItem,
      @ObjectModel.foreignKey.association: '_ReservationRecordType'
  key resb.RecordType                                              as ReservationRecordType,

      //Material data

      @ObjectModel.foreignKey.association: '_MaterialGroup'
      resb.MaterialGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductStdVH', element: 'Product' } } ]
      @ObjectModel.foreignKey.association: '_Material'
      resb.Material,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_Plant'
      resb.Plant,

      // Order and Operation data

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      resb.OrderCategory                                           as ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      resb.OrderType                                               as ManufacturingOrderType,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
      @ObjectModel.foreignKey.association: '_MfgOrder'
      cast(resb.OrderID as manufacturingorder preserving type)     as ManufacturingOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderSequenceStdVH', element: 'ManufacturingOrderSequence' } } ]
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      resb.Sequence                                                as ManufacturingOrderSequence,
      @ObjectModel.foreignKey.association: '_MfgOrderSequenceCategory'
      resb.SequenceCategory                                        as MfgOrderSequenceCategory,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrdOpBySemanticKeyStdVH', element: 'ManufacturingOrderOperation' } } ]
      @ObjectModel.foreignKey.association: '_MfgOrderOperationBySemKey'
      resb.OrderOperation                                          as ManufacturingOrderOperation,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      resb.ProductionPlant,
      @ObjectModel.foreignKey.association: '_OrderInternalID'
      resb.OrderInternalID,
      @ObjectModel.foreignKey.association: '_MfgOrderOperation'
      resb.OrderOperationInternalID,
      @ObjectModel.foreignKey.association: '_AssemblyMRPController'
      cast(afko.MRPController as assymrpcontrl preserving type)    as AssemblyMRPController,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      afko.ProductionSupervisor,

      // Date and Time

      @Semantics.businessDate.at: true
      resb.MatlCompRequirementDate,
      resb.MatlCompRequirementTime,
      resb.LatestRequirementDate,
      afko.ActualReleasedDate                                      as MfgOrderActualReleaseDate,

      // Attributes

      resb.ReservationItemCreationCode,
      resb.ReservationIsFinallyIssued,
      resb.MatlCompIsMarkedForDeletion,
      resb.MaterialComponentIsMissing,
      resb.IsBulkMaterialComponent,
      resb.MatlCompIsMarkedForBackflush,
      resb.MatlCompIsTextItem,
      resb.MaterialPlanningRelevance,
      resb.MatlCompIsConfigurable,
      resb.MaterialComponentIsClassified,
      resb.MaterialCompIsIntraMaterial,
      resb.MaterialIsDirectlyProduced,
      resb.MaterialIsDirectlyProcured,

      // Text

      @Semantics.text: true
      resb.MaterialComponentText,
      @Semantics.text: true
      resb.MaterialComponentSecondText,
      resb.MaterialComponentHasLongText, 
      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      resb.LongTextLanguage,

      // Assignments

      @ObjectModel.foreignKey.association: '_RequirementType'
      resb.RequirementType,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderStdVH', element: 'SalesOrder' } } ]
      @ObjectModel.foreignKey.association: '_SalesOrder'
      resb.SalesOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderItemStdVH', element: 'SalesOrderItem' } } ]
      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      resb.SalesOrderItem,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElementBasicDataStdVH', element: 'WBSElementInternalID' } } ]
      @ObjectModel.foreignKey.association: '_WBSElementBasicData'
      resb.WBSElementInternalID,
      resb.ProductConfiguration,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ChangeMasterStdVH', element: 'ChangeNumber' } } ]
      @ObjectModel.foreignKey.association: '_ChangeNumber'
      resb.ChangeNumber,
      resb.MaterialRevisionLevel,
      resb.EffectivityParameterVariant,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'MaterialComponentSortText'
      resb.MatlCompFreeDefinedAttribute,
      resb.MaterialComponentSortText,
      resb.ObjectInternalID,

      // Assignments BOM

      resb.BillOfMaterialCategory,
      resb.BillOfMaterialInternalID,
      afko.BillOfMaterialVariantUsage,
      resb.BillOfMaterialVariant,
      cast(afko.BillOfMaterial as pph_stnum preserving type)       as BillOfMaterial,
      resb.BOMItem                                                 as BillOfMaterialItemNodeNumber,
      resb.BillOfMaterialVersion,
      resb.BOMItemInternalChangeCount,
      resb.InheritedBOMItemNode,
      resb.BOMItemCategory                                         as BillOfMaterialItemCategory,
      resb.BillOfMaterialItemNumber,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'MaterialComponentText'
      resb.BOMItemDescription,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'MaterialComponentSecondText'
      resb.BOMItemText2,
      @ObjectModel.foreignKey.association: '_BOMExplosion'
      resb.BOMExplosionDateID,

      // Assignments Purchasing

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PurchasingInfoRecordStdVH', element: 'PurchasingInfoRecord' } } ]      
      resb.PurchasingInfoRecord,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      resb.PurchasingGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PurchaseRequisitionStdVH', element: 'PurchaseRequisition' } } ]
      resb.PurchaseRequisition,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PurchaseRequisitionItemStdVH', element: 'PurchaseRequisitionItem' } } ]
      resb.PurchaseRequisitionItem,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PurchaseOrderStdVH', element: 'PurchaseOrder' } } ]
      resb.PurchaseOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PurchaseOrderItemStdVH', element: 'PurchaseOrderItem' } } ]
      resb.PurchaseOrderItem,
      resb.PurchaseOrderScheduleLine,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_Supplier_VH', element: 'Supplier' } } ]
      @ObjectModel.foreignKey.association: '_Supplier'
      resb.Supplier,
      resb.DeliveryDurationInDays,
      resb.MaterialGoodsReceiptDuration,
      -- Price
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      resb.ExternalProcessingPrice,
      resb.NumberOfPriceUnits                                      as NumberOfOperationPriceUnits,   

      // Goods Movement data

      resb.GoodsMovementIsAllowed,
      @ObjectModel.foreignKey.association: '_StorageLocation'
      resb.StorageLocation,
      @ObjectModel.foreignKey.association: '_DebitCreditCode'
      resb.DebitCreditCode,
      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      resb.GoodsMovementType,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
      resb.InventorySpecialStockType,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockValnType'
      resb.InventorySpecialStockValnType,
      @ObjectModel.foreignKey.association: '_ConsumptionPosting'
      resb.ConsumptionPosting,
      @ObjectModel.foreignKey.association: '_SupplyArea'
      resb.SupplyArea,
      @Semantics.text: true
      resb.GoodsRecipientName,
      @Semantics.text: true
      resb.UnloadingPointName,
      resb.StockSegment,
      resb.RequirementSegment,

      // Batch data

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BatchStdVH', element: 'Batch' } } ]
      @ObjectModel.foreignKey.association: '_Batch'
      resb.Batch,
--    @ObjectModel.foreignKey.association: '_BatchEntryDetermination'         
      resb.BatchEntryDeterminationCode,
      @ObjectModel.foreignKey.association: '_BatchSplitType'      
      resb.BatchSplitType,
      resb.BatchMasterReservationItem,
      resb.BatchClassification,

      // Assignments WM

      resb.MaterialStaging,
      @ObjectModel.foreignKey.association: '_Warehouse'
      resb.Warehouse,
      resb.StorageType,
      resb.StorageBin,

      // Assignments FI/CO

      resb.MaterialCompCostingRelevancy,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } } ]
      @ObjectModel.foreignKey.association: '_BusinessArea'
      resb.BusinessArea,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      @ObjectModel.foreignKey.association: '_CompanyCode'
      resb.CompanyCode,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_GLAccountStdVH', element: 'GLAccount' } } ]
      @ObjectModel.foreignKey.association: '_GLAccount'
      resb.GLAccount,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      resb.FunctionalArea,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      resb.ControllingArea,
      @ObjectModel.foreignKey.association: '_AccountAssignmentCategory'
      resb.AccountAssignmentCategory,
      @ObjectModel.foreignKey.association: '_EarmarkedFunds'
      resb.EarmarkedFundsDocument,
--    @ObjectModel.foreignKey.association: '_EarmarkedFundsItem'
      resb.EarmarkedFundsDocumentItem,
--    @ObjectModel.foreignKey.association: '_FundsCenter'    
      resb.FundsCenter,
--    @ObjectModel.foreignKey.association: '_Fund'
      resb.Fund,
--    @ObjectModel.foreignKey.association: '_CommitmentItem'
      resb.CommitmentItem,
      resb.CommitmentItemShortID,

      // Variable-size item data

      resb.MaterialCompIsVariableSized,
      @Semantics.unitOfMeasure: true
      -- Item quantity (ROANZ and ROAME)
      resb.VariableSizeItemUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeItemUnit'
      @Aggregation.default: #SUM
      resb.VariableSizeItemQuantity,
      -- Component quantity (ROKME and ROMEN) 
      @Semantics.unitOfMeasure: true
      resb.VariableSizeComponentUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      @Aggregation.default: #SUM
      resb.VariableSizeComponentQuantity,
      -- Dimensions (ROMEI and ROMSn)
      @Semantics.unitOfMeasure: true
      resb.VariableSizeDimensionUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      @Aggregation.default: #MAX
      resb.VariableSizeDimension1,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      @Aggregation.default: #MAX
      resb.VariableSizeDimension2,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      @Aggregation.default: #MAX
      resb.VariableSizeDimension3,
      resb.VariableSizeCompFormulaKey,
 
      // Alternative item data

      resb.MaterialCompIsAlternativeItem,
      resb.AlternativeItemGroup,
      resb.AlternativeItemStrategy,
      resb.AlternativeItemPriority,
      resb.UsageProbabilityPercent,
      resb.AlternativeMstrReservationItem,

      // Phantom assembly

      resb.MaterialComponentIsPhantomItem,
      resb.OrderPathValue,
      resb.OrderLevelValue,
      @ObjectModel.foreignKey.association: '_PhantomAssembly'
      resb.Assembly,
      resb.AssemblyOrderPathValue,
      resb.AssemblyOrderLevelValue,

      // Discontinuation

      resb.DiscontinuationGroup,
      @ObjectModel.foreignKey.association: '_DiscontinuationType'
      resb.MatlCompDiscontinuationType,
      resb.MatlCompIsFollowUpMaterial,
      resb.FollowUpGroup,
      @ObjectModel.foreignKey.association: '_FollowUpMaterial'
      resb.FollowUpMaterial,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'FollowUpMaterialIsActive'
      resb.FollowUpMaterialIsNotActive,
      resb.FollowUpMaterialIsActive,
      resb.DiscontinuationMasterResvnItem,

      // Material provision

      @ObjectModel.foreignKey.association: '_ProvisionType'
      resb.MaterialProvisionType,

      // Spare part

      @ObjectModel.foreignKey.association: '_SparePartType'
      resb.MatlComponentSparePartType,

      // Lead-Time offset

      resb.LeadTimeOffset,
      @Semantics.unitOfMeasure: true
      resb.OperationLeadTimeOffsetUnit,
      resb.OperationLeadTimeOffset,

      // Quantities and UoM

      resb.QuantityIsFixed,
      resb.IsNetScrap,
      resb.ComponentScrapInPercent,
      resb.OperationScrapInPercent,
      resb.MaterialQtyToBaseQtyNmrtr,
      resb.MaterialQtyToBaseQtyDnmntr,
      -- Base unit
      @Semantics.unitOfMeasure: true
      resb.BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      resb.RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      resb.WithdrawnQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      resb.ConfirmedAvailableQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      resb.MaterialCompOriginalQuantity,
      -- Entry unit
      @Semantics.unitOfMeasure: true
      resb.EntryUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      @Aggregation.default: #SUM
      resb.GoodsMovementEntryQty,

      // Amount and Currency

      @Semantics.currencyCode: true
      resb.Currency,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      resb.WithdrawnQuantityAmount,

      // Fashion Manufacturing Fields

      resb.CriticalComponentType,
      resb.CriticalComponentLevel,
            
      // Associations

      _Reservation,
      _ReservationItem,
      _ReservationRecordType,
      _MfgOrder,
      _MfgOrderCategory,
      _MfgOrderType,
      _MfgOrderOperation,
      _MfgOrderOperationBySemKey,
      _MfgOrderSequence,
      resb._SequenceCategory as _MfgOrderSequenceCategory,
      _MfgOrderComponentLongText,
      @Consumption.hidden: true
      resb._OrderInternalID,
      resb._ProductionPlant,
      _AssemblyMRPController,
      _ProductionSupervisor,
      resb._RequirementType,
      resb._MaterialGroup,
      resb._Material,
      resb._Product,
      resb._ProductPlant,
      resb._ProductStorageLocation,
      _ProductSupplyPlanning,
      _ProductUnitsOfMeasure,
      resb._Plant,
      resb._StorageLocation,
      resb._Batch,
      resb._BatchSplitType,
      resb._DebitCreditCode,
      resb._GoodsMovementType,
      resb._InventorySpecialStockType,
      resb._InventorySpecialStockValnType,
      resb._ConsumptionPosting,
      resb._SupplyArea,
      resb._Warehouse,
      resb._FollowUpMaterial,
      resb._DiscontinuationType,
      resb._ProvisionType,
      resb._SparePartType,
      resb._PhantomAssembly,
      resb._BOMExplosion,
      resb._BillOfMaterialItem,
      resb._BOMItemCategory,
      resb._SalesOrder,
      resb._SalesOrderItem,
      resb._WBSElementBasicData,
      resb._ChangeNumber,
      resb._MaterialRevisionLevel,
      resb._PurchasingGroup,
      resb._PurchasingInfoRecord,
      resb._PurchaseOrder,
      resb._PurchaseOrderItem,
      resb._PurchaseRequisition,
      resb._PurchaseRequisitionItem,
      resb._Supplier,
      @Consumption.hidden: true
      _SupplierCompanyByPlant,
      resb._CompanyCode,
      resb._BusinessArea,
      resb._GLAccount,
      resb._ControllingArea,
      resb._FunctionalArea,
      resb._AccountAssignmentCategory,
      resb._EarmarkedFunds,
      resb._EarmarkedFundsItem,
      resb._Fund,
      resb._FundsCenter,
      resb._CommitmentItem,
      resb._CommitmentItemShortID,
      resb._OpLeadTimeOffsetUnit,
      resb._VariableSizeItemUnit,
      resb._VariableSizeComponentUnit as _VariableSizeCompUnit,
      resb._BaseUnit,
      resb._EntryUnit,
      resb._Currency,
      resb._LongTextLanguage,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_MfgOrderComponentLongText'
      resb._LongText
}
where
    ( resb.OrderCategory = '10' or     // Manufacturing Orders only

      resb.OrderCategory = '40' ) and
      resb.MaterialIsCoProduct =  '';  // no Co-Products