C_ChmlCmplncMatlAssgmtTP

@EndUserText.label: 'Chemical Compliance Material Assignment'

@AbapCatalog:
{
  sqlViewName: 'CCCMATLASSGMTTP',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  // blocking of personal data not required (no personal data fields exposed for material (MARA))

  personalData.blocking: #NOT_REQUIRED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  transactionalProcessingDelegated: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  semanticKey:  [ 'MaterialName' ],
  usageType:
  {
    /*Service Quality - reflects the quality of service with respect to the expected performance of the CDS view:
      #A: may be consumed within business logic for high volume transactions or background processing
      #B: may be consumed within business logic for transactions or background processing
    */
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
  }
}

@Metadata.allowExtensions: true

@Search.searchable: true

define view C_ChmlCmplncMatlAssgmtTP
  as select from I_ChmlCmplncMatlAssgmtTP

  association [1..1] to C_ChmlCmplncInfoTP as _ChmlCmplncInfo on _ChmlCmplncInfo.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID

{

      
  key ChmlCmplncMatlAssgmtUUID,

      
      ChmlCmplncInfoUUID,

      
      @ObjectModel:
      {
        mandatory: true
      }
      
      Material,

      
      @ObjectModel.readOnly: true
      cast(_Product._Text[ 1: Language = $session.system_language ].ProductName as ehfnd_cci_material_name )                                                    as MaterialName,

      
      @ObjectModel:
        {
          readOnly: true,
          text.element:  [ 'MaterialGroupName' ]
        }
      cast(_Product.ProductGroup as ehfnd_cci_material_group preserving type)                                                                                   as MaterialGroup,

      
      @ObjectModel.readOnly: true
      _Product._ProductGroup._Text[1: Language = $session.system_language ].MaterialGroupName,

      
      @ObjectModel:
      {
          readOnly: true
      }
      cast(_Product._ProductStatusText[1: Language = $session.system_language ].MaterialUsabilityProfileName as ehfnd_cci_crossplantstatus_txt preserving type) as CrossPlantStatusName,

      
      MatlAssgmtIsPrimary,

      @ObjectModel.readOnly: true
      cast(_Product.ExternalProductGroup as ehfnd_ext_material_group preserving type)                                                                           as ExternalProductGroup,
      @ObjectModel.readOnly: true
      _Product.Division                                                                                                                                         as Division,

      /* Associations */
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _ChmlCmplncInfo
}