R_CADocumentTP

@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Contract Accounting Document - TP'

@ObjectModel: { representativeKey:      'CADocumentNumber',
                sapObjectNodeType.name: 'ContrAcctgDocument',
                usageType:               { dataClass:      #TRANSACTIONAL,
                                           sizeCategory:   #XXL,
                                           serviceQuality: #C } }

@VDM: { lifecycle.contract.type: #SAP_INTERNAL_API,
        viewType:                #TRANSACTIONAL }

define root view entity R_CADocumentTP
  as select from I_CADocument

  composition [0..*] of R_CADocumentBPItemTP as _BPItem
  composition [0..*] of R_CADocumentGLItemTP as _GLItem
   
  association [0..*] to I_CADocumentBPItemLogicalEnhcd as _LogicalBPItem on $projection.CADocumentNumber = _LogicalBPItem.CADocumentNumber
  association [0..*] to I_CADocumentBPItemPaymentData as _BPItemPaytData on $projection.CADocumentNumber = _BPItemPaytData.CADocumentNumber
  association [0..*] to I_CADocumentGLItemPaymentData as _GLItemPaytData on $projection.CADocumentNumber = _GLItemPaytData.CADocumentNumber
  association [1..1] to I_CADocumentUI as _DocUI on $projection.CADocumentNumber = _DocUI.CADocumentNumber
{
      //I_CADocument

  key CADocumentNumber,
      CreatedByUser,
      
      CreationDate,
      CreationTime,
      cast(dats_tims_to_tstmp(CreationDate, CreationTime, abap_system_timezone($session.client, 'NULL'), $session.client, 'NULL') as vdm_creationdatetime) as CreationDateTime,

      LastChangeDate,
      LastChangeTime,
      CATaxCompanyCode,
      CAStorageLocationOfTaxSuplmnt,
      CATaxCodeWasExchanged,
      TaxReportingDate,
      CAReconciliationKey,
      CASeparateDocIsCreatedInGL,
      CARequestedPeriodForGLTransfer,
      CAApplicationArea,
      CADocumentType,
      CADocumentOriginCode,
      TransactionCurrency,
      DocumentDate,
      CAPostingDate,
      ExchangeRateDate,
      CAReferenceDocument,
      CAReturnReason,
      CAPostingReason,
      ReferenceDocumentType,
      OriginalReferenceDocument,
      CAReversedDocumentNumber,
      CAClearingInformation,
      CAReversalDocumentNumber,
      CADocumentSupplements,
      LogicalSystem,
      CAWorkflowCheckReason,
      CAWorkflowCheckProcess,
      CADocumentTransactionClass,
      CADocContainsCashFlowItems,
      CADocumentClass,
      CADocumentVersion,
      IsIndividualPosting,
      CADocumentIsAged,

      

      //etag

      @Semantics.systemDateTime.lastChangedAt: true
      case when ( LastChangeDate is initial or LastChangeDate is null )
        then cast( dats_tims_to_tstmp( LastChangeDate, LastChangeTime, 'UTC', $session.client, 'NULL') as vdm_lastchangedon )
        else cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL') as vdm_lastchangedon )
      end                                                                 as LastChangeDateTime,

      /* Associations */
      // own association

      _BPItem,
      _GLItem,
      _BPItemPaytData,
      _GLItemPaytData,
      _LogicalBPItem,
      _DocUI,
      // associations from I_CADocument

      _ApplArea,
      _CAClearingInformation,
      _CADocTransactionClass,
      _CADocumentClass,
      _CADocumentSupplement,
      _CADocumentVersion,
      _CAPostingReason,
      _CAReturnReason,
      _CARequestedSpecialPeriod,
      _CATaxSupplementStorageLoc,
      _CompCode,
      _Currency,
      _DocType,
      _DocOriginCode,
      _WorkflowCheckProcess,
      _WorkflowCheckReason
}