R_InsurancePolicyTP_2

@EndUserText.label: 'Policy - TP'
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@ObjectModel: {
   semanticKey: [ 'InsurancePolicy' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@ObjectModel.sapObjectNodeType.name: 'InsurancePolicy'
@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'POL',
  allowNewDatasources: false,
  allowNewCompositions: true,
  dataSources: [ '_Extension' ],
  quota: {
    maximumFields: 408, /*as per business context defined in CFD_REGISTERY max is 408 allowed*/
    maximumBytes: 8160
  }
}
define root view entity R_InsurancePolicyTP_2
  as select from I_InsurPlcyBasic as Policy

  composition [1..*] of R_InsurPlcyPolicyHolderTP_2    as _PolicyHolder      //on  $projection.InsurPlcyUUID = _PolicyHolder.InsurPlcyUUID

  composition [0..*] of R_InsurPlcyReltdContractTP     as _RelatedContract   //on  $projection.InsurPlcyUUID = _RelatedContract.InsurPlcyUUID

  composition [0..*] of R_InsurPlcyExternalReferenceTP as _ExternalReference //on  $projection.InsurPlcyUUID = _ExternalReference.InsurPlcyUUID

  composition [0..*] of R_InsurPlcyAgentTP             as _Agent             //on  $projection.InsurPlcyUUID = _Agent.InsurPlcyUUID

  composition [0..*] of R_InsurPlcyClauseTP_2          as _Clause            //on  $projection.InsurPlcyUUID = _Clause.InsurPlcyUUID

  composition [0..*] of R_InsurPlcyCommissionTP        as _Commission        //on  $projection.InsurPlcyUUID = _Commission.InsurPlcyUUID

  composition [0..*] of R_InsurPlcyDistrPlnRelshpTP    as _DistributionPlan  //on  $projection.InsurPlcyUUID = _DistributionPlan.InsurPlcyUUID

  composition [0..*] of R_InsurPlcyContrBndlTP         as _ContractBundle    //on  $projection.InsurPlcyUUID = _ContractBundle.InsurPlcyUUID

  composition [0..*] of R_InsurPlcyDistrPlnRelshpTP_2  as _DistributionPlan_2

  association [0..*] to R_InsurPlcyContractTP          as _Contract                  on  $projection.InsurPlcyUUID = _Contract.InsurPlcyUUID
  association [1..*] to R_InsurPlcyContrJrnlHdrTP      as _ContractJournalHeader     on  $projection.InsurPlcyUUID = _ContractJournalHeader.InsurPlcyUUID
  association [0..*] to R_InsurPlcyApplJrnlHdrTP       as _ApplicationJournalHeader  on  $projection.InsurPlcyUUID = _ApplicationJournalHeader.InsurPlcyUUID
  association [0..*] to R_InsurPlcyCashFlowHdrTP       as _CashFlowDocumentHeader    on  $projection.InsurPlcyUUID = _CashFlowDocumentHeader.InsurPlcyUUID
  association [0..*] to R_InsurPlcyCBCCashFlowHdrTP    as _CBCCashFlowDocumentHeader on  $projection.InsurPlcyUUID = _CBCCashFlowDocumentHeader.InsurPlcyUUID
  association [0..*] to R_InsurPlcyCBCOverviewTP       as _CBCOverview               on  $projection.InsurPlcyUUID = _CBCOverview.InsurPlcyUUID
                                                                                     or  $projection.InsurPlcyUUID = _CBCOverview.InsurPlcyApplUUID
  association [0..*] to R_InsurPlcyAccountingTP_2      as _TransferSettle            on  $projection.InsurancePolicy = _TransferSettle.InsurPlcyAcctgExtPlcyNmbr
  association [0..*] to R_InsurPlcyAccountingTP_2      as _TransferSettleRef         on  $projection.InsurancePolicy = _TransferSettleRef.InsurPlcyAcctgRefPlcyNmbr
  association [0..*] to R_InsurPlcyDualControlTP       as _DualControl               on  $projection.InsurPlcyUUID = _DualControl.InsurPlcyUUID
  association [0..*] to R_InsurPlcyBnftCasesAndClaimTP as _BenefitCasesAndClaims     on  $projection.InsurPlcyUUID = _BenefitCasesAndClaims.InsurPlcyUUID
  association [0..*] to R_InsurPlcyPlndDteProcessingTP as _PlannedProcessing         on  $projection.InsurPlcyUUID = _PlannedProcessing.InsurPlcyUUID
  association [0..*] to R_InsurPlcyCoinsurCashFlowTP   as _CoinsuranceCashFlow       on  $projection.InsurPlcyUUID = _CoinsuranceCashFlow.InsurPlcyUUID
  association [1..1] to E_InsurancePolicy              as _Extension                 on  $projection.InsurPlcyUUID        = _Extension.InsurPlcyUUID
                                                                                     and $projection.InsurPlcyJrnlEndNmbr = _Extension.InsurPlcyJrnlEndNmbr
                                                                                     and $projection.InsurPlcyJrnlNmbr    = _Extension.InsurPlcyJrnlNmbr

{
  key InsurPlcyUUID,
      InsurPlcyJrnlNmbr,
      InsurPlcyJrnlEndNmbr,
      InsurancePolicy,
      /*this is used in the Acces control role so should not be commented...comment in A view*/
      InsurPlcyAuthznSlsProductGroup,
      //Correction for 2380047004

      // InsurPlcyStartDateTime,

      InsurPolicyStartDate,
      InsurancePolicyStartTime,
      InsurancePolicyStartTimeZone,
      //End of Correction

      InsurApplLifeCycSts,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyDistributionChannel'
      InsurPlcyDistrChnl,
      InsrrIDByInsrr,
      InsurPlcySalesProductTemplate,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyAcquisitionType'
      InsurPlcyAcqnType,
      InsurPlcyBusinessObject,
      PrdcssrInsurancePolicy,
      LastChangeDateTime,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyNoActiveContract'
      InsurPolicyCancellationStatus,
      InsurancePlcyPolicyIsCancelled,
      InsurancePolicyNumberOld,
      InsurPlcyExchRateType,
      InsurPlcyCrcy,
      InsurancePolicyNoteIdentifier,
      LongText,
      TextObjectCategory,
      TextObjectKey,
      Language,
      InsurPlcyExtApplNmbr,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCommsnPostingCode'
      InsurPlcyCommissionPostingCode,
      InsurancePolicyDuplicateID,
      InsurancePolicyGenerationDate,
      //@ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyGenerationDetDateSource'

      InsurPlcySrceOfGnrtnDteCode,
      InsurancePolicyKey,
      InsurPlcySrceDocStsDateTime,
      InsurPlcyChangeOptionNumber,
      InsurPlcyChgOptnApplID,
      InsurPlcyChangeOptionText,
      InsurancePolicyIsChangeOption,
      InsurPlcyHasPndgCommsnCase,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyChangeOptionCategory'
      InsurPlcyChangeOptionCategory,
      InsurMstrPlcyJrnlNmbr,
      InsurMstrPlcySmplApplID,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyChangeOptionReason'
      InsurPlcyChgOptnRsn,
      InsuranceMasterPolicyNumber,
      InsurPlcyIsCoinsurPrtcpnt,
      InsurPlcyGnrtnDetnDte,
      InsurPlcyHasPolicyProcessing,
      //      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyShiftMode'

      InsurancePolicyShiftType,
      InsurancePolicySubjectCode,
      InsurancePolicyHasReassessment,
      InsurPlcyReassessmentNoteID,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyPremWaiverAnnulment'
      InsurPlcyPremWvrAnnulmentRsn,
      InsurPlcyContractualDpndcySts,
      cast ( ' ' as boolean preserving type )                        as InsurPlcyIsReleasePolicy,
      cast ( ' ' as boolean preserving type )                        as InsurPlcyIsSavePolicy,
      cast ( ' ' as boolean preserving type )                        as InsurPlcyIsCalctPolicy,
      cast ( ' ' as boolean preserving type )                        as InsurPlcyIsCBCAmtSimulate,
      cast ( ' ' as boolean preserving type )                        as InsurPlcyIsSmltePolicy,
      cast ( '0000000000000000000000' as /pm0/abd_svc_exa_lock_key ) as InsurancePolicyLockKey,


      /*Associations*/
      _Contract,
      _ContractBundle,
      _PolicyHolder,
      _RelatedContract,
      _ExternalReference,
      _Agent,
      _Clause,
      _Commission,
      _DistributionPlan,
      _DistributionPlan_2,
      _ContractJournalHeader,
      _ApplicationJournalHeader,
      _CashFlowDocumentHeader,
      _TransferSettle,
      _TransferSettleRef,
      _CBCCashFlowDocumentHeader,
      _CBCOverview,
      _DualControl,
      _BenefitCasesAndClaims,
      _PlannedProcessing,
      _CoinsuranceCashFlow 

}