I_PPM_ProjectRoleText

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ObjectModel: {
   dataCategory: #TEXT,
   representativeKey:  'ProjectRoleUUID',
   usageType: {
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #S
    }
}

@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'IPPMPROROLETEXT'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Project Role Text'
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API 

define view I_PPM_ProjectRoleText
  as select from    I_PPM_ProjectRole as role
    left outer join I_PPM_ProjectRoot as ProjectRoot on role.ProjectUUID = ProjectRoot.ProjectUUID  
    left outer join I_PPM_Text        as TextLogon   on (
         TextLogon.LanguageCode                                                       = $session.system_language
       )
                                                     and(
                                                       TextLogon.ReferencedObjectUUID = role.ProjectRoleUUID
                                                     )
    left outer join I_PPM_Text        as TextMaster  on (
        TextMaster.LanguageCode                                                        = ProjectRoot.MasterLanguage
      )
                                                     and(
                                                       TextMaster.ReferencedObjectUUID = role.ProjectRoleUUID
                                                     )
{
    @ObjectModel.text.element: ['ProjectRoleName']
key role.ProjectRoleUUID,

    @EndUserText.label: 'Object Description'
    @Semantics.text: true            -- identifies the first text field
    @UI.hidden: true
    cast( case
         when TextLogon.ObjectName > '' then
              TextLogon.ObjectName
         else (
         case
              when TextMaster.ObjectName > '' then
              TextMaster.ObjectName
              else role.ProjectRole
         end
         )
      end as dpr_project_name ) as ProjectRoleName,
 //Authorization check relevant data   

      role.ProjectSummaryTaskUUID,
      role.ProjectInternalID,
      role.WBSElementInternalID,
      role._I_Project,
      role._ProjObj,
      role._AuthUser,
      role._AuthSubst,
      role._AuthRole,
      role._AuthGroup 
}