I_MDChgProcessWorklistQueryTP

DDL: I_MDCHGPROCESSWORKLISTQUERYTP Type: view TRANSACTIONAL

Process Master Data Change Process Query

I_MDChgProcessWorklistQueryTP is a Transactional CDS View that provides data about "Process Master Data Change Process Query" in SAP S/4HANA. It reads from 3 data sources (I_Mdchgprocessworklist, mdc_d_prcwlquery, mdc_search_query) and exposes 15 fields with key field MDChgProcessSrceWlQueryUUID. It has 3 associations to related views. It is exposed through 1 OData service (MASTERDATACHANGEPROCESSSD).

3 data source(s) Exposed by 1 service(s) 15 fields

Data Sources (3)

SourceAliasJoin Type
I_Mdchgprocessworklist I_Mdchgprocessworklist inner
mdc_d_prcwlquery mdc_d_prcwlquery left_outer
mdc_search_query mdc_search_query from

Associations (3)

CardinalityTargetAliasCondition
[1..1] I_MDChgProcessSourceWorklistTP _Parent _Parent.MDChgProcessSourceWorklist = $projection.MasterDataChgProcessWorklist
[1..1] I_MasterDataChangeProcessTP _Root _Root.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
[1..1] I_MDChangeProcessModelFieldVH _Field _Field.MDChgProcessSrchQueryAttribute = $projection.MDChgProcessSrchQueryAttribute and _Field.MDChgProcessSrceObjectTypeCode = $projection.MDChgProcessSrceObjectTypeCode

Annotations (12)

NameValueLevelField
EndUserText.label Process Master Data Change Process Query view
AbapCatalog.sqlViewName IMDCHGPROCQRYTP view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
ClientHandling.algorithm #SESSION_VARIABLE view
AccessControl.authorizationCheck #CHECK view
ObjectModel.writeActivePersistence IMDCHGPROCQRY_W view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view

OData Services (1)

ServiceBindingVersionContractRelease
MASTERDATACHANGEPROCESSSD MASTERDATACHANGEPROCESSSB V2 C1 NOT_RELEASED

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY MDChgProcessSrceWlQueryUUID mdc_search_query query_guid
MasterDataChangeProcessUUID _Parent MasterDataChangeProcessUUID
MDChgProcessSrceWlUUID _Parent MDChgProcessSrceWlUUID
MasterDataChangeProcess _Parent MasterDataChangeProcess
MasterDataChgProcessWorklist I_Mdchgprocessworklist MasterDataChgProcessWorklist
MDChgProcessSrchQueryAttribute attributeqry
MDChgProcessSrchQuerySign signqry
MDChgProcessSrchQueryOption optionqry
MDChgProcessSrchQueryLowValue lowqry
MDChgProcessSrchQueryHighValue highqry
MDChgProcessSrceObjectTypeCode I_Mdchgprocessworklist MDChgProcessWlObjectTypeCode
MDChangeProcessModelFieldDesc _Field MDChangeProcessModelFieldDesc
_Parent _Parent
_Root _Root
_Field _Field 
@EndUserText.label: 'Process Master Data Change Process Query'
@AbapCatalog: {
  sqlViewName: 'IMDCHGPROCQRYTP',
  compiler.compareFilter: true,
  preserveKey: true
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: {
  writeActivePersistence: 'IMDCHGPROCQRY_W',
  createEnabled,
  updateEnabled,
  deleteEnabled,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #M
  }
//  alternativeKey: [{

//    id : 'MDCHGPROCESSSRCHQUERY',

//    uniqueness : #UNIQUE_IF_NOT_INITIAL,

//    element : ['MASTERDATACHANGEPROCESS', 'MDCHGPROCESSSOURCEWORKLIST', 'MDCHGPROCESSSRCHQUERY' ]

//  }]

}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view I_MDChgProcessWorklistQueryTP
  as select from    mdc_search_query
    left outer join mdc_d_prcwlquery       on mdc_d_prcwlquery.query_guid = mdc_search_query.query_guid
    inner join      I_Mdchgprocessworklist on I_Mdchgprocessworklist.MDChgProcessWlSavedSearch = mdc_search_query.search_guid

  association [1..1] to I_MDChgProcessSourceWorklistTP as _Parent  on _Parent.MDChgProcessSourceWorklist = $projection.MasterDataChgProcessWorklist
  association [1..1] to I_MasterDataChangeProcessTP    as _Root    on _Root.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [1..1] to I_MDChangeProcessModelFieldVH  as _Field  on  _Field.MDChgProcessSrchQueryAttribute = $projection.MDChgProcessSrchQueryAttribute
                                                                   and _Field.MDChgProcessSrceObjectTypeCode = $projection.MDChgProcessSrceObjectTypeCode
{
  key mdc_search_query.query_guid                         as MDChgProcessSrceWlQueryUUID,
      _Parent.MasterDataChangeProcessUUID                 as MasterDataChangeProcessUUID,
      _Parent.MDChgProcessSrceWlUUID                      as MDChgProcessSrceWlUUID,
      _Parent.MasterDataChangeProcess                     as MasterDataChangeProcess,
      I_Mdchgprocessworklist.MasterDataChgProcessWorklist,
      @ObjectModel.foreignKey.association: '_Field'
      @Consumption.valueHelpDefinition: [{
        entity: { name: 'I_MDChangeProcessModelFieldVH', element: 'MDChgProcessSrchQueryAttribute'},
        additionalBinding: [{ usage: #FILTER, element: 'MDChgProcessSrceObjectTypeCode', localElement: 'MDChgProcessSrceObjectTypeCode' }]
      }]
      @UI.textArrangement: #TEXT_FIRST
      attributeqry                                        as MDChgProcessSrchQueryAttribute,
      signqry                                             as MDChgProcessSrchQuerySign,
      optionqry                                           as MDChgProcessSrchQueryOption,
      lowqry                                              as MDChgProcessSrchQueryLowValue,
      highqry                                             as MDChgProcessSrchQueryHighValue,
      I_Mdchgprocessworklist.MDChgProcessWlObjectTypeCode as MDChgProcessSrceObjectTypeCode,
      _Field.MDChangeProcessModelFieldDesc                as MDChangeProcessModelFieldDesc,

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
      _Parent,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _Root,
      _Field
}

Learn More