I_ChmlCmplncProdAssgmt

@EndUserText.label: 'Chemical Compliance Product Assignment'

@AbapCatalog:
{
  sqlViewName: 'ICCPRODASSGMT',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #CHECK
}

@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  }
}


@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_ChmlCmplncProdAssgmt
  as select from ehfndv_cci_prod
  // packaged product

  association [1..1] to I_ChmlCmplncInfo as _ChmlCmplncInfo on _ChmlCmplncInfo.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID
  // unpackaged product

  association [1..1] to I_ChmlCmplncInfo as _ChmlCmplncInfoProduct on _ChmlCmplncInfoProduct.ChmlCmplncInfoUUID = $projection.ChmlCmplncProdUUID
{
  key chmlcmplncprodassgmtuuid as ChmlCmplncProdAssgmtUUID,
      // UUID of packaged product

      chmlcmplncinfouuid       as ChmlCmplncInfoUUID,
      // UUID of unpackaged product

      @ObjectModel.foreignKey.association: '_ChmlCmplncInfoProduct'
      chmlcmplncproduuid       as ChmlCmplncProdUUID,
      
      @Semantics.systemDateTime.createdAt: true
      cast(creationutcdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationUTCDateTime,
      @Semantics.user.createdBy: true
      cast(createdbyuser as ehfnd_bo_crea_uname preserving type )             as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeUTCDateTime,
      @Semantics.user.lastChangedBy: true
      cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )         as LastChangedByUser,
      
      -- associations
      _ChmlCmplncInfo,
      _ChmlCmplncInfoProduct
}