I_PPM_CHECKLISTITEMTEXT

CDS View

Check item text

I_PPM_CHECKLISTITEMTEXT is a CDS View in S/4HANA. Check item text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_PPM_CollectedSeverityForTask view left_outer COMPOSITE Collected Severity For Task 
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory:  #M
@ObjectModel.usageType.dataClass:  #MIXED
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'IPPMCHKLSTITMTXT'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Check item text'
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

define view I_PPM_ChecklistItemText
  as select from    I_PPM_ChecklistItem as entity
    left outer join I_PPM_Task          as task        on entity.ChecklistParentObjectUUID = task.TaskUUID
    left outer join I_PPM_ProjectRoot   as ProjectRoot on task.ProjectUUID = ProjectRoot.ProjectUUID
    left outer join I_PPM_Text          as TextLogon   on  TextLogon.LanguageCode         = $session.system_language
                                                       and TextLogon.ReferencedObjectUUID = entity.ChecklistItemUUID
    left outer join I_PPM_Text          as TextMaster  on  TextMaster.LanguageCode         = ProjectRoot.MasterLanguage
                                                       and TextMaster.ReferencedObjectUUID = entity.ChecklistItemUUID
{
  key entity.ChecklistItemUUID as ChecklistItemUUID,
      @EndUserText.label: 'Object Description'
      cast ( case
         when TextLogon.ObjectName > '' then
              TextLogon.ObjectName
         else (
         case
              when TextMaster.ObjectName > '' then
              TextMaster.ObjectName
              else entity.ChecklistItem
         end
         )
      end as dpr_tv_text )                     as ChecklistItemName,
      entity._AuthUser,
      entity._AuthSubst,
      entity._AuthRole,
      entity._AuthGroup
      
}

Learn More