I_MasterDataChangeProcessTP

@AbapCatalog.sqlViewName: 'IMDCHGPROCESSTP'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Master Data Change Process'
 
@ObjectModel: {
  sapObjectNodeType.name: 'MasterDataChangeProcess',
  compositionRoot: true,
  writeActivePersistence: 'TMDCHGPROCESS_W',
  transactionalProcessingEnabled: true,
  createEnabled,
  updateEnabled,
  deleteEnabled,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory: #M
  },
  alternativeKey: [{
//    id: 'MASTERDATACHANGEPROCESS',

    uniqueness: #UNIQUE_IF_NOT_INITIAL,
    element: ['MasterDataChangeProcess']
  }],
  entityChangeStateId: 'MDChgProcessUpdateToken'
}
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
define view I_MasterDataChangeProcessTP
  as select from mdc_d_prcroot as _Process

  association [1..1] to I_MDChgProcessAuthorityCheck as _Auth on _Auth.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..*] to I_MDChangeProcessSourceTP as _Source on _Source.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..*] to I_MDChgProcessStepTP      as _Step   on _Step.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
{
  key _Process.db_key                                      as MasterDataChangeProcessUUID,
      _Process.id                                          as MasterDataChangeProcess,
      _Process.description                                 as MDChgProcessDescription,
      _Process.type_id                                     as MDChgProcessTypeID,
      _Process.goal                                        as MDChgProcessGoal,
      @ObjectModel.readOnly: false
      _Process.status                                      as MDChgProcessStatus,
      _Process.source_otc                                  as MDChgProcessSrceObjectTypeCode,
      @ObjectModel.readOnly: true
      _Process.workflow                                    as MDChgProcessWorkflowTemplate,
      @ObjectModel.readOnly: true
      _Process.requestor                                   as MDChgProcessRequestor,
      _Process.delete_source                               as MDChgProcessDelSrceDataIsRqd,
      @ObjectModel.readOnly: true
      _Process.create_date                                 as MDChgProcessCreationDate,
      @ObjectModel.readOnly: true
      _Process.create_time                                 as MDChgProcessCreationTime,
      @ObjectModel.readOnly: false
      _Process.change_date                                 as MDChgProcessChangeDate,
      @ObjectModel.readOnly: false
      _Process.change_time                                 as MDChgProcessChangeTime,
      @ObjectModel.readOnly: true
      _Process.finish_date                                 as MDChgProcessFinishDate,
      @ObjectModel.readOnly: true
      _Process.finish_time                                 as MDChgProcessFinishTime,
      @ObjectModel.readOnly: true
      _Process.update_counter                              as MDChgProcessUpdateToken,
      @ObjectModel.readOnly: true
      _Process.started                                     as MDChgProcessIsStarted,
      @ObjectModel.readOnly: true
      _Process.initialized                                 as MDChgProcessIsInitialized,
      @ObjectModel.readOnly: true
      _Process.finalized                                   as MDChgProcessIsFinalized,
      @ObjectModel.readOnly: true
      _Process.last_step_finished                          as MDChgProcessLastStepIsFinished,
      @ObjectModel.readOnly: true
      _Process.current_step_no                             as MDChgProcessCurrentStepNumber,
      @ObjectModel.readOnly: true
      _Process.check_point_active                          as MDChgProcessChkPointIsActive,
      @ObjectModel.readOnly: true
      _Process.complete_requested                          as MDChgProcessCompletionIsReqd,
      @ObjectModel.readOnly: true
      _Process.wf_delete_requested                         as MDChgProcessWrkFlwDeltnIsRqd,
      @ObjectModel.readOnly: true
      _Process.src_delete_requested                        as MDChgProcessSrceDeletionIsRqd,
      @ObjectModel.readOnly: true
      ltrim ( rtrim( _Process.filter_chain, '\\' ), '\\' ) as MDChgProcessFilterChain,
      _Process.log_error                                   as MDChgProcessErrorsAreLogged,
      @ObjectModel.readOnly: true
      _Process.last_act_key                                as MDChgProcessLastActKey,
      _Process.predecessor_id                              as MDChgProcessPredecessor,
      @ObjectModel.readOnly: true
      _Process.finalizing_at                               as MDChgProcessFinalDateTime,
      _Process.next_step_scheduled_at                      as MDChgProcessNextStpAtDateTime,
      _Process.duplicate_strategy                          as MDChgProcessDuplicateStrategy,
      _Process.reliable                                    as MDChgProcessIsReliable,
      _Process.erased                                      as MDChgProcessIsErased,
      _Process.mass_intention                              as MDChgProcessMassIntention,
      _Process.protection_reason                           as MDChgProcessProtectionReason,
      _Process.referenced_federation_token                 as MDChgProcRefcdFederationToken,
      _Process.referenced_fed_proc_step                    as MDChgProcRefcdFederationStp,
      _Process.federation_proc_bus_system                  as MDChgProcFederationBusSystName,
      //    associations

      @ObjectModel.association.type: #TO_COMPOSITION_CHILD
      _Source,
      @ObjectModel.association.type: #TO_COMPOSITION_CHILD
      _Step,
      _Auth
}
where _Auth.MasterDataChangeProcessUUID is not null