R_InternalOrderTP

 @AccessControl: {
  authorizationCheck: #CHECK,
  privilegedAssociations: [
  '_InternalOrderIsLocked',
  '_IntOrdSettlementRuleIsCreated'
  ]
}
@EndUserText.label: 'Internal Order'

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.semanticKey: [ 'InternalOrder' ]
@ObjectModel.sapObjectNodeType.name: 'InternalOrder'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

define root view entity R_InternalOrderTP
  as select from I_InternalOrder

  composition [0..*] of R_InternalOrderSystemStatusTP  as _InternalOrderSystemStatusTP

  composition [0..*] of R_IntOrderNumberedUserStatusTP as _IntOrderNumberedUserStatusTP

  composition [0..*] of R_IntOrdUnnumberedUserStatusTP as _IntOrdUnnumberedUserStatusTP

  composition [0..*] of R_IntOrdOverallSystemStatusTP  as _IntOrdOverallSystemStatusTP

  composition [0..*] of R_IntOrdLongDescriptionDraftTP as _IntOrdLongDescriptionDraftTP

  association [0..1] to I_StatusObjectStatusBasic      as _InternalOrderIsLocked         on  I_InternalOrder.ControllingObject = _InternalOrderIsLocked.StatusObject
                                                                                         and _InternalOrderIsLocked.StatusCode = 'I0043'

  association [0..1] to I_StatusObjectStatusBasic      as _IntOrdSettlementRuleIsCreated on  I_InternalOrder.ControllingObject               = _IntOrdSettlementRuleIsCreated.StatusObject
                                                                                         and (
                                                                                            _IntOrdSettlementRuleIsCreated.StatusCode        = 'I0028'
                                                                                            or _IntOrdSettlementRuleIsCreated.StatusCode     = 'I0027'
                                                                                          )
                                                                                         and _IntOrdSettlementRuleIsCreated.StatusIsInactive = ''

  association [0..1] to I_StatusObjectStatusBasic      as _IntOrdDeletionFlagIsSet       on  I_InternalOrder.ControllingObject   = _IntOrdDeletionFlagIsSet.StatusObject
                                                                                         and _IntOrdDeletionFlagIsSet.StatusCode = 'I0076'

  association [0..1] to I_StatusObjectStatusBasic      as _IntOrdIsMarkedForDeletion     on  I_InternalOrder.ControllingObject     = _IntOrdIsMarkedForDeletion.StatusObject
                                                                                         and _IntOrdIsMarkedForDeletion.StatusCode = 'I0013'

  association [0..1] to I_TaxJurisdiction              as _TaxJurisdiction               on  $projection.TaxJurisdiction = _TaxJurisdiction.TaxJurisdiction

{
  key InternalOrder,
  key cast('00000000000000000000000000000000' as sysuuid_c32)                           as InternalOrderDraftInternalUUID,
      @ObjectModel.editableFieldFor: 'InternalOrder'
      InternalOrder                                                                     as InternalOrderForEdit,
      cast( InternalOrderDescription as kltxt )                                         as InternalOrderDescription,
      OrderCategory,
      BusinessArea,
      @ObjectModel.text.association:null
      ControllingArea,
      Plant,
      Currency,
      IsStatisticalOrder,
      ReferenceOrder,
      SalesOrder,
      SalesOrderItem,
      WBSElementInternalID,
      _WBSElementBasicData.WBSElementExternalID,
      RequestingCostCenter,
      RequestingCompanyCode,
      RequestingOrder,
      InternalOrderLocation,
      LocationPlant,
      ExternalOrder,
      ActualPostedCostCenter,
      CostCenter,
      LogicalSystem,
      OrdIsUsedInIntegratedPlanning,
      ResultAnalysisInternalID,
      ConditionUsage,
      ConditionApplication,
      CostingSheet,
      OverheadCode,
      OrderInterestCalcProfile,
      IntOrderSettlementCostElement,
      BasicSettlementGLAccount,
      IntOrderIndividualField1Value,
      IntOrderIndividualField2Value,
      IntOrderIndividualField3Value,
      IntOrderIndividualField4Value,
      IntOrderIndividualField5Amount,
      IntOrderIndividualField6Date,
      IntOrderIndividualField7Value,
      IntOrderIndividualField8Date,
      IntOrderIndividualField9Date,
      cast ( IntOrderIndividualField10Value as fco_io_aufuser9 preserving type )        as IntOrderIndividualField10Value,
      OrderProcessingGroup,
      InvestmentProfile,
      InvestmentScale,
      InvestmentReason,
      EnvironmentalInvestmentReason,
      JointVenture,
      JointVentureRecoveryCode,
      JointVentureEquityType,
      JointVentureOriginalCostObject,
      JointVentureObjectType,
      JointVentureClass,
      JointVentureSubClass,
      case _IntOrdIsMarkedForDeletion.StatusIsInactive
        when 'X' then cast ('' as fco_io_markedfordeletion preserving type )
        when '' then cast ('X' as fco_io_markedfordeletion preserving type )
        else cast ('' as fco_io_markedfordeletion preserving type )
      end                                                                               as InternalOrderIsDeleted,
      case _IntOrdDeletionFlagIsSet.StatusIsInactive
        when 'X' then cast ('' as fco_io_deletionflag preserving type )
        when '' then cast ('X' as fco_io_deletionflag preserving type )
        else cast ('' as fco_io_deletionflag preserving type )
      end                                                                               as InternalOrderDeletionFlagIsSet,
      CreationDate,
      CreationTime,
      CreatedByUser,
      cast ( LastChangedByUser as fco_io_aufaenam preserving type )                     as LastChangedByUser,
      LastChangeDate,
      LastChangeTime,

      @Semantics.systemDateTime.lastChangedAt: true
      cast( dats_tims_to_tstmp( LastChangeDate,
                          LastChangeTime,
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client,
                         'NULL' ) as timestamp )                                        as LastChangeDateTime,

      ControllingObject,
      CompanyCode,
      ProfitCenter,
      FunctionalArea,
      ControllingObjectClass,
      @ObjectModel.text.association:null
      OrderType,
      ResponsibleCostCenter,
      InternalOrderResponsibleUser,
      case _InternalOrderType.CommitmentsMgmtActvtnStatus
        when '' then cast( '' as fins_co_io_obligo )
        when '1' then cast( 'X' as fins_co_io_obligo )
      end                                                                               as CommitmentsMgmtActvtnStatus,

      case substring(CostCollector, 1, 1)
        when '1'
          then cast( '' as erloese )
        when '2'
          then cast( 'X' as erloese )
      end                                                                               as RevenuePostingIsAllowed,
      @ObjectModel.text.association:null
      _SystemStatus.ControllingObjectStatus,
      _SystemStatus._Text[1: Language = $session.system_language].SystemStatusShortName as IntOrderSystemStatusShortName,
      _SystemStatus._Text[1: Language = $session.system_language].StatusName            as InternalOrderSystemStatusName,
      case _InternalOrderIsLocked.StatusIsInactive
        when 'X' then cast ('' as fco_io_lock preserving type )
        when '' then cast ('X' as fco_io_lock preserving type )
        else cast ('' as fco_io_lock preserving type )
        end                                                                             as InternalOrderIsLocked,
      case _IntOrdSettlementRuleIsCreated.StatusIsInactive
        when 'X' then cast ('' as fco_io_settl_rule_created preserving type )
        when '' then cast ('X' as fco_io_settl_rule_created preserving type )
        else cast ('' as fco_io_settl_rule_created preserving type )
        end                                                                             as IntOrdSettlementRuleIsCreated,
      TaxJurisdiction,

      /* Associations */
      _ActualPostedCostCenter,
      _BasicSettlementGLAccount,
      _CompanyCode,
      _ConditionApplication,
      _ConditionUsage,
      _ControllingArea,
      _ControllingAreaText,
      _ControllingObjectClass,
      _CostCenter,
      _CostCenterData,
      _CostingSheetProcedure,
      _EnvrnmtlInvestmentReason,
      _FunctionalArea,
      _InternalOrderType,
      _InternalOrderTypeText,
      _IntOrderSettlementCostElement,
      _InvestmentObjectScale,
      _InvestmentProfile,
      _InvestmentReason,
      _JntIntrstBillgClass,
      _JntIntrstBillgSubclass,
      _JntVntrEquityTypeMaster,
      _JointVentureRecovery,
      _Location,
      _LocationPlant,
      _LogicalSystem,
      _OrderProcessingGroup,
      _ProfitCenter,
      _RequestingCompanyCode,
      _RequestingCostCenter,
      _RequestingOrder,
      _ResultsAnalysisKey,
      _ResponsibleUser,
      _CreatedByUser,
      _LastChangedByUser,
      _CurRespCostCenterText,
      _CurRequestingCostCenterText,
      _CurCostCenterDataText,
      _SystemStatus,
      _WBSElementBasicData,
      _Currency,
      _OrderCategory,
      _Plant,
      _BusinessArea,
      _CurProfitCenterText,
      _CurActualPostedCostCenterText,
      _InternalOrderIsLocked,
      _IntOrdSettlementRuleIsCreated,
      _IntOrdDeletionFlagIsSet,
      _IntOrdIsMarkedForDeletion,
      _InternalOrderSystemStatusTP,
      _IntOrdUnnumberedUserStatusTP,
      _IntOrderNumberedUserStatusTP,
      _IntOrdOverallSystemStatusTP,
      _IntOrdLongDescriptionDraftTP,
      _TaxJurisdiction
}