I_PPM_CollectedSeverityForTask

@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'IPPMCLCTDSEV4TSK'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Collected Severity For Task'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory:  #M
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.representativeKey: 'ViolationUUID'
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

define view I_PPM_CollectedSeverityForTask
  as select from    P_PPM_AggregatedSeverity as link
    left outer join I_PPM_SeverityValue      as severity           on link.ViolationUUID = severity.ViolationUUID
    left outer join I_EnterpriseProjElmntHier as level              on level.TaskUUID = link.TaskUUID
    left outer join I_PPM_Task               as task              on link.TaskUUID = task.TaskUUID
    left outer join I_PPM_TaskText           as tasktext           on tasktext.TaskUUID = link.ReferencedObjectUUID
    left outer join I_PPM_TaskText           as Projecttext        on Projecttext.TaskUUID = severity.ProjectSummaryTaskUUID
    left outer join I_PPM_ProjectRoleText    as roletext           on roletext.ProjectRoleUUID = link.ReferencedObjectUUID
    left outer join I_PPM_ChecklistItemText  as checklistitem_text on checklistitem_text.ChecklistItemUUID = link.ReferencedObjectUUID
    left outer join I_EPPMGlobalSetting as _GlobalSetting on _GlobalSetting.EPPMUsageArea = '0007' and _GlobalSetting.EPPMGlobalSettingsCode = '0053'
{
  key link.ViolationUUID,
      link.Severity as Severity,
      link.ViolationType,
      link.TaskUUID,
      cast(severity._Severity.CriticalityCode as abap.char( 6 )) as CriticalityCode,
      severity._Severity.ViolationReasonCode,
      case
      when severity._Severity._SeverityText[1:LanguageCode = $session.system_language].SeverityText is null then severity.Severity
      else severity._Severity._SeverityText[1:LanguageCode = $session.system_language].SeverityText end
                                                                 as SeverityText,
      case
      when severity._Threshold._Text[1:LanguageCode = $session.system_language].ThresholdText is null then severity.Threshold
      else severity._Threshold._Text[1:LanguageCode = $session.system_language].ThresholdText
      end                                                        as ThresholdText,
      link.ObjectType,
//      task.LastestFinishDateTime,

      task.LatestFinishDateTime,
      task.IsMirroredTask,
      task.IsProjectMilestone,
      task.IsSummaryTask,
      severity.ProjectSummaryTaskUUID                            as ProjectSummaryTaskUUID,
      task.ProjectUUID                                           as ProjectUUID,
      Projecttext.ObjectName                                     as ProjectName,
      case link.ObjectType
      when 'ITO' then level.HierarchyNodeLevel*2 + 1
      when 'MTG' then level.HierarchyNodeLevel*2 + 2
      else level.HierarchyNodeLevel*2
      end                                                        as HierarchyNodeLevel,
      case link.ObjectType
      when 'ITO' then checklistitem_text.ChecklistItemName
      when 'MTG' then roletext.ProjectRoleName
      else tasktext.ObjectName
      end                                                        as ObjectName,
      _GlobalSetting.EPPMSettingsDefaultValue

}