I_ChmlCmplncProdAssgmtDimn

@AbapCatalog.sqlViewName: 'ICCPRODASSGMTD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ObjectModel.representativeKey: 'Product'

@EndUserText.label: 'Dimension Prodcut Assignment'

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@ClientHandling:
{
  type: #INHERITED,
  algorithm: #SESSION_VARIABLE
}

@VDM.viewType: #COMPOSITE

@ObjectModel.usageType:{ serviceQuality: #D,
                         sizeCategory: #XL,
                         dataClass: #MIXED }

@Analytics.dataCategory: #DIMENSION

@Metadata.allowExtensions: true

/*----------------------------------------------------------------------------------------------------------------------
    Dimension Product Assignments for Analytics
------------------------------------------------------------------------------------------------------------------------*/

define view I_ChmlCmplncProdAssgmtDimn
  as select from I_ChmlCmplncProdAssgmt as _ChmlCmplncProdAssgmt
  -- inner join to Chemical Compliance Information of Unpackaged Product
    inner join   I_ChmlCmplncAnlyts1    as _UnpackagedProduct on  _ChmlCmplncProdAssgmt.ChmlCmplncProdUUID = _UnpackagedProduct.ChmlCmplncInfoUUID
                                                              and _UnpackagedProduct.MatlAssgmtIsPrimary   = 'X'

  -- Association to Substance
  association [0..1] to I_Substance           as _Substance       on _UnpackagedProduct.SubstanceUUID = _Substance.SubstanceUUID

  -- Association to Composition Type
  association [0..1] to I_ChmlCompositionType as _CompositionType on _UnpackagedProduct.ChmlCompositionType = _CompositionType.ChmlCompositionType

  -- packaged product
  association [1..1] to I_ChmlCmplncInfo      as _ChmlCmplncInfo1 on _ChmlCmplncProdAssgmt.ChmlCmplncInfoUUID = _ChmlCmplncInfo1.ChmlCmplncInfoUUID

{
      -- UUID of Chemical Compliance Info of Packaged Product
      @ObjectModel.foreignKey.association: '_ChmlCmplncInfo1'
  key _ChmlCmplncProdAssgmt.ChmlCmplncInfoUUID                                           as ChmlCmplncInfoUUID,

      -- Material assigned to Packaged Product
  key _ChmlCmplncInfo._MaterialAssignment.Material                                       as Product,

      -- UUID of Company Substance from Composition of Unpackaged Product
      @ObjectModel.foreignKey.association: '_Substance'
  key _UnpackagedProduct.SubstanceUUID                                                   as SubstanceUUID,

      -- Composition Type
      @ObjectModel.foreignKey.association: '_CompositionType'
  key _UnpackagedProduct.ChmlCompositionType,

      -- Material is Sold flag of Packaged Product
      _ChmlCmplncInfo.MaterialIsSold                                                     as MaterialIsSold,

      -- Material assigned to Unpackaged Product
      _UnpackagedProduct.Material,

      -- Product Group of assigned material of Unpackaged Product
      _UnpackagedProduct.ProductGroup,

      -- UUID of Chemical Compliance Info of Unpackaged Product
      cast( _ChmlCmplncProdAssgmt.ChmlCmplncProdUUID as ehfnd_cci_uuid preserving type ) as ChmlCmplncProdUUID,

      -- Associations
      _ChmlCmplncInfo,
      _ChmlCmplncInfo1,
      _CompositionType,
      _Substance
}
where
  MaterialIsSold = 'X'