I_MDChangeProcessSourceTP

@AbapCatalog.sqlViewName: 'IMDCHGPROCSRCETP'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Master Data Change Process Source'

@ObjectModel.writeActivePersistence: 'TMDCHGPROCSRCE_W'
@ObjectModel.createEnabled
@ObjectModel.updateEnabled
@ObjectModel.deleteEnabled

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel.alternativeKey: [{
        id : 'MDCHGPROCESSSOURCE',
        uniqueness : #UNIQUE_IF_NOT_INITIAL,  
        element : ['MASTERDATACHANGEPROCESS', 'MDCHGPROCESSSRCESYSTEM', 'MDCHGPROCESSSRCESTATUS', 'MDCHGPROCESSSRCEFILTER' ]
    }]
@Search.searchable: true
define view I_MDChangeProcessSourceTP
  as select from mdc_d_prcsrc
  association [0..*] to I_MDChgProcessSourceWorklistTP as _SourceWorklist on _SourceWorklist.MDChgProcessSourceUUID = $projection.MDChgProcessSourceUUID
  association [1..1] to I_MasterDataChangeProcessTP    as _Root           on _Root.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
{
      // keys

  key db_key         as MDChgProcessSourceUUID,
      // data

      parent_key     as MasterDataChangeProcessUUID,
      process_id     as MasterDataChangeProcess,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH }
      source_system  as MDChgProcessSrceSystem,
      status         as MDChgProcessSrceStatus,
      filter         as MDChgProcessSrceFilter,
      source_records as MDChgProcessNmbrOfSrceRecords,
      //@ObjectModel.readOnly: true

      source_otc     as MDChgProcessSrceObjectTypeCode,
      @ObjectModel.readOnly: true 
      filter_chain   as MDChgProcessSrceFilterChain,
      // associations

      @ObjectModel.association.type: #TO_COMPOSITION_CHILD
      _SourceWorklist,
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _Root
}