R_IntOrdLongDescriptionDraftTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Internal Order Long Description'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #CUSTOMIZING
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
define view entity R_IntOrdLongDescriptionDraftTP
  as select from P_InternalOrderLongDescription

  association to parent R_InternalOrderTP as _InternalOrderTP on  $projection.InternalOrder                  = _InternalOrderTP.InternalOrder
                                                              and $projection.InternalOrderDraftInternalUUID = _InternalOrderTP.InternalOrderDraftInternalUUID

{
  key InternalOrder,
  key cast('00000000000000000000000000000000' as sysuuid_c32) as InternalOrderDraftInternalUUID,
  key TextObjectType,
  key TextObjectCategory,
  key Language,
  key cast('00000000000000000000000000000000' as sysuuid_c32) as IntOrderLongDescriptionUUID,
      @ObjectModel.editableFieldFor: 'Language'
      Language                                                as LanguageForEdit,
      IntOrdLongDescIsAvailable,

      _TextObjectType,
      _TextObjectCategory,
      _Language,

      _InternalOrderTP
}