R_InternalOrderSystemStatusTP

@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #MIXED
  }
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}

@AccessControl: {
  authorizationCheck: #CHECK,
  privilegedAssociations: ['_LastChangedByUser']
}
@EndUserText.label: 'Internal order system status'
define view entity R_InternalOrderSystemStatusTP
  as select from P_InternalOrderSystemStatus

  association to parent R_InternalOrderTP as _InternalOrderTP on  $projection.InternalOrder                  = _InternalOrderTP.InternalOrder
                                                              and $projection.InternalOrderDraftInternalUUID = _InternalOrderTP.InternalOrderDraftInternalUUID

{
  key InternalOrder,
  key cast('00000000000000000000000000000000' as sysuuid_c32) as InternalOrderDraftInternalUUID,
      @ObjectModel.text.association:null
  key SystemStatus,
      SystemStatusShortName,
      SystemStatusName,
      InternalOrderStatusPlannedDate,
      InternalOrderStatusReachedDate,
      ControllingObject,
      LastChangedByUser,
      cast ('' as fin_io_status_is_active)                    as IsActive,
      IntOrdSystemStatusCriticality,
      //      cast( '0' as fin_io_status_criticality preserving type ) as IntOrdSystemStatusCriticality,


      _InternalOrderTP,
      _LastChangedByUser
}