R_InsurPlcySubcoverageTP_2

@EndUserText.label: 'Subcoverage'
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@AccessControl: {
authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   semanticKey: [ 'InsurPlcyInsuranceSubCoverage' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}

@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'SBC',
  allowNewDatasources: false,
  dataSources: [ '_Extension' ],
  allowNewCompositions: true,
  quota: {
    maximumFields: 250,
    maximumBytes: 2500
  }
}
@ObjectModel.sapObjectNodeType.name: 'InsuranceSubcoverage'

define root view entity R_InsurPlcySubcoverageTP_2
  as select from I_InsurPlcySubCoverageBasic

  association [1..1] to E_InsurancePolicySubCoverage  as _Extension on  $projection.InsurPlcyUUID              = _Extension.InsurPlcyUUID
                                                                    and $projection.InsurPlcyInsurContr        = _Extension.InsurPlcyInsurContr
                                                                    and $projection.InsurPlcyCoveragePackageID = _Extension.InsurPlcyCoveragePackageID
                                                                    and $projection.InsurPlcyCoverageID        = _Extension.InsurPlcyCoverageID
                                                                    and $projection.InsurPlcySubCvrgID         = _Extension.InsurPlcySubCvrgID
                                                                    and $projection.InsurPlcyJrnlNmbr          = _Extension.InsurPlcyJrnlNmbr
                                                                    and $projection.InsurPlcyJrnlEndNmbr       = _Extension.InsurPlcyJrnlEndNmbr

  composition [0..*] of R_InsurPlcySbcvrgLimitTP      as _Limit
  composition [0..*] of R_InsurPlcySbcvrgDeductibleTP as _Deductible
  composition [0..*] of R_InsurPlcySbcvrgClauseTP     as _Clause
  association [1..1] to R_InsurancePolicyTP_2         as _Policy    on  $projection.InsurPlcyUUID = _Policy.InsurPlcyUUID

{
  key InsurPlcyUUID,
  key InsurPlcyInsurContr,
  key InsurPlcyCoveragePackageID,
  key InsurPlcyCoverageID,
  key InsurPlcySubCvrgID,
      _Policy.InsrrIDByInsrr,
      _Policy.InsurPlcyAuthznSlsProductGroup,
      InsurPlcyJrnlNmbr,
      InsurPlcyJrnlEndNmbr,
      InsurPlcyProductPackageID,
      InsurPlcyInsuranceSubCoverage,
      InsurPlcySubCoverageTemplate,
      InsurPlcySubCoverageStartDate,
      InsurPlcySubCoverageEndDate,
      InsurPlcySubCvrgInsrdSumAmount,
      InsurPlcySubCoverageCurrency,
      InsurPlcySubCvrgInsuredSumPct,
      InsurPlcySubCvrgInsrdSumCalc,
      InsurPlcyBusinessObject,
      LastChangeDateTime,
      InsurPlcySbcvrgIsCanceled,
      InsurPlcySubcoverageType,
      InsurPlcySubcoverageRankValue,
      InsurPlcySbcvrgGrssPremBfrAmt,
      InsurPlcySbcvrgPremCrrtnAmt,
      InsurPlcySbcvrgSuplmntAmt,
      InsurPlcySubcoverageNmbrValue,

      /* Associations */
      _Limit,
      _Deductible,
      _Clause

}