I_CADocumentUI

@EndUserText.label: 'Document UI enhancements'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.representativeKey: 'CADocumentNumber'

@VDM.viewType: #COMPOSITE
define view entity I_CADocumentUI
  as select from R_CADocumentTP
  association [1..1] to P_CADocumentOpenAmountInTC     as _OpenAmount       on $projection.CADocumentNumber = _OpenAmount.CADocumentNumber
  association [1..1] to P_CADocumentDueAmountInTC      as _DueAmount        on $projection.CADocumentNumber = _DueAmount.CADocumentNumber
  association [1..1] to P_CADocumentClearedAmountInTC  as _ClearedAmount    on $projection.CADocumentNumber = _ClearedAmount.CADocumentNumber
  association [0..1] to P_CADocumentBPItemCount        as _DocBPItemCount   on $projection.CADocumentNumber = _DocBPItemCount.CADocumentNumber
  association [0..1] to P_CADocumentGLItemCount        as _DocGLItemCount   on $projection.CADocumentNumber = _DocGLItemCount.CADocumentNumber
  association [0..1] to P_CADocumentPaytInfoPaymentLot as _PayInfoLot       on $projection.CADocumentNumber = _PayInfoLot.CADocumentNumber and $projection.CADocumentOriginCode = '05'
  association [0..1] to P_CADocumentPaytInfoPaymentRun as _PayInfoRun       on $projection.CADocumentNumber = _PayInfoRun.CADocumentNumber and $projection.CADocumentOriginCode = '06'
  association [0..1] to P_CADocumentPaytInfoReturn     as _PayInfoReturn    on $projection.CADocumentNumber = _PayInfoReturn.CAPaymentDocument and $projection.CADocumentOriginCode = '08'
  association [0..1] to P_CADocumentPaytInfoPaytOrder  as _PayInfoOrder     on $projection.CADocumentNumber = _PayInfoOrder.CAPaymentDocument and $projection.CADocumentOriginCode = '45'
  association [0..1] to P_CADocumentPaytInfoRpaytReq   as _PayInfoRepayReq  on $projection.CADocumentNumber = _PayInfoRepayReq.CAPaymentDocument and $projection.CADocumentOriginCode = '35'
{
  key CADocumentNumber,
      CADocumentOriginCode,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      _OpenAmount.CAOpenAmountInTransactionCrcy,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      _DueAmount.CADueAmountInTransactionCrcy,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      _ClearedAmount.CAClrdAmountInTransactionCrcy,

      @ObjectModel.foreignKey.association: '_Currency'
      TransactionCurrency,

      _DocBPItemCount.NumberOfCADocumentBPItems,
      _DocGLItemCount.NumberOfCADocumentGLItems,

      //Payment Info Common fields

      case when CADocumentOriginCode = '05' then _PayInfoLot._BkClrgAcct.HouseBank
           when CADocumentOriginCode = '06' then _PayInfoRun.HouseBank
           when CADocumentOriginCode = '08' then _PayInfoReturn.HouseBank
           when CADocumentOriginCode = '45' then _PayInfoOrder.HouseBank
      end as HouseBank,

      case when CADocumentOriginCode = '05' then _PayInfoLot._BkClrgAcct.HouseBankAccount
           when CADocumentOriginCode = '06' then _PayInfoRun.HouseBankAccount
           when CADocumentOriginCode = '08' then _PayInfoReturn.HouseBankAccount
           when CADocumentOriginCode = '45' then _PayInfoOrder.HouseBankAccount
      end as HouseBankAccount,

      case when CADocumentOriginCode = '06' then _PayInfoRun.CAMassRunDate
           when CADocumentOriginCode = '45' then _PayInfoOrder.CAMassRunDate
      end as CAMassRunDate,

      case when CADocumentOriginCode = '06' then _PayInfoRun.CAMassRunID
           when CADocumentOriginCode = '45' then _PayInfoOrder.CAMassRunID
      end as CAMassRunID,

      case when CADocumentOriginCode = '06' then _PayInfoRun.CAMassRunDateAndID
           when CADocumentOriginCode = '45' then _PayInfoOrder.CAMassRunDateAndID
      end as CAMassRunDateAndID,

      case when CADocumentOriginCode = '35' then _PayInfoRepayReq.CAPaymentDocument
           when CADocumentOriginCode = '45' then _PayInfoOrder.CAPaymentDocument
      end as CAPaymentDocument,

      case when CADocumentOriginCode = '06' then _PayInfoRun.CAPaymentMethod
           when CADocumentOriginCode = '35' then _PayInfoRepayReq.CAPaymentMethod
           when CADocumentOriginCode = '45' then _PayInfoOrder.CAPaymentMethod
      end as CAPaymentMethod,

      case when CADocumentOriginCode = '35' then _PayInfoRepayReq.CABankClearingAccount
           when CADocumentOriginCode = '05' then _PayInfoLot.CABankClearingAccount
      end as CABankClearingAccount,

      case when CADocumentOriginCode = '35' then _PayInfoRepayReq.CompanyCode
           when CADocumentOriginCode = '45' then _PayInfoOrder.CompanyCode
      end as CompanyCode,

      case when CADocumentOriginCode = '35' then _PayInfoRepayReq.CABankAccountHolderName
           when CADocumentOriginCode = '05' then _PayInfoLot.CABankAccountHolderName
      end as CABankAccountHolderName,


      //Payment Info Payment Lot

      _PayInfoLot.CAPaymentLot,
      _PayInfoLot.CAPaymentLotItem,
      _PayInfoLot.BankNumber,
      _PayInfoLot.BankAccount,
      _PayInfoLot.BankCountry,
      _PayInfoLot.BankDetailReference,
      _PayInfoLot.CANoteToPayeeInPayment,

      //Payment Info Payment Run

      _PayInfoRun.LastName,
      _PayInfoRun.FirstName,
      _PayInfoRun.CAPaymentDocumentReference,

      //Payment Info Payment Order

      _PayInfoOrder.CAPaymentOrder,
      _PayInfoOrder.CAPaymentOrderExternalRef,
      _PayInfoOrder.CAPaymentOrderStatus,
      _PayInfoOrder.CANetAmountInTransCurrency,
      _PayInfoOrder.PaidItemDueDate,
      _PayInfoOrder.ValueDate,
      _PayInfoOrder.CAPaymentOrderExpirationDate,
      _PayInfoOrder.BusinessPartner,

      //Payment Info Return

      _PayInfoReturn.CAReturnLot,
      _PayInfoReturn.CAItemNumberInReturnLot,
      _PayInfoReturn.CAReturnReasonOfHouseBank,
      _PayInfoReturn.CAReturnCharge1,
      _PayInfoReturn.TaxCodeForFirstReturnCharge,
      _PayInfoReturn.CATaxAmountForReturnCharge1,
      _PayInfoReturn.CAChargeAmountFromBank1,
      _PayInfoReturn.TaxCodeForFirstBankCharge,
      _PayInfoReturn.CATaxAmountOfBankCharge1,

      //Payment Info Repayment Request

      _PayInfoRepayReq.CARepaymentRequest,
      _PayInfoRepayReq.CAStatusOfRepaymentRequest,
      _PayInfoRepayReq.CAAmountInTransactionCurrency,
      _PayInfoRepayReq.CANetDueDate,
      _PayInfoRepayReq.CAPaymentCompanyCode,
      _PayInfoRepayReq.ProfitCenter,
      _PayInfoRepayReq.CARepaymentRequestDocument,
      _PayInfoRepayReq.CAPostingDate,
      _PayInfoRepayReq.PayeeBankNumber,
      _PayInfoRepayReq.PayeeBankCountry,
      _PayInfoRepayReq.PayeeBankAccount,
      _PayInfoRepayReq.PayeeIBAN,
      _PayInfoRepayReq.PayeeSWIFTCode,



      _Currency

}