I_CADOCUMENT
Contract Accounting Document
I_CADOCUMENT is a CDS View in S/4HANA. Contract Accounting Document. It contains 58 fields. 11 CDS views read from this table.
CDS Views using this table (11)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_CADocumentCube | view_entity | from | COMPOSITE | Contract Accounting Document - Cube |
| I_CADocumentHeader | view | from | BASIC | Contract Accounting Document |
| I_CAWriteOffDocument | view_entity | from | COMPOSITE | Contract Accounting Write Off Document |
| I_NL_SAFTBusinessPartner | view | inner | COMPOSITE | SAF-T NL Business Partner |
| P_BOPDbtflRblsCARslt | view_entity | from | COMPOSITE | |
| P_BOPFICA_BP_ITEM_2 | view_entity | from | COMPOSITE | FI-CA BP Item 2 |
| P_BOPFICA_BP_ITEM_2 | view_entity | union | COMPOSITE | FI-CA BP Item 2 |
| P_BOPFICA_BP_ITEM_2_OG | view_entity | from | COMPOSITE | |
| P_BOPFICA_BP_ITEM_2_REV | view_entity | from | COMPOSITE | |
| P_PT_CADocItmAnnex | view_entity | inner | CONSUMPTION | Contract Accounting Document Item for Portugal Annex O |
| R_CADocumentTP | view_entity | from | TRANSACTIONAL | Contract Accounting Document - TP |
Fields (58)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CADocumentNumber | CADocumentNumber,CAReversalDocumentNumber | 4 |
| _AccountingDocType | _AccountingDocType | 1 | |
| _ApplArea | _ApplArea | 1 | |
| _CAClearingInformation | _CAClearingInformation | 1 | |
| _CADocTransactionClass | _CADocTransactionClass | 1 | |
| _CADocumentClass | _CADocumentClass | 1 | |
| _CADocumentSupplement | _CADocumentSupplement | 1 | |
| _CADocumentVersion | _CADocumentVersion | 1 | |
| _CAPostingReason | _CAPostingReason | 1 | |
| _CARequestedSpecialPeriod | _CARequestedSpecialPeriod | 1 | |
| _CAReturnReason | _CAReturnReason | 1 | |
| _CATaxSupplementStorageLoc | _CATaxSupplementStorageLoc | 1 | |
| _CompCode | _CompCode | 1 | |
| _Currency | _Currency | 1 | |
| _DocOriginCode | _DocOriginCode | 1 | |
| _DocType | _DocType | 1 | |
| _WorkflowCheckProcess | _WorkflowCheckProcess | 1 | |
| _WorkflowCheckReason | _WorkflowCheckReason | 1 | |
| CA1stCountrySpecificReference | CA1stCountrySpecificReference | 1 | |
| CAApplicationArea | CAApplicationArea | 1 | |
| CAClearingInformation | CAClearingInformation | 1 | |
| CADocContainsCashFlowItems | CADocContainsCashFlowItems | 1 | |
| CADocumentClass | CADocumentClass | 1 | |
| CADocumentIsAged | CADocumentIsAged | 1 | |
| CADocumentOriginCode | CADocumentOriginCode | 1 | |
| CADocumentSupplements | CADocumentSupplements | 1 | |
| CADocumentTransactionClass | CADocumentTransactionClass | 1 | |
| CADocumentType | CADocumentType | 5 | |
| CADocumentTypeForGLTransfer | CADocumentTypeForGLTransfer | 1 | |
| CADocumentVersion | CADocumentVersion | 1 | |
| CAFirstCountrySpecificDate | CAFirstCountrySpecificDate | 1 | |
| CAPostingDate | CAPostingDate,PostingDate | 4 | |
| CAPostingReason | CAPostingReason | 1 | |
| CAReconciliationKey | CAReconciliationKey | 5 | |
| CAReferenceDocument | CAReferenceDocument | 1 | |
| CARequestedPeriodForGLTransfer | CARequestedPeriodForGLTransfer | 1 | |
| CAReturnReason | CAReturnReason | 1 | |
| CAReversalDocumentNumber | CAReversalDocumentNumber | 3 | |
| CAReversedDocumentNumber | CAReversedDocumentNumber | 5 | |
| CASeparateDocIsCreatedInGL | CASeparateDocIsCreatedInGL | 1 | |
| CAStorageLocationOfTaxSuplmnt | CAStorageLocationOfTaxSuplmnt | 1 | |
| CATaxCodeWasExchanged | CATaxCodeWasExchanged | 1 | |
| CATaxCompanyCode | CATaxCompanyCode | 1 | |
| CAWorkflowCheckProcess | CAWorkflowCheckProcess | 1 | |
| CAWorkflowCheckReason | CAWorkflowCheckReason | 1 | |
| CreatedByUser | CreatedByUser | 1 | |
| CreationDate | CreationDate | 1 | |
| CreationTime | CreationTime | 1 | |
| DocumentDate | DocumentDate | 2 | |
| ExchangeRateDate | ExchangeRateDate | 1 | |
| IsIndividualPosting | IsIndividualPosting | 1 | |
| LastChangeDate | LastChangeDate | 1 | |
| LastChangeTime | LastChangeTime | 1 | |
| LogicalSystem | LogicalSystem | 1 | |
| OriginalReferenceDocument | OriginalReferenceDocument | 1 | |
| ReferenceDocumentType | ReferenceDocumentType | 1 | |
| TaxReportingDate | TaxReportingDate | 1 | |
| TransactionCurrency | TransactionCurrency | 1 |
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Contract Accounting Document'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: { representativeKey: 'CADocumentNumber',
supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
#SQL_DATA_SOURCE,
#CDS_MODELING_DATA_SOURCE ] }
@ObjectModel.usageType: { serviceQuality: #A,
sizeCategory: #XXL,
dataClass: #TRANSACTIONAL }
@VDM.viewType: #BASIC
define view entity I_CADocument
as select from dfkkko
association [0..1] to I_AccountingDocumentType as _AccountingDocType on $projection.CADocumentTypeForGLTransfer = _AccountingDocType.AccountingDocumentType
association [1..1] to I_CompanyCode as _CompCode on $projection.CATaxCompanyCode = _CompCode.CompanyCode
association [1..1] to I_Currency as _Currency on $projection.TransactionCurrency = _Currency.Currency
association [1..1] to I_CAApplicationArea as _ApplArea on $projection.CAApplicationArea = _ApplArea.CAApplicationArea
association [0..1] to I_CAClearingInformation as _CAClearingInformation on $projection.CAClearingInformation = _CAClearingInformation.CAClearingInformation
association [1..1] to I_CADocTransactionClass as _CADocTransactionClass on $projection.CADocumentTransactionClass = _CADocTransactionClass.CADocumentTransactionClass
association [0..1] to I_CADocumentClass as _CADocumentClass on $projection.CADocumentClass = _CADocumentClass.CADocumentClass
association [1..1] to I_CADocumentOriginCode as _DocOriginCode on $projection.CADocumentOriginCode = _DocOriginCode.CADocumentOriginCode
association [0..1] to I_CADocumentSupplement as _CADocumentSupplement on $projection.CADocumentSupplements = _CADocumentSupplement.CADocumentSupplements
association [1..1] to I_CADocumentType as _DocType on $projection.CADocumentType = _DocType.CADocumentType
and $projection.CAApplicationArea = _DocType.CAApplicationArea
association [0..1] to I_CADocumentVersion as _CADocumentVersion on $projection.CADocumentVersion = _CADocumentVersion.CADocumentVersion
association [0..1] to I_CAPostingReason as _CAPostingReason on $projection.CADocumentOriginCode = _CAPostingReason.CADocumentOriginCode
and $projection.CAPostingReason = _CAPostingReason.CAPostingReason
association [0..*] to I_CAReturnReason as _CAReturnReason on $projection.CAReturnReason = _CAReturnReason.CAReturnReason
and _CAReturnReason.HouseBank is not initial
association [1..1] to I_CARequestedSpecialPeriod as _CARequestedSpecialPeriod on $projection.CARequestedPeriodForGLTransfer = _CARequestedSpecialPeriod.CARequestedPeriodForGLTransfer
association [0..1] to I_CATaxSupplementStorageLoc as _CATaxSupplementStorageLoc on $projection.CAStorageLocationOfTaxSuplmnt = _CATaxSupplementStorageLoc.CAStorageLocationOfTaxSuplmnt
association [0..1] to I_CAWorkflowCheckReason as _WorkflowCheckReason on $projection.CAWorkflowCheckReason = _WorkflowCheckReason.CAWorkflowCheckReason
association [0..1] to I_CAWorkflowCheckProcess as _WorkflowCheckProcess on $projection.CAWorkflowCheckProcess = _WorkflowCheckProcess.CAWorkflowCheckProcess
association [1..1] to E_CADocumentHeader as _Extension on $projection.CADocumentNumber = _Extension.CADocumentNumber
{
key opbel as CADocumentNumber,
fikey as CAReconciliationKey,
@ObjectModel.foreignKey.association: '_ApplArea'
applk as CAApplicationArea,
@ObjectModel.foreignKey.association: '_DocType'
blart as CADocumentType,
@ObjectModel.foreignKey.association: '_DocOriginCode'
herkf as CADocumentOriginCode,
cast(ernam as fclm_bam_created_by preserving type ) as CreatedByUser,
cast(cpudt as fis_cpdat preserving type) as CreationDate,
cast(cputm as ttet_dt_cr_time preserving type ) as CreationTime,
@ObjectModel.foreignKey.association: '_Currency'
cast(waers as fis_rwcur preserving type ) as TransactionCurrency,
cast(bldat as fis_bldat preserving type ) as DocumentDate,
budat as CAPostingDate,
cast(wwert as vdm_v_exchange_rate_date preserving type ) as ExchangeRateDate,
xblnr as CAReferenceDocument,
@ObjectModel.foreignKey.association: '_CAReturnReason'
rlgrd as CAReturnReason,
@ObjectModel.foreignKey.association: '_CAPostingReason'
abgrd as CAPostingReason,
xeibh as CASeparateDocIsCreatedInGL,
//xbwer
cast(awtyp as fis_awtyp preserving type ) as ReferenceDocumentType,
awkey as OriginalReferenceDocument,
cast(stbel as stbel_gfn_kk preserving type ) as CAReversedDocumentNumber,
//stmet
@ObjectModel.foreignKey.association: '_CADocumentClass'
bltyp as CADocumentClass,
@ObjectModel.foreignKey.association: '_CAClearingInformation'
aginf as CAClearingInformation,
@ObjectModel.foreignKey.association: '_CompCode'
stbuk as CATaxCompanyCode,
cast(storb as storb_gfn_kk preserving type ) as CAReversalDocumentNumber,
@ObjectModel.foreignKey.association: '_CADocumentSupplement'
appdx as CADocumentSupplements,
awsys as LogicalSystem,
@ObjectModel.foreignKey.association: '_CADocumentVersion'
versn as CADocumentVersion,
@ObjectModel.foreignKey.association: '_WorkflowCheckReason'
c4eye as CAWorkflowCheckReason,
@ObjectModel.foreignKey.association: '_WorkflowCheckProcess'
c4eyp as CAWorkflowCheckProcess,
@ObjectModel.foreignKey.association: '_CADocTransactionClass'
tatyp as CADocumentTransactionClass,
@ObjectModel.foreignKey.association: '_AccountingDocType'
hbbla as CADocumentTypeForGLTransfer,
xcsha as CADocContainsCashFlowItems,
@ObjectModel.foreignKey.association: '_CATaxSupplementStorageLoc'
utloc as CAStorageLocationOfTaxSuplmnt,
xtxch as CATaxCodeWasExchanged,
cast(vatdate as vatdate preserving type ) as TaxReportingDate,
//fulfilldate
@ObjectModel.foreignKey.association: '_CARequestedSpecialPeriod'
wnper as CARequestedPeriodForGLTransfer,
xsing as IsIndividualPosting,
//keypp
//_dataging
xdaag as CADocumentIsAged,
//trsla
//locok
//bttype
//cbttype
//closingstep
chdate as LastChangeDate,
chtime as LastChangeTime,
//cadoctype
glo_ref1_hd as CA1stCountrySpecificReference,
glo_dat1_hd as CAFirstCountrySpecificDate,
/* associations */
_AccountingDocType,
_ApplArea,
_CAClearingInformation,
_CADocTransactionClass,
_CADocumentClass,
_CADocumentSupplement,
_CADocumentVersion,
_CAPostingReason,
_CAReturnReason,
_CARequestedSpecialPeriod,
_CATaxSupplementStorageLoc,
_CompCode,
_Currency,
_DocType,
_DocOriginCode,
_WorkflowCheckProcess,
_WorkflowCheckReason
}