A_InsurOpnApplSubcoverage

@EndUserText.label: 'Subcoverage'
@VDM: {
  viewType:#CONSUMPTION,
  lifecycle.contract.type:#PUBLIC_REMOTE_API,
  usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
}
@AccessControl: {
authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_Clause',
                            '_Limit',
                            '_Deductible' ]
}
@Metadata: {
  ignorePropagatedAnnotations:true
}
@ObjectModel: {
   semanticKey: [ 'InsurPlcySubCvrgID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@OData.entityType.name: 'InsurOpnApplSubcoverage_Type'
@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'SBC',
  allowNewDatasources: false,
  dataSources: [ 'Subcoverage' ],
  allowNewCompositions: true,
  quota: {
    maximumFields: 250,
    maximumBytes: 2500
  }
}
define root view entity A_InsurOpnApplSubcoverage
  provider contract transactional_query
  as projection on R_InsurPlcySubcoverageTP_2 as Subcoverage
{
                @ObjectModel.virtualElement: true
                @ObjectModel.filter.transformedBy: 'ABAP:/PM0/CL_ABP_VDM_VE_F_PPD_POLID'
  key           InsurPlcyUUID,
  key           InsurPlcyInsurContr,
  key           InsurPlcyCoveragePackageID,
  key           InsurPlcyCoverageID,
  key           InsurPlcySubCvrgID,
                InsrrIDByInsrr,
                InsurPlcyAuthznSlsProductGroup,
                InsurPlcyJrnlNmbr,
                InsurPlcyJrnlEndNmbr,
                InsurPlcyProductPackageID,
                @ObjectModel.virtualElement: true
                @ObjectModel.filter.transformedBy: 'ABAP:/PM0/CL_ABP_VDM_VE_F_PPD_EFFDT'
                @ObjectModel.virtualElementCalculatedBy: 'ABAP:/PM0/CL_ABP_VDM_VE_C_EFFDT'
  virtual       InsurancePolicyEffectiveDate : /pm0/abd_effective_dt,
                @ObjectModel.virtualElement: true
                @ObjectModel.filter.transformedBy: 'ABAP:/PM0/CL_ABP_VDM_VE_F_PPD_ORDNO'
                @ObjectModel.virtualElementCalculatedBy: 'ABAP:/PM0/CL_ABP_VDM_VE_C_ORDNO'
  virtual       InsurPlcyOrderNumber         : /pm0/abj_orderno_id,
                InsurPlcyInsuranceSubCoverage,
                InsurPlcySubCoverageTemplate,
                InsurPlcySubCoverageStartDate,
                InsurPlcySubCoverageEndDate,
                @Semantics.amount.currencyCode: 'InsurPlcySubCoverageCurrency'
                InsurPlcySubCvrgInsrdSumAmount,
                @ObjectModel.sapObjectNodeTypeReference: 'Currency'
                InsurPlcySubCoverageCurrency,
                InsurPlcySubCvrgInsuredSumPct,
                InsurPlcySubCvrgInsrdSumCalc,
                InsurPlcyBusinessObject,
                LastChangeDateTime,
                InsurPlcySbcvrgIsCanceled,
                InsurPlcySubcoverageType,
                InsurPlcySubcoverageRankValue,
                @Semantics.amount.currencyCode: 'InsurPlcySubCoverageCurrency'
                InsurPlcySbcvrgGrssPremBfrAmt,
                @Semantics.amount.currencyCode: 'InsurPlcySubCoverageCurrency'
                InsurPlcySbcvrgPremCrrtnAmt,
                @Semantics.amount.currencyCode: 'InsurPlcySubCoverageCurrency'
                InsurPlcySbcvrgSuplmntAmt,
                InsurPlcySubcoverageNmbrValue,
                /* Associations */
                _Clause     : redirected to composition child A_InsOpApSubcoverageClause,
                _Deductible : redirected to composition child A_InsurOpnApplSbcvrgDeductible,
                _Limit      : redirected to composition child A_InsurOpnApplSubcoverageLimit
}