I_ControllingObject

@EndUserText.label: 'Controlling Object'
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFICOOBJECT'
@AccessControl.authorizationCheck: #CHECK //NOT_REQUIRED

@ObjectModel.representativeKey: 'ControllingObject'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.supportedCapabilities: [ #EXTRACTION_DATA_SOURCE, #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION 

@ObjectModel.usageType: {
  dataClass: #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory: #L
}
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

define view I_ControllingObject
// Corresponds to calculation view 'sap.hba.ecc.ControllingObject'

as select from onr00

left outer join onrks on  onr00.objnr = onrks.objnr
left outer join onrbp on  onr00.objnr = onrbp.objnr
left outer join onrkl on  onr00.objnr = onrkl.objnr
left outer join onror on  onr00.objnr = onror.objnr
//left outer join onrov on  Join_4.objnr = onrov.objnr

left outer join onrpd on  onr00.objnr = onrpd.objnr
left outer join onrpr on  onr00.objnr = onrpr.objnr
left outer join onrvb on  onr00.objnr = onrvb.objnr

association[1]          to I_ControllingArea              as _ControllingArea         
    on  $projection.ControllingArea         = _ControllingArea.ControllingArea
association [0..*]      to I_CostCenter                   as _CostCenter             
    on  $projection.CostCenter              = _CostCenter.CostCenter
    and $projection.ControllingArea         = _CostCenter.ControllingArea
association[0..*]       to I_CostCenterActivityType       as _CostCtrActivityType     
    on  $projection.CostCtrActivityType     = _CostCtrActivityType.CostCtrActivityType
    and $projection.ControllingArea         = _CostCtrActivityType.ControllingArea    
{

  
  
  key   onr00.objnr as ControllingObject,

        onror.aufnr as OrderID,

        onrbp.prznr as BusinessProcess,

        onrkl.lstar as CostCtrActivityType,

        onrvb.vbeln as SalesDocument,

        onrvb.posnr as SalesDocumentItem,
 
        cast ( COALESCE ( COALESCE( COALESCE(onrks.kokrs, onrbp.kokrs ),   onrkl.kokrs), '')  as fis_kokrs ) as ControllingArea,

        cast( COALESCE(onrks.kostl, onrkl.kostl) as fis_kostl ) as CostCenter,

        cast( onrpr.pspnr as fis_wbsint_no_conv preserving type ) as WBSElementInternalID,
        cast( onrpd.pspnr as fis_projectint_no_conv preserving type) as ProjectInternalID,
        cast ( SUBSTRING( onr00.objnr, 1, 2) as j_obart) as ControllingObjectType,
        _ControllingArea ,
        _CostCenter ,
        _CostCtrActivityType  
        
};