I_MDChangeProcessModelFieldVH

@AbapCatalog.sqlViewName: 'IMDCHGPRMDLFLDVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Process model field value help'
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@Search.searchable: true
@Consumption.ranked: true 
define view I_MDChangeProcessModelFieldVH
  as select from    I_MDChangeProcessModelTable as Table
    inner join      mdc_model_fields            as Field       on  Field.bo_type    = Table.MDChgProcessSrceObjectTypeCode
                                                               and Field.table_name = Table.MDChgProcessModelTableName
    inner join      dd03l                       as dd03l       on  dd03l.tabname   = Table.MDChgProcessModelTableName
                                                               and dd03l.fieldname = Field.field_name
                                                               and dd03l.as4local  = 'A'
                                                               and dd03l.as4vers   = '0000'
    left outer to one join mdc_modelcfields            as CustomField on  CustomField.bo_type    = Table.MDChgProcessSrceObjectTypeCode
                                                               and CustomField.table_name = Table.MDChgProcessModelTableName
                                                               and CustomField.field_name = Field.field_name
    left outer to many join dd04t                       as dd04t       on  dd04t.rollname   = dd03l.rollname
                                                               and dd04t.as4local   = dd03l.as4local
                                                               and dd04t.as4vers    = dd03l.as4vers
                                                               and dd04t.ddlanguage = $session.system_language
{
      @EndUserText.label: 'Attribute'
      @EndUserText.quickInfo: 'Search Query Attribute'
      @ObjectModel.text.element: ['MDChangeProcessModelFieldDesc']
      @Search.ranking: #MEDIUM
  key cast ( concat(concat(Table.MDChgProcessModelTableName, '-'), Field.field_name) as mdc_wl_attribute ) as MDChgProcessSrchQueryAttribute,
      @Consumption.filter.hidden: true
  key Table.MDChgProcessSrceObjectTypeCode                                                                           as MDChgProcessSrceObjectTypeCode,
      @EndUserText.label: 'Table'
      @EndUserText.quickInfo: 'Table Name'
      @Search.ranking: #HIGH
      Table.MDChgProcessModelTableName                                                                               as MDChgProcessModelTableName,
      @EndUserText.label: 'Table Description'
      @Search.ranking: #LOW
      Table.MDChangeProcModelTableDesc                                                                               as MDChangeProcModelTableDesc,
      @EndUserText.label: 'Field'
      @Search.ranking: #MEDIUM
      Field.field_name                                                                                               as MDChangeProcessModelFieldName,
      @EndUserText.label: 'Field Description'
      @Semantics.text: true
      @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.6, ranking: #LOW}
      dd04t.ddtext                                                                                                   as MDChangeProcessModelFieldDesc,
      @UI.hidden : true
      dd03l.keyflag                                                                                                  as IsKeyField
}
where
  (
    (
      (
            CustomField.obscured                 is initial
        or  CustomField.obscured                 is null
        and Field.obscured                       is initial
      )
      and(
            CustomField.technical                is initial
        or  CustomField.technical                is null
        and Field.technical                      is initial
      )
    )
    or(
            CustomField.selective                is not initial
      or    CustomField.selective                is null
      and   Field.selective                      is not initial
    )
  )