C_ManageJournalEntryTaxItem

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Journal Entry Tax Item'
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MIXED
}

@UI.headerInfo: {
  typeName: 'Tax',
  typeNamePlural: 'Taxes'
}

@UI.presentationVariant: [{
    sortOrder: [{
      by: 'AccountingDocument',
      direction: #ASC
    }]
}]

@VDM.viewType: #CONSUMPTION

define view entity C_ManageJournalEntryTaxItem
  as select from R_ManageJournalEntryTaxItem
  association [0..1] to I_CompanyCode                as _CompanyCode   on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_GlAccountTextInCompanycode as _GlAccountText on  $projection.CompanyCode = _GlAccountText.CompanyCode
                                                                       and $projection.GLAccount   = _GlAccountText.GLAccount
                                                                       and _GlAccountText.Language = $session.system_language
  association [0..1] to I_TaxCodeText                as _TaxCodeText   on  $projection.TaxCode                 = _TaxCodeText.TaxCode
                                                                       and $projection.TaxCalculationProcedure = _TaxCodeText.TaxCalculationProcedure
                                                                       and _TaxCodeText.Language               = $session.system_language

{
      @ObjectModel.text.element:  [ 'CompanyCodeName' ]
      @UI.textArrangement: #TEXT_LAST
  key CompanyCode,
      @Consumption.semanticObject: 'AccountingDocument'
  key AccountingDocument,
  key FiscalYear,
  key TaxItem,
      @UI: {
        lineItem: [{ position: 10 }]
      }
      @ObjectModel.text.element:  [ 'TaxCodeName' ]
      @UI.textArrangement: #TEXT_LAST
      TaxCode,
      @UI: {
        lineItem: [{ position: 20 }]
      }
      @ObjectModel.text.element:  [ 'GLAccountName' ]
      @UI.textArrangement: #TEXT_LAST
      GLAccount,
      TaxItemGroup,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @EndUserText.label: 'Tax Base Amount in Company Code Currency'
      TaxBaseAmountInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @EndUserText.label: 'Tax Base Amount in Transaction Currency'
      TaxBaseAmountInTransCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @EndUserText.label: 'Tax Amount in Company Code Currency'
      @UI.hidden: true
      TaxAmountInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @EndUserText.label: 'Tax Amount in Transaction Currency'
      @UI.hidden: true
      TaxAmount,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      @EndUserText.label: 'Credit Tax Amount in Company Code Currency'
      CreditAmountInCoCodeCrcy,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      @EndUserText.label: 'Debit Tax Amount in Company Code Currency'
      DebitAmountInCoCodeCrcy,

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      @EndUserText.label: 'Credit Tax Amount in Transaction Currency'
      CreditAmountInTransCrcy,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      @EndUserText.label: 'Debit Tax Amount in Transaction Currency'
      DebitAmountInTransCrcy,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      @EndUserText.label: 'Credit Tax Amount in Additional Currency 1' 
      CreditAmountInAddlCrcy1,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      @EndUserText.label: 'Debit Tax Amount in Additional Currency 1'  
      DebitAmountInAddlCrcy1,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      @EndUserText.label: 'Credit Tax Amount in Additional Currency 2'
      CreditAmountInAddlCrcy2,
      @EndUserText.label: 'Debit Tax Amount in Additional Currency 2' 
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      DebitAmountInAddlCrcy2,
            
      TransactionTypeDetermination,
      ConditionRecord,
      DestinationCountry,
      SupplyingCountry,
      TaxJurisdiction,
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      @EndUserText.label: 'Tax Amount in Additional Currency 1'
      @UI.hidden: true
      TaxAmountInAdditionalCurrency1,
      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      @EndUserText.label: 'Tax Amount in Additional Currency 2'
      @UI.hidden: true
      TaxAmountInAdditionalCurrency2,
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      @EndUserText.label: 'Tax Base Amount in Additional Currency 1'
      TaxBaseAmtInAdditionalCrcy1,
      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      @EndUserText.label: 'Tax Base Amount in Additional Currency 2'
      TaxBaseAmtInAdditionalCrcy2,
      ConditionType,
      TaxReturnDate,
      TaxReportingDate,
      @UI: {
        lineItem: [{ position: 60 }]
      }
      @ObjectModel.text.element:  [ 'TaxRegisterPercentageUnit' ]
      @UI.textArrangement: #TEXT_LAST
      @EndUserText.label: 'Tax Rate'  
      TaxRate,
      @UI.hidden: true
      cast( '%' as txrgpercentageunit ) as TaxRegisterPercentageUnit,
      TaxReturnCountry,
      @Semantics.amount.currencyCode: 'CountryCurrency'
      @EndUserText.label: 'Tax Amount in Reporting Currency' 
      @UI.hidden: true     
      TaxAmountInCountryCrcy,    
      @Semantics.amount.currencyCode: 'CountryCurrency'
      @EndUserText.label: 'Tax Base Amount in Reporting Currency'        
      TaxBaseAmountInCountryCrcy,
      @Semantics: { amount : {currencyCode: 'CountryCurrency'} }
      @EndUserText.label: 'Credit Tax Amount in Reporting Currency'
      CreditAmountInReportingCrcy,  
      @Semantics: { amount : {currencyCode: 'CountryCurrency'} }
      @EndUserText.label: 'Debit Tax Amount in Reporting Currency'
      DebitAmountInReportingCurrency,        
      TaxDeterminationDate,
      BusinessPlace,
      LowestLevelTaxJurisdiction,
      TaxJurisdictionLevel,
      TaxItemAcctgDocItemRef,
      TaxResultManualModification,
      @EndUserText.label: 'Debit/Credit Indicator'
      DebitCreditCode,
      TaxRateValidityStartDate,
      TaxCountry,
      CompanyCodeCurrency,
      TransactionCurrency,
      AdditionalCurrency1,
      AdditionalCurrency2,
      CountryCurrency,
      TaxCalculationProcedure,
      @Semantics.text: true
      @UI.hidden: true
      _CompanyCode.CompanyCodeName,
      @Semantics.text: true
      @UI.hidden: true
      _GlAccountText.GLAccountName,
      @Semantics.text: true
      @UI.hidden: true
      _TaxCodeText.TaxCodeName
}