I_ORDEROPERATIONBASIC

@AbapCatalog.sqlViewName: 'IORDEROPBASIC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_LongText']
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'OrderOperationInternalID'
@ObjectModel.semanticKey: ['OrderInternalID', 'OrderOperationInternalID']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API  // status "not to be released - but kept stable"

@VDM.viewType: #BASIC
@EndUserText.label: 'Order Operation Basic'
// Basic reuse view for order operations' main table AFVC 

// For reuse view including joins to AFVV and AFVU refer to CDS I_OrderOperation

// Due to the high number of consumers, this CDS view is protected against incompatible changes


define view I_OrderOperationBasic
  as select from afvc as afvc

  association [1..1] to I_OrderInternalID as _OrderInternalID        on  $projection.OrderInternalID = _OrderInternalID.OrderInternalID
  association [0..1] to I_Currency        as _Currency               on  $projection.Currency = _Currency.Currency
  association [0..1] to I_WorkCenter      as _WorkCenterByInternalID on  _WorkCenterByInternalID.WorkCenterTypeCode = 'A '
                                                                     and $projection.WorkCenterInternalID = _WorkCenterByInternalID.WorkCenterInternalID
  association [0..1] to I_OrderOperationLongText as _LongText        on  $projection.OrderInternalID          = _LongText.OrderInternalID
                                                                     and $projection.OrderOperationInternalID = _LongText.OrderOperationInternalID
{
      // Key

      @ObjectModel.foreignKey.association: '_OrderInternalID'
  key afvc.aufpl as OrderInternalID,
  key afvc.aplzl as OrderOperationInternalID,

      // Semantic key

      afvc.aplfl as Sequence,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'Operation_2'
      afvc.vornr as Operation,                                      // with conv. exit NUMCV

      cast(afvc.vornr as vdm_vornr preserving type) as Operation_2, // without conversion exit


      // Text

      afvc.ktsch as StandardTextInternalID,
      @Semantics.text: true
      afvc.ltxa1 as OperationText,
      @Semantics.text: true
      afvc.ltxa2 as OperationSecondText,
      afvc.txtsp as Language,
      cast(case 
             when afvc.txtsp <> '' then 'X'
             else afvc.txtsp
      end as aufltext preserving type)                     as OperationHasLongText,

      // BOO data

      afvc.plnfl as BillOfOperationsSequence,
      afvc.plnty as BillOfOperationsType,
      afvc.plnnr as BillOfOperationsGroup,
      afvc.plnal as BillOfOperationsVariant,
      afvc.plnkn as BOOOperationInternalID,
      afvc.tl_versn as BillOfOperationsVersion,

      // Assignments

      afvc.sumnr as SuperiorOperationInternalID,
      afvc.steus as OperationControlProfile,
      afvc.arbid as WorkCenterInternalID,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'WorkCenterTypeCode_2'
      'A'        as WorkCenterTypeCode,  // do not use for associations

      'A '       as WorkCenterTypeCode_2,
      afvc.werks as Plant,
      afvc.kalid as FactoryCalendar,
      afvc.objnr as ObjectInternalID,
      afvc.bedid as CapacityRequirement,
      afvc.bedzl as CapacityRequirementItem,
      afvc.anzzl as NumberOfCapacities,
      afvc.mlstn as UsageCode,
      afvc.istru as Assembly,
      cast(afvc.projn as ps_s4_proj_pspnr preserving type) as ProjectInternalID,
      afvc.rueck as OperationConfirmation,
      afvc.rmzhl as NumberOfOperationConfirmations,
      afvc.aennr as ChangeNumber,
      afvc.pernr as OperationPersonResponsible,
      afvc.equnr as Equipment,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'FunctionalLocation_2'
      afvc.tplnr as FunctionalLocation,                                             // with conv. exit NUMCV

      cast(afvc.tplnr as vdm_eam_tplnr preserving type)    as FunctionalLocation_2, // without conversion exit


      // Subcontracting/Purchasing

      afvc.sortl as OperationPurgInfoRecdSearchTxt,
      @Semantics.booleanIndicator
      afvc.frdlb as ExtProcgOperationHasSubcontrg,
      afvc.kzfix as PurgInfoRecdDataIsFixed,
      afvc.infnr as PurchasingInfoRecord,
      afvc.esokz as PurchasingInfoRecordCategory,
      afvc.ekorg as PurchasingOrganization,
      afvc.ekgrp as PurchasingGroup,
      afvc.banfn as PurchaseRequisition,
      afvc.bnfpo as PurchaseRequisitionItem,
      afvc.ebeln as PurchasingDocument,
      afvc.ebelp as PurchasingDocumentItem,
      afvc.matkl as MaterialGroup,
      afvc.wempf as GoodsRecipientName,
      afvc.ablad as UnloadingPointName,

      // FI/CO Data

      afvc.bukrs as CompanyCode,
      afvc.gsber as BusinessArea,
      afvc.prctr as ProfitCenter,
      afvc.sakto as CostElement,
      afvc.klvar as CostingVariant,
      afvc.kalnr as CostEstimate,
      afvc.kalsm as CostingSheet,
      afvc.anfko as RequestingCostCenter,
      afvc.indet as OperationCalculationControl,
      afvc.selkz as OperationCostingRelevancyType,
      afvc.netzkont as NtwkAccountAssignmentCode,
      afvc.clasf as ActyIsTakenAcctForProjSmmry,
      afvc.owaer as ControllingObjectCurrency,
      cast(afvc.scope as pph_scope preserving type) as ControllingObjectClass,
      afvc.txjcd as TaxJurisdiction,
      afvc.func_area as FunctionalArea,
      afvc.larnt as CostCtrActivityType,
      @Semantics.currencyCode: true
      afvc.waers as Currency,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      afvc.prkst as PlannedActivityCost,
      
      // Setup and Overlapping

      afvc.rfgrp as OperationSetupGroupCategory,
      afvc.rfsch as OperationSetupGroup, 
      afvc.rasch as OperationSetupType,
      afvc.uemus as OperationOverlappingIsRequired,
      afvc.uekan as OperationOverlappingIsPossible,
      afvc.flies as OperationsIsAlwaysOverlapping,
      afvc.spmus as OperationSplitIsRequired,
      afvc.splim as MaximumNumberOfSplits,
      afvc.rstra as LeadTimeReductionStrategy,
      afvc.zschl as OverheadCode,

      // Others

      afvc.phflg as MfgOrderOperationIsPhase,
      afvc.pvzkn as OrderIntBillOfOpItemOfPhase,
      afvc.nprio as OperationImportance,
      afvc.spanz as ActualNumberOfSplits,
      afvc.loekz as OperationIsToBeDeleted,
      afvc.pprio as NetworkActivityPriority,
      afvc.aufak as OperationScrapPercent,
      afvc.anlzu as OperationSystemCondition,
      afvc.prznt as OperationWorkPercent,
      
      // EAM

      cast(afvc.maintopexecutionphasecode as eam_premainpost_cds preserving type) as MaintOperationExecStageCode,
      afvc.maintordopprocessphasecode                                             as MaintOrdOpProcessPhaseCode,
      afvc.maintordopprocesssubphasecode                                          as MaintOrdOpProcessSubPhaseCode,      
      
      // OAN specific fields

      afvc.oan_inst_id_setup    as SetupOpActyNtwkInstance,
      afvc.oan_inst_id_produce  as ProduceOpActyNtwkInstance,
      afvc.oan_inst_id_teardown as TeardownOpActyNtwkInstance,
      
      // Associations

      _OrderInternalID,
      _Currency,
      _WorkCenterByInternalID,
      _LongText
};