I_MeasuringPoint

@AbapCatalog.sqlViewName: 'IMEASPOINT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Measuring Point'
@ObjectModel.representativeKey: 'MeasuringPoint'

@Search.searchable: true
@VDM.viewType: #BASIC

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.supportedCapabilities: #CDS_MODELING_DATA_SOURCE
@Metadata.ignorePropagatedAnnotations:true

define view I_MeasuringPoint
  as select from imptt
  association [1..1] to I_ControllingObject            as _ControllingObject            on  $projection.MeasuringPointObjectIdentifier = _ControllingObject.ControllingObject
  association [0..1] to I_Language                     as _Language                     on  $projection.Language = _Language.Language
  association [0..1] to I_Product                      as _Product                      on  $projection.Assembly = _Product.Product
  association [0..1] to I_MeasuringPoint               as _ReferenceMeasuringPoint      on  $projection.ReferenceMeasuringPoint = _ReferenceMeasuringPoint.MeasuringPoint
  association [0..1] to I_UnitOfMeasure                as _UnitOfMeasure                on  $projection.MeasurementRangeUnit = _UnitOfMeasure.UnitOfMeasure
  association [0..1] to I_MeasuringPoint               as _MsmtRdngSourceMeasuringPoint on  $projection.MsmtRdngSourceMeasuringPoint = _MsmtRdngSourceMeasuringPoint.MeasuringPoint
  association [0..1] to I_Inspectioncatalog            as _MeasuringPointCatalogType    on  $projection.MeasuringPointCatalogType = _MeasuringPointCatalogType.InspectionCatalog
  association [0..1] to I_InspectionCodeGroup          as _MeasuringPointCodeGroup      on  $projection.MeasuringPointCatalogType = _MeasuringPointCodeGroup.InspectionCatalog
                                                                                        and $projection.MeasuringPointCodeGroup   = _MeasuringPointCodeGroup.InspectionCodeGroup
  association [0..1] to I_ClfnCharacteristicForKeyDate as _Characteristic               on  $projection.MsrgPtInternalCharacteristic = _Characteristic.CharcInternalID
  association [0..1] to I_MeasuringPointCategory       as _MeasuringPointCategory       on  $projection.MeasuringPointCategory = _MeasuringPointCategory.MeasuringPointCategory
  association [0..1] to I_Equipment                    as _Equipment                    on  $projection.MeasuringPointObjectIdentifier = _Equipment.MaintObjectInternalID
  association [0..1] to I_FunctionalLocation           as _FunctionalLocation           on  $projection.MeasuringPointObjectIdentifier = _FunctionalLocation.MaintObjectInternalID
  association [0..1] to I_FunctionalLocationLabel      as _FunctionalLocationLabel      on  $projection.FunctionalLocation = _FunctionalLocationLabel.FunctionalLocation
  association [0..1] to I_TechObjAuthznGrp             as _AuthorizationGroup           on  $projection.AuthorizationGroup = _AuthorizationGroup.TechObjAuthorizationGroup
//  association [0..1] to P_Building                     as _Building                     on  $projection.MeasuringPointObjectIdentifier = _Building.ObjectNumberOfBuilding

//  association [0..1] to P_SettlementUnit               as _SettlementUnit               on  $projection.MeasuringPointObjectIdentifier = _SettlementUnit.ObjectNumberOfSettlementUnit

//  association [0..1] to P_RentalObject                 as _RentalObject                 on  $projection.MeasuringPointObjectIdentifier = _RentalObject.ObjectNumberOfRentalObject


{

      @ObjectModel.text.element: 'MeasuringPointDescription'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
  key point                                     as MeasuringPoint,

      @ObjectModel.foreignKey.association: '_ControllingObject'
      mpobj                                     as MeasuringPointObjectIdentifier,

      psort                                     as MeasuringPointPositionNumber,

      @ObjectModel.foreignKey.association: '_MeasuringPointCategory'
      mptyp                                     as MeasuringPointCategory,

      @Semantics.systemDate.createdAt: true
      erdat                                     as CreationDate,

      @Semantics.systemDate.lastChangedAt: true
      aedat                                     as LastChangeDate,

      @ObjectModel.foreignKey.association: '_AuthorizationGroup'
      begru                                     as AuthorizationGroup,

      inact                                     as MeasuringPointIsInactive,

      indct                                     as MeasuringPointIsCounter,

      lvorm                                     as MultiLevelDeletionLogicStatus,

//      @Consumption.valueHelpDefinition: [{

//        entity: {

//            name:    'I_MaterialStdVH',

//            element: 'Material'

//        }

//      }]

      @ObjectModel.foreignKey.association: '_Product'
      locas                                     as Assembly,

      @ObjectModel.foreignKey.association: '_ReferenceMeasuringPoint'
      refmp                                     as ReferenceMeasuringPoint,

      @ObjectModel.foreignKey.association: '_Characteristic'
      atinn                                     as MsrgPtInternalCharacteristic,

      expon                                     as MeasuringPointExponent,

      decim                                     as MeasuringPointDecimalPlaces,

      mrmin                                     as MeasuringPointMinimumThreshold,

      mrmini                                    as MinimumThresholdIsEntered,

      mrmax                                     as MeasuringPointMaximumThreshold,

      mrmaxi                                    as MaximumThresholdIsEntered,

      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      @Semantics.unitOfMeasure: true
      mrngu                                     as MeasurementRangeUnit,
      
      _UnitOfMeasure._Dimension.UnitOFMeasureSiUnit as MeasuringPointSIUnitOfMeasure, 

      indrv                                     as MsrgPtIsCountingBackwards,

      @ObjectModel.foreignKey.association: '_MsmtRdngSourceMeasuringPoint'
      trans                                     as MsmtRdngSourceMeasuringPoint,

      cjump                                     as CounterOverflowRdngThreshold,

      cjumpi                                    as OverflowReadingIsEntered,

      pyear                                     as MeasuringPointAnnualEstimate,

      pyeari                                    as MsrgPtAnnualEstimateIsEntered,

      @ObjectModel.foreignKey.association: '_MeasuringPointCatalogType'
      codct                                     as MeasuringPointCatalogType,

      @ObjectModel.foreignKey.association: '_MeasuringPointCodeGroup'
      codgr                                     as MeasuringPointCodeGroup,

      cdsuf                                     as ValuationCodeIsSufficient,

      @ObjectModel.foreignKey.association: '_Language'
      mlang                                     as Language,

      @Semantics.text: true
      pttxt                                     as MeasuringPointDescription,

      dstxt                                     as MeasuringPointShortText,

      irfmp                                     as MeasuringPointIsReference,

      indtr                                     as MeasurementTransferIsSupported,

      @Semantics.user.createdBy: true
      ernam                                     as CreatedByUser,

      @Semantics.user.lastChangedBy: true
      aenam                                     as LastChangedByUser,

      kzltx                                     as MeasuringPointHasLongText,

      cast(substring(mpobj,1,2) as j_obart)     as MeasuringPointObjectType,

      desir                                     as MeasuringPointTargetValue,

      desiri                                    as TargetValueIsEntered,
      
      modtr                                     as MsmtRdngTransferMode,
    
     _FunctionalLocation.FunctionalLocation     as FunctionalLocation,
 
      // Propagate association(s)

      _ControllingObject,
      _Language,
      _Product,
      _ReferenceMeasuringPoint,
      _UnitOfMeasure,
      _MsmtRdngSourceMeasuringPoint,
      _MeasuringPointCatalogType,
      _MeasuringPointCodeGroup,
      _Characteristic,
      _MeasuringPointCategory,
      _Equipment,
      _FunctionalLocation,
      _FunctionalLocationLabel,
      _AuthorizationGroup
//      _Building,

//      _SettlementUnit,

//      _RentalObject


}