C_ChmlCmplncProdAssgmt

@EndUserText.label: 'Chemical Compliance Packaged Product Assignment'

@AbapCatalog:
{
  sqlViewName: 'CCCPRODASSGMT',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  // blocking of personal data not required (no personal data fields exposed for material (MARA))

  personalData.blocking: #NOT_REQUIRED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  semanticKey:  [ 'MaterialName' ],
  usageType:
  {
    /*Service Quality - reflects the quality of service with respect to the expected performance of the CDS view:
      #A: may be consumed within business logic for high volume transactions or background processing
      #B: may be consumed within business logic for transactions or background processing
    */
    dataClass: #MASTER,
    sizeCategory: #M,
    serviceQuality: #C
  }
}

--Header information
  /*define data for the header*/
@UI:
{
  headerInfo:
  {
    typeName: 'Compliance Views for Related Packaged Products',
    typeNamePlural: 'Compliance Views for Related Packaged Products'
  },
  presentationVariant:
  {
    requestAtLeast: ['ChmlCmplncInfoUUID', 'ChmlCmplncProdUUID', 'Material', 'ChmlCmplncInfoType', 'ProdStewardshipRespUnit', 'MaterialIsTransported', 'MaterialIsSold', 'MaterialIsProduced', 'MaterialIsSourced', 'ChmlCmplncChgLogsRoleIsAllwd' ],
    sortOrder:
    {
      by: 'Material',
      direction: #ASC
    }
  }
}

@Search.searchable: true

define view C_ChmlCmplncProdAssgmt
  as select from I_ChmlCmplncProdAssgmt
  association [1..1] to C_ChmlCmplncMatlAssgmtTP as _MatAss on _MatAss.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID

{
      @UI.hidden: true
  key ChmlCmplncProdAssgmtUUID,

      @ObjectModel.mandatory: true
      @UI.hidden: true
      ChmlCmplncInfoUUID,

      //--[ GENERATED:012:GlBfhyFV7jY4i}8L6{LzUW

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ChmlCmplncInfoStdVH',
                     element: 'ChmlCmplncInfoUUID' }
        }]
      // ]--GENERATED

      @ObjectModel.mandatory: true
      @UI.hidden: true
      ChmlCmplncProdUUID,

      @UI:
      {
        lineItem:
        {
          position: 10,
          importance: #HIGH
        }
      }
      @ObjectModel.readOnly: true
      @ObjectModel.text.element: ['MaterialName']
      @UI.textArrangement: #TEXT_SEPARATE
      @Search: {
        defaultSearchElement : true,
        fuzzinessThreshold: 0.7,
        ranking: #MEDIUM
      }
      _MatAss.Material,

      @UI:
      {
        lineItem:
        {
          position: 20,
          importance: #HIGH
        }
      }
      @ObjectModel.readOnly: true
      @Search: {
        defaultSearchElement : true,
        fuzzinessThreshold: 0.7,
        ranking: #MEDIUM
      }
      _MatAss.MaterialName,

      @UI:
      {
        lineItem:
        {
          position: 30,
          importance: #LOW
        },
        textArrangement: #TEXT_ONLY
      }
      @ObjectModel:
      {
        readOnly: true,
        text.element:  [ 'MaterialGroupName' ]
      }
      _MatAss.MaterialGroup,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      _MatAss.MaterialGroupName,

      -----------------------------------------------------------------------------------------------------------------------------------------------------------------
      -- CCI Type and Roles
      -----------------------------------------------------------------------------------------------------------------------------------------------------------------
      --Chemical Compliance Information Type
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _ChmlCmplncInfo.ChmlCmplncInfoType,

      --Responsible Unit
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _ChmlCmplncInfo.ProdStewardshipRespUnit,

      --Indicator: Chemical Compliance Information is transported
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _ChmlCmplncInfo.MaterialIsTransported,

      --Indicator: Chemical Compliance Information is sold
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _ChmlCmplncInfo.MaterialIsSold,

      --Indicator: Chemical Compliance Information is produced
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _ChmlCmplncInfo.MaterialIsProduced,

      --Indicator: Chemical Compliance Information is sourced
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _ChmlCmplncInfo.MaterialIsSourced,

      -----------------------------------------------------------------------------------------------------------------------------------------------------------------
      -- Logistics Roles Info
      -----------------------------------------------------------------------------------------------------------------------------------------------------------------
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_CHGROLE_CALC_EXIT'
      @UI:
      {
        lineItem:
        {
          position: 40,
          importance: #LOW
        }
      }
      @ObjectModel.readOnly: true
      cast('' as ehfnd_cci_log_role_info)                  as ChmlCmplncCurLogsRole,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_CHGROLE_CALC_EXIT'
      @UI.hidden: true
      @ObjectModel.readOnly: true
      cast('' as ehfnd_cci_chg_role_allwd preserving type) as ChmlCmplncChgLogsRoleIsAllwd,

      /* Associations */
      _ChmlCmplncInfoProduct,
      _MatAss
}