@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Journal Entry'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
serviceQuality: #X,
sizeCategory: #XXL,
dataClass: #MIXED
}
@AccessControl.privilegedAssociations: ['_CreatedByContactCard', '_ParkedByUserContactCard']
@VDM: {
viewType: #CONSUMPTION,
usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
}
@UI.headerInfo: {
typeName: 'Journal Entry',
typeNamePlural: 'Journal Entries',
title: {
value: 'AccountingDocument',
label: 'Journal Entry'
},
description: { type: #STANDARD, value: 'AccountingDocumentHeaderText' }
}
@UI.presentationVariant: [{
text: 'Journal Entries',
//qualifier: 'VAR_DOCHEADER',
sortOrder: [{
by: 'DocumentDate',
direction: #DESC
},
{
by: 'AccountingDocument',
direction: #DESC
}]
}]
define root view entity C_ManageJournalEntryTP
provider contract transactional_query
as projection on R_ManageJournalEntryTP as _JournalEntry
association [1..*] to C_MngJrnlEntrCrcyTranslation as _CrcyTranslation
on $projection.CompanyCode = _CrcyTranslation.CompanyCode
and $projection.FiscalYear = _CrcyTranslation.FiscalYear
and $projection.AccountingDocument = _CrcyTranslation.AccountingDocument
association [1..*] to C_ManageJournalEntryLedgerView as _ItemGLView
on $projection.CompanyCode = _ItemGLView.CompanyCode
and $projection.FiscalYear = _ItemGLView.FiscalYear
and $projection.AccountingDocument = _ItemGLView.AccountingDocument
association [1..*] to C_MngJrnlEntrTechLedgerView as _ItemTechnicalLedgerView
on $projection.CompanyCode = _ItemTechnicalLedgerView.CompanyCode
and $projection.FiscalYear = _ItemTechnicalLedgerView.FiscalYear
and $projection.AccountingDocument = _ItemTechnicalLedgerView.AccountingDocument
association [0..*] to C_ManageJournalEntryLedger as _JournalEntryLedger
on $projection.CompanyCode = _JournalEntryLedger.CompanyCode
and $projection.FiscalYear = _JournalEntryLedger.FiscalYear
and $projection.AccountingDocument = _JournalEntryLedger.AccountingDocument
association [0..*] to C_MngJrnlEntrReltdJournalEntry as _RelatedJournalEntry
on $projection.OriginalReferenceDocument = _RelatedJournalEntry.OriginalReferenceDocument
and $projection.ReferenceDocumentType = _RelatedJournalEntry.ReferenceDocumentType
and $projection.AccountingDocument <> _RelatedJournalEntry.AccountingDocument
association [0..*] to C_MngJrnlEntrRelatedDocument as _RelatedDocument
on $projection.CompanyCode = _RelatedDocument.CompanyCode
and $projection.FiscalYear = _RelatedDocument.FiscalYear
and $projection.AccountingDocument = _RelatedDocument.AccountingDocument
association [0..*] to C_ManageJournalEntryTaxItem as _TaxItem
on $projection.CompanyCode = _TaxItem.CompanyCode
and $projection.AccountingDocument = _TaxItem.AccountingDocument
and $projection.FiscalYear = _TaxItem.FiscalYear
association [0..*] to C_MngJrnlEntrPrkdDocTaxItem as _ParkedTaxItem
on $projection.CompanyCode = _ParkedTaxItem.SourceCompanyCode
and $projection.AccountingDocument = _ParkedTaxItem.AccountingDocument
and $projection.FiscalYear = _ParkedTaxItem.FiscalYear
association [1..*] to C_MngJrnlEntrPrkdDocumentItem as _ParkedItem
on _JournalEntry.CompanyCode = _ParkedItem.SourceCompanyCode
and _JournalEntry.AccountingDocument = _ParkedItem.SourceAccountingDocument
and _JournalEntry.FiscalYear = _ParkedItem.SourceFiscalYear
association [0..*] to C_ManageJournalEntryNote as _Note
on _JournalEntry.CompanyCode = _Note.CompanyCode
and _JournalEntry.AccountingDocument = _Note.AccountingDocument
and _JournalEntry.FiscalYear = _Note.FiscalYear
{
@UI.facet:[
{ label: 'General Information',
id: 'GeneralInformation',
type: #COLLECTION,
purpose: #STANDARD,
position: 10 },
{ id: 'TransactionDataFldGrp',
type: #FIELDGROUP_REFERENCE,
purpose: #STANDARD,
parentId: 'GeneralInformation',
position: 10,
targetQualifier: 'TransactionDataFldGrp',
label: 'Transaction Data' },
{ id: 'DateTimeFldGrp',
type: #FIELDGROUP_REFERENCE,
purpose: #STANDARD,
parentId: 'GeneralInformation',
position: 20,
targetQualifier: 'DateTimeFldGrp',
label: 'Date & Time' },
{ id: 'AmountFldGrp',
type: #FIELDGROUP_REFERENCE,
purpose: #STANDARD,
parentId: 'GeneralInformation',
position: 30,
targetQualifier: 'AmountFldGrp',
label: 'Amounts' },
{ id: 'TaxesFldGrp',
type: #FIELDGROUP_REFERENCE,
purpose: #STANDARD,
parentId: 'GeneralInformation',
position: 60,
targetQualifier: 'TaxesFldGrp',
label: 'Taxes'},
//isPartOfPreview: #(UICT_TaxesFieldGroup) },
{ id: 'WFFldGrp',
type: #FIELDGROUP_REFERENCE,
purpose: #STANDARD,
parentId: 'GeneralInformation',
position: 50,
targetQualifier: 'WFFldGrp',
label: 'Workflow' },
{ id: 'CurrencyTranslation',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'Historical Exchange Rates',
position: 30,
targetElement: '_CrcyTranslation',
hidden: #(UICT_CurrencyTranslation)},
{ id: 'TaxItem',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'Taxes',
position: 50,
targetElement: '_TaxItem',
hidden: #(UICT_TaxItem)},
{ id: 'ParkedTaxItem',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'Taxes',
position: 60,
targetElement: '_ParkedTaxItem',
hidden: #(UICT_ParkedTaxItem)},
{ id: 'RelatedJE',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'Associated Journal Entries',
position: 70,
targetElement: '_RelatedJournalEntry',
hidden: #(UICT_RelatedJE)},
{ id: 'RelatedDoc',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'Related Documents',
position: 80,
targetElement: '_RelatedDocument',
hidden: #(UICT_RelatedDocument)},
{ id: 'AttachmentFacet',
purpose: #STANDARD,
type: #FIELDGROUP_REFERENCE,
label: 'Attachments',
position: 90},
{ id: 'CountrySpecificFldGrp',
type: #FIELDGROUP_REFERENCE,
purpose: #STANDARD,
parentId: 'GeneralInformation',
position: 70,
targetQualifier: 'CountrySpecificFldGrp',
label: 'Country/Region-Specific Data'} ]
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeVH', element: 'CompanyCode' } }]
@UI: {
lineItem: [{ position: 30 }],
selectionField: [{ position: 10 }],
fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 20, importance: #HIGH} ]
}
@ObjectModel.text.element: ['CompanyCodeName']
@UI.textArrangement: #TEXT_LAST
key _JournalEntry.CompanyCode,
@UI: {
selectionField: [{ position: 60 }]
}
@Semantics.fiscal.year: true
key _JournalEntry.FiscalYear,
@Consumption.semanticObject: 'AccountingDocument'
@UI: {
lineItem: [{ position: 10 }],
selectionField: [{ position: 30 }]
}
key _JournalEntry.AccountingDocument,
// @UI: {
// lineItem: [{ position: 10 }],
// selectionField: [{ position: 10 }]
// }
// // Why is there IF lr_header->rfccur IS INITIAL. (?)
// case
// when _JournalEntry.Ledger is not initial then _JournalEntry.Ledger
// when _LedgerGroupAssignment.Ledger is not initial then _LedgerGroupAssignment.Ledger
// else _LeadingLedger.Ledger
// end as Ledger, // RLDNR
//
// @UI.hidden: true
// _JournalEntry.TechnicalLedger,
//
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_AccountingDocumentCategory', element: 'AccountingDocumentCategory' } }]
@UI: {
lineItem: [{ position: 90 }],
selectionField: [{ position: 100 }],
fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 50, importance: #HIGH, hidden: #(UICT_AccountingDocumentCat)} ]
}
@ObjectModel.text.element: [ 'AccountingDocumentCategoryName' ]
@UI.textArrangement: #TEXT_LAST
_JournalEntry.AccountingDocumentCategory,
@Semantics.text: true
@UI.hidden: true
_AccountingDocumentCategoryT.AccountingDocumentCategoryName,
@UI: {
lineItem: [{ position: 70 }],
fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 1, importance: #HIGH, hidden: #(UICT_AcctgDocumentHeaderText)}]
}
_JournalEntry.AccountingDocumentHeaderText,
_JournalEntry.SenderAccountingDocument,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_AccountingDocumentTypeStdVH', element: 'AccountingDocumentType' } }]
@UI: {
lineItem: [{ position: 20 }],
selectionField: [{ position: 90 }],
fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 10, importance: #HIGH} ]
}
@ObjectModel.text.element: [ 'AccountingDocumentTypeName' ]
@UI.textArrangement: #TEXT_LAST
_JournalEntry.AccountingDocumentType,
@Semantics.text: true
@UI.hidden: true
_AccountingDocumentTypeText.AccountingDocumentTypeName,
// NOT IN I_JournalEntry
// @UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 60, importance: #HIGH, hidden: #(UICT_AccountingPrinciple) } ]
// _JournalEntry.AccountingPrinciple,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_Currency', element: 'Currency' } }]
_JournalEntry.AdditionalCurrency1,
// NOT IN I_JournalEntry
// _JournalEntry.AdditionalCrcy1ExchangeRate,
_JournalEntry.AdditionalCurrency1Role,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_Currency', element: 'Currency' } }]
_JournalEntry.AdditionalCurrency2,
// NOT IN I_JournalEntry
// _JournalEntry.AdditionalCrcy2ExchangeRate,
_JournalEntry.AdditionalCurrency2Role,
// _JournalEntry.AdditionalCrcy2RoleName,
_JournalEntry.AlternativeReferenceDocument,
@UI: {
lineItem: [{ position: 60 }],
fieldGroup: [ { qualifier: 'AmountFldGrp', position: 10, importance: #HIGH, hidden: #(UICT_IsAmountHidden)} ]
}
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_AMOUNT_CALC'
@ObjectModel.filter.transformedBy: 'ABAP:CL_MJE_FILTER_TRANSFORM'
@ObjectModel.sort.transformedBy: 'ABAP:CL_MJE_SORT_TRANSFORM'
virtual AmountInCompanyCodeCurrency: fis_hsl,
@UI.fieldGroup: [ { qualifier: 'AmountFldGrp', position: 30, importance: #HIGH, hidden: #(UICT_IsParkedDocument)} ]
@Semantics.amount.currencyCode: 'FunctionalCurrency'
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_AMOUNT_CALC'
@ObjectModel.filter.transformedBy: 'ABAP:CL_MJE_FILTER_TRANSFORM'
@ObjectModel.sort.transformedBy: 'ABAP:CL_MJE_SORT_TRANSFORM'
virtual AmountInFunctionalCurrency: fis_vfccur12,
@UI.fieldGroup: [ { qualifier: 'AmountFldGrp', position: 20, importance: #HIGH, hidden: #(UICT_IsAmountHidden)} ]
@Semantics.amount.currencyCode: 'TransactionCurrency'
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_AMOUNT_CALC'
@ObjectModel.filter.transformedBy: 'ABAP:CL_MJE_FILTER_TRANSFORM'
@ObjectModel.sort.transformedBy: 'ABAP:CL_MJE_SORT_TRANSFORM'
virtual AmountInTransactionCurrency: fis_wsl,
// NOT IN I_JournalEntry
// _JournalEntry.AuthorizationCheckLedger,
// NOT IN I_JournalEntry
// _JournalEntry.AuthorizationGroupDocumentType,
@UI: {
fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 25, importance: #HIGH, hidden: #(UICT_Branch)} ]
}
_JournalEntry.Branch,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessTransactionTypeVH', element: 'BusinessTransactionType' } }]
_JournalEntry.BusinessTransactionType,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_Currency', element: 'Currency' } }]
_JournalEntry.CompanyCodeCurrency,
@Semantics.text: true
_CompanyCode.CompanyCodeName,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeVH', element: 'CompanyCode' } }]
_JournalEntry.SenderCompanyCode,
// NOT IN I_JournalEntry
// _JournalEntry.ControllingDocumentSender,
@Consumption.valueHelpDefinition: [ { entity: { name: 'C_ManageJournalEntryUserVH', element: 'UserID' } }]
@UI: {
lineItem: [{ position: 80 }],
selectionField: [{ position: 80 }],
fieldGroup: [ { qualifier: 'DateTimeFldGrp', position: 40, importance: #HIGH } ]
}
@ObjectModel.text.element: [ 'CreatedByUserName' ]
@UI.textArrangement: #TEXT_LAST
_JournalEntry.AccountingDocCreatedByUser,
@Semantics.text: true
@UI.hidden: true
_JournalEntry._CreatedByContactCard.FullName as CreatedByUserName,
@UI.hidden: true
_JournalEntry.AccountingDocumentCreationDate,
@UI.hidden: true
_JournalEntry.CreationTime,
@Consumption.filter.selectionType: #INTERVAL
@UI.fieldGroup: [ { qualifier: 'DateTimeFldGrp', position: 50, importance: #HIGH} ]
@ObjectModel.filter.transformedBy: 'ABAP:CL_MJE_DATETIME_FLTR_TRANSFORM'
_JournalEntry.CreationDateTime,
// NOT IN I_JournalEntry
// _JournalEntry.LocalCreationDate,
@Consumption.filter.selectionType: #INTERVAL
@UI: {
lineItem: [{ position: 40 }],
selectionField: [{ position: 40 }],
fieldGroup: [ { qualifier: 'DateTimeFldGrp', position: 10, importance: #HIGH} ]
}
_JournalEntry.DocumentDate,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 30, importance: #HIGH} ]
_JournalEntry.DocumentReferenceID,
@UI.fieldGroup: [ { qualifier: 'AmountFldGrp', position: 40, importance: #HIGH, hidden: #(UICT_ExchangeRate) } ]
_JournalEntry.AbsoluteExchangeRate,
@Consumption.filter.selectionType: #INTERVAL
@UI.fieldGroup: [ { qualifier: 'DateTimeFldGrp', position: 80, importance: #HIGH, hidden: #(UICT_ExchangeRateDate) } ]
_JournalEntry.ExchangeRateDate,
@UI.fieldGroup: [ { qualifier: 'TaxesFldGrp', position: 50, importance: #HIGH, hidden: #(UICT_TaxExchangeRate) } ]
_JournalEntry.TaxAbsoluteExchangeRate,
@UI.fieldGroup: [ { qualifier: 'TaxesFldGrp', position: 55, importance: #HIGH, hidden: #(UICT_CtryCrcyTaxExchangeRate) } ]
_JournalEntry.CtryCrcyTxAbsoluteExchangeRate,
@UI.fieldGroup: [ { qualifier: 'AmountFldGrp', position: 45, importance: #HIGH, hidden: #(UICT_MarketDataExchangeRate) } ]
_JournalEntry.MarketDataAbsoluteExchangeRate,
@UI.fieldGroup: [ { qualifier: 'TaxesFldGrp', position: 56, importance: #HIGH, hidden: #(UICT_TaxCountry) } ]
@ObjectModel.text.element: [ 'TaxCountryName' ]
@UI.textArrangement: #TEXT_LAST
_JournalEntry.TaxCountry,
@Semantics.text: true
@UI.hidden: true
_JournalEntry._TaxCountryText.CountryName as TaxCountryName,
_JournalEntry.ExchangeRateType,
@UI.selectionField: [{ position: 70 }]
@Semantics.fiscal.period: true
_JournalEntry.FiscalPeriod,
@UI.fieldGroup: [ { qualifier: 'DateTimeFldGrp', position: 30, importance: #HIGH} ]
@Semantics.fiscal.yearPeriod: true
_JournalEntry.FiscalYearPeriod,
@Semantics.fiscal.year: true
_JournalEntry.SenderFiscalYear,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_Currency', element: 'Currency' } }]
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_AMOUNT_CALC'
@ObjectModel.filter.transformedBy: 'ABAP:CL_MJE_FILTER_TRANSFORM'
@ObjectModel.sort.transformedBy: 'ABAP:CL_MJE_SORT_TRANSFORM'
virtual FunctionalCurrency: fins_currfc,
// NOT IN I_JournalEntry
// _JournalEntry.GroupCurrency,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 100, importance: #HIGH, hidden: #(UICT_CrossCC) } ]
@Consumption.semanticObject: 'AccountingDocument'
_JournalEntry.IntercompanyTransaction,
@Consumption.filter.selectionType: #INTERVAL
@UI.fieldGroup: [ { qualifier: 'TaxesFldGrp', position: 20, importance: #HIGH, hidden: #(UICT_InvoiceReceiptDate) } ]
_JournalEntry.InvoiceReceiptDate,
@Consumption.filter.selectionType: #INTERVAL
@UI.hidden: #(UICT_LastManualChangeDate)
@UI.fieldGroup: [ { qualifier: 'DateTimeFldGrp', position: 100, hidden: #(UICT_LastManualChangeDate) } ]
_JournalEntry.LastManualChangeDate,
@UI.hidden: true
_JournalEntry.LastAutomaticChangeDate,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_LedgerGroupVH', element: 'LedgerGroup' } }]
@UI: {
selectionField: [{ position: 20 }],
fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 70, importance: #HIGH, hidden: #(UICT_LedgerGroup) } ]
}
@ObjectModel.text.element: [ 'LedgerGroupName' ]
@UI.textArrangement: #TEXT_LAST
_JournalEntry.LedgerGroup,
@Semantics.text: true
@UI.hidden: true
_LedgerGroupText.LedgerGroupName,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_LogicalSystem', element: 'LogicalSystem' } }]
_JournalEntry.SenderLogicalSystem,
// NOT IN I_JournalEntry
// _JournalEntry.MarketDataExchangeRate,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 130, hidden: #(UICT_NmbrOfPages)} ]
_JournalEntry.NmbrOfPages,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 45, importance: #HIGH, hidden: #(UICT_OriglReferenceDocument) } ]
@Consumption.semanticObject: 'AccountingDocument'
@Consumption.semanticObjectMapping.additionalBinding: [{ localElement: 'OriginalReferenceDocument', element: 'OriginalReferenceDocument' }]
_JournalEntry.OriginalReferenceDocument,
_JournalEntry.ReferenceDocumentLogicalSystem,
@UI.hidden: true
_JournalEntry.ParkingTime,
@Consumption.valueHelpDefinition: [ { entity: { name: 'C_ManageJournalEntryUserVH', element: 'UserID' } }]
@UI: {
fieldGroup: [ { qualifier: 'DateTimeFldGrp', position: 60, hidden: #(UICT_Parked) } ]
}
@EndUserText.label: 'Submitted/Parked By'
@EndUserText.quickInfo: 'Submitted/Parked By'
@ObjectModel.text.element: [ 'ParkedByUserName' ]
@UI.textArrangement: #TEXT_LAST
_JournalEntry.ParkedByUser,
@Semantics.text: true
@UI.hidden: true
_JournalEntry._ParkedByUserContactCard.FullName as ParkedByUserName,
@UI.hidden: true
_JournalEntry.ParkingDate,
@Consumption.filter.selectionType: #INTERVAL
@UI.fieldGroup: [ { qualifier: 'DateTimeFldGrp', position: 70, importance: #HIGH, hidden: #(UICT_Parked) } ]
@ObjectModel.filter.transformedBy: 'ABAP:CL_MJE_DATETIME_FLTR_TRANSFORM'
@EndUserText.label: 'Submitted/Parked On'
@EndUserText.quickInfo: 'Submitted/Parked On'
_JournalEntry.ParkingDateTime,
// NOT IN I_JournalEntry
// _JournalEntry.LocalParkedDate,
// NOT IN I_JournalEntry
// _JournalEntry.ParkTransaction,
@Consumption.filter.selectionType: #INTERVAL
@UI: {
lineItem: [{ position: 50 }],
selectionField: [{ position: 50 }],
fieldGroup: [ { qualifier: 'DateTimeFldGrp', position: 20, importance: #HIGH} ]
}
_JournalEntry.PostingDate,
// NOT IN I_JournalEntry
// _JournalEntry.RecrrgAccDocTemplCompanyCode,
// NOT IN I_JournalEntry
// _JournalEntry.RecurringAccDocTemplFiscalYear,
_JournalEntry.RecurringAccountingDocument,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 110, hidden: #(UICT_Reference1InDocumentHdr)} ]
_JournalEntry.Reference1InDocumentHeader,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 120, hidden: #(UICT_Reference2InDocumentHdr)} ]
_JournalEntry.Reference2InDocumentHeader,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ReferenceDocumentTypeVH', element: 'ReferenceDocumentType' } }]
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 40, importance: #HIGH} ]
@ObjectModel.text.element: [ 'ReferenceDocumentTypeName' ]
@UI.textArrangement: #TEXT_LAST
_JournalEntry.ReferenceDocumentType,
@Semantics.text: true
@UI.hidden: true
_ReferenceDocumentTypeText.ReferenceDocumentTypeName,
// NOT IN I_JournalEntry
// _JournalEntry.ReversalFunction,
// _JournalEntry.ReversalFunctionName,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 95, importance: #HIGH, hidden: #(UICT_ReversalReason)} ]
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ReversalReasonValueHelp', element: 'ReversalReason' } }]
@ObjectModel.text.element: [ 'ReversalReasonName' ]
@UI.textArrangement: #TEXT_LAST
_JournalEntry.ReversalReason,
@Semantics.text: true
@UI.hidden: true
_ReversalReasonText.ReversalReasonName,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 81, importance: #HIGH, hidden: #(UICT_ReversalReferenceDocument)} ]
_JournalEntry.ReversalReferenceDocument,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 91, importance: #HIGH, hidden: #(UICT_ReversedReferenceDocument)} ]
_JournalEntry.ReversedReferenceDocument,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 80, importance: #HIGH, hidden: #(UICT_ReversalReference)} ]
@Consumption.semanticObject: 'AccountingDocument'
@Consumption.semanticObjectMapping.additionalBinding: [{ localElement: 'ReverseDocumentFiscalYear', element: 'FiscalYear' },
{ localElement: 'ReverseDocument', element: 'AccountingDocument' } ]
@EndUserText.label: 'Reversed By'
@EndUserText.quickInfo: 'Reversed By'
_JournalEntry.ReverseDocument,
@UI.fieldGroup: [ { qualifier: 'TransactionDataFldGrp', position: 90, importance: #HIGH, hidden: #(UICT_ReversedReference)} ]
@Consumption.semanticObject: 'AccountingDocument'
@Consumption.semanticObjectMapping.additionalBinding: [{ localElement: 'ReverseDocumentFiscalYear', element: 'FiscalYear' },
{ localElement: 'ReversedDocument', element: 'AccountingDocument' } ]
@EndUserText.label: 'Reversal Of'
@EndUserText.quickInfo: 'Reversal Of'
_JournalEntry.ReversedDocument,
@Semantics.booleanIndicator
_JournalEntry.IsReversal,
@Semantics.booleanIndicator
_JournalEntry.IsReversed,
_JournalEntry.ReverseDocumentFiscalYear,
@Consumption.filter.selectionType: #INTERVAL
@UI.fieldGroup: [ { qualifier: 'DateTimeFldGrp', position: 90, importance: #HIGH, hidden: #(UICT_PlannedReversalDate) } ]
_JournalEntry.PlannedReversalDate,
@Semantics.booleanIndicator
_JournalEntry.TaxBaseAmountIsNetAmount,
@Consumption.filter.hidden: true
@UI.fieldGroup: [ { qualifier: 'TaxesFldGrp', position: 70, importance: #HIGH, hidden: #(UICT_TaxItemOP) } ]
@ObjectModel.text.element: [ 'TaxBaseAmountOriginText' ]
@UI.textArrangement: #TEXT_ONLY
_JournalEntry.TaxBaseAmountOrigin,
@Semantics.text: true
@UI.hidden: true
_JournalEntry._MngJrnlEntrTxBaseAmtOrignTxt.TaxBaseAmountOriginText,
@Consumption.filter.selectionType: #INTERVAL
@UI.fieldGroup: [ { qualifier: 'TaxesFldGrp', position: 40, importance: #HIGH, hidden: #(UICT_TaxFulfillmentDate) } ]
_JournalEntry.TaxFulfillmentDate,
@Semantics.booleanIndicator
_JournalEntry.TaxIsCalculatedAutomatically,
@Consumption.filter.hidden: true
@UI.fieldGroup: [ { qualifier: 'TaxesFldGrp', position: 60, importance: #HIGH, hidden: #(UICT_TaxItemOP) } ]
@ObjectModel.text.element: [ 'TaxCalculationTypeText' ]
@UI.textArrangement: #TEXT_ONLY
_JournalEntry.TaxCalculationType,
@Semantics.text: true
@UI.hidden: true
_JournalEntry._MngJrnlEntrTaxCalcTypeText.TaxCalculationTypeText,
@Consumption.filter.selectionType: #INTERVAL
@UI.fieldGroup: [ { qualifier: 'TaxesFldGrp', position: 30, importance: #HIGH, hidden: #(UICT_TaxReportingDate) } ]
_JournalEntry.TaxReportingDate,
@Consumption.filter.selectionType: #INTERVAL
@UI.fieldGroup: [ { qualifier: 'TaxesFldGrp', position: 10, importance: #HIGH, hidden: #(UICT_WhgdTaxReportingDate) } ]
_JournalEntry.WithholdingTaxReportingDate,
_JournalEntry.TransactionCode,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_Currency', element: 'Currency' } }]
_JournalEntry.TransactionCurrency,
@UI.fieldGroup: [ { qualifier: 'CountrySpecificFldGrp', position: 10, importance: #HIGH } ]
_JournalEntry.JrnlEntryCntrySpecificRef1,
@Consumption.filter.selectionType: #INTERVAL
_JournalEntry.JrnlEntryCntrySpecificDate1,
_JournalEntry.JrnlEntryCntrySpecificRef2,
@Consumption.filter.selectionType: #INTERVAL
_JournalEntry.JrnlEntryCntrySpecificDate2,
_JournalEntry.JrnlEntryCntrySpecificRef3,
@Consumption.filter.selectionType: #INTERVAL
_JournalEntry.JrnlEntryCntrySpecificDate3,
_JournalEntry.JrnlEntryCntrySpecificRef4,
@Consumption.filter.selectionType: #INTERVAL
_JournalEntry.JrnlEntryCntrySpecificDate4,
_JournalEntry.JrnlEntryCntrySpecificRef5,
@Consumption.filter.selectionType: #INTERVAL
_JournalEntry.JrnlEntryCntrySpecificDate5,
_JournalEntry.JrnlEntryCntrySpecificBP1,
_JournalEntry.JrnlEntryCntrySpecificBP2,
@UI.fieldGroup: [ { qualifier: 'WFFldGrp', position: 10} ]
@EndUserText.label: 'Workflow Status'
@Consumption.filter.hidden: true
_DocumentWorkflowStatus.StatusName,
@EndUserText.label: 'Workflow Status'
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_MngJrnlEntrDocWorkflowStatus', element: 'AcctgDocumentWorkflowStatus' }}]
_JournalEntry.AcctgDocumentWorkflowStatus,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_HEADER_FIELDS_CALC'
virtual CAReconciliationKey : fikey_kk,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_HEADER_FIELDS_CALC'
virtual FinSGLErrorDocument : gle_dte_ecs_int_doc_ref_id,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_HEADER_FIELDS_CALC'
virtual FinSGLErrorFiscalYear : gle_dte_ecs_int_doc_ref_year,
//
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_CurrencyTranslation : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_GLView : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_TechnicalLedgerView : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_EntryView : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_RelatedJE : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_RelatedDocument : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_CrossCC : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_TaxFulfillmentDate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_TaxReportingDate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_WhgdTaxReportingDate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_InvoiceReceiptDate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_AccountingPrinciple : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_LedgerGroup : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_ExchangeRate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_ExchangeRateDate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_TaxExchangeRate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_TaxesFieldGroup : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_ReversalReference : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_ReversedReference : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_Parked : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_TaxItem : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_ParkedTaxItem : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_ParkedEntryView : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_IsParkedDocument : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
virtual UICT_IsAmountHidden : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
virtual UICT_TaxItemOP : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_OBJKEY'
@UI.hidden: true
virtual UICT_AttachmentObjectKey : abap.char(18),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_LastManualChangeDate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_IntercompanyTransaction : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_AccountingDocumentCat : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_AbsoluteExchangeRate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_Branch : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_PlannedReversalDate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_DocumentReferenceID : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_Reference1InDocumentHdr : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_Reference2InDocumentHdr : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_AcctgDocumentHeaderText : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_OriglReferenceDocument : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_NmbrOfPages : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_CtryCrcyTaxExchangeRate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_MarketDataExchangeRate : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_TaxCountry : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_EditIsHidden : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_ReversalReason : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_AuditMask : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_ReversalReferenceDocument : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_DETPAGE_VISIBILITY_CALC'
@UI.hidden: true
@Semantics.booleanIndicator
virtual UICT_ReversedReferenceDocument : abap.char(1),
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_GLO_FIELDS'
@UI.hidden: true
virtual UICT_GloMetadata : fco_drct_acty_value,
@UI.hidden: true
@Semantics.booleanIndicator: true
WrkflwScenIsActv,
@UI.hidden: true
_JournalEntry.JournalEntryLastChangeDateTime,
@UI.hidden: true
@Semantics.booleanIndicator
_JournalEntry.AccountingDocumentIsReversible,
_CrcyTranslation,
_ItemGLView,
_JournalEntryLedger,
_RelatedJournalEntry,
@ObjectModel.filter.enabled: false
_RelatedDocument,
_ItemTechnicalLedgerView,
_TaxItem,
_ParkedTaxItem,
_ParkedItem,
@ObjectModel.filter.enabled: false
_Note,
@Consumption.filter.hidden: true
_AmountFilter,
@Consumption.filter.hidden: true
_CreatedByContactCard,
@Consumption.filter.hidden: true
_ParkedByUserContactCard,
_ItemEntryView : redirected to composition child C_ManageJournalEntryItemTP,
//DCL
@Consumption.hidden: true
_AccountingDocumentType
}