I_MDChgProcessStepTP

@AbapCatalog.sqlViewName: 'IMDCHGPROCSTEPTP'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Master Data Change Process Step'

@ObjectModel.writeActivePersistence: 'TMDCHGPROCSTEP_W'

@ObjectModel.transactionalProcessingEnabled: true
@ObjectModel.createEnabled
@ObjectModel.updateEnabled
@ObjectModel.deleteEnabled

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@ObjectModel.alternativeKey: [{
        id : 'MDCHGPROCESSSTEP',
        uniqueness : #UNIQUE_IF_NOT_INITIAL,
        element : ['MASTERDATACHANGEPROCESS', 'MDCHGPROCESSSTEP']
    }]
   
define view I_MDChgProcessStepTP 
  as select from mdc_d_prcstep
  association [1..1] to I_MasterDataChangeProcessTP as _Root      on _Root.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  
{
      // key

  key db_key                                                                              as MDChgProcessStepUUID,
      // data

      parent_key                                                                          as MasterDataChangeProcessUUID,
      process_id                                                                          as MasterDataChangeProcess,
      @ObjectModel.readOnly: true
      step_number                                                                         as MDChgProcessStep,
      @ObjectModel.readOnly: true
      step_type                                                                           as MDChgProcessStepType,
      //use p_mdchgprocstepdescr for language dependent description of Steps from Step Type !

      //Language independent description of Step

      description                                                                         as MDChgProcessStepDescription,
      @ObjectModel.readOnly: true
      status                                                                              as MDChgProcessStepStatus,
      adapter                                                                             as MDChgProcessStepAdapter,
      adapter_config_id                                                                   as MDChgProcessStepAdapterConfign,
      check_point_active                                                                  as MDChgProcessStepChkPointIsActv,
      @ObjectModel.readOnly: true
      original_step_no                                                                    as MDChgProcessStepOriglNumber,
      @ObjectModel.readOnly: true
      original_step_seq_no                                                                as MDChgProcessStepOriglSqncNmbr,
      @ObjectModel.readOnly: true
      start_requested                                                                     as MDChgProcessStepStartIsReqd,
      @ObjectModel.readOnly: true
      source_otc                                                                          as MDChgProcessSrceObjectTypeCode,
      @ObjectModel.readOnly: true
      filter_chain                                                                        as MDChgProcessStepFilterChain,
      @ObjectModel.readOnly: true
      started_at                                                                          as MDChgProcessStepStartDateTime,
      @ObjectModel.readOnly: true
      finished_at                                                                         as MDChgProcessStepFinishDateTime,
      process_config_uuid                                                                 as MDChgProcessStepConfign,
      use_own_config                                                                      as MDChgProcessStpOwnConfignIsRqd,
      ad_hoc_step                                                                         as MDChgProcIsAdhocStep,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_STEP_CALC_EXIT'
      cast( 'X' as boole_d preserving type )                                              as MDChgProcStepIsRollbackAllowed,
      action_ctrl                                                                         as MDChgProcessStepActionControl,
      begru                                                                               as MDChgProcessStepAuthznGroup,
      @ObjectModel.readOnly: true
      scp_workflow_definition_id                                                          as MDChgProcessStepWrkflwDefID,
      scp_workflow_handle                                                                 as MDChgProcessStepWrkflwHandle,
      scp_workflow_status                                                                 as MDChgProcessStepWrkflwSts,
      scp_workflow_decision                                                               as MDChgProcessStepWrkflwOvrlDcsn,     
      local_workflow                                                                      as MDChgProcessStepLocalWorkflow,  
      local_workflow_status                                                               as MDChgProcStpLoclWorkflowStatus,
      // associations

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _Root
}