C_CABillgDocInvcgDocSource

@AbapCatalog.sqlViewName: 'CCAINVBILINVDOCS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:  #NOT_REQUIRED
@EndUserText.label: 'Fakturierungsbeleg Quellen'
@UI:{
  headerInfo: {
    typeName:       'Fakturierungshistorie',
    typeNamePlural: 'Fakturierungshistorie'
  },
  presentationVariant: [{
    sortOrder: [ { by: 'CAInvcgCreationDate', direction: #DESC },
                 { by: 'CAInvcgCreationTime', direction: #DESC } ],
    requestAtLeast: ['CAInvcgSourceDocumentSemObj']
  }]
}
@ObjectModel.query.implementedBy: 'ABAP:CL_CINV_RAP_QRY_BILLDOC_DSP'
define view C_CABillgDocInvcgDocSource
  as select from I_CAInvcgDocSource as _CAInvDocSource
  association [0..1] to C_CAInvcgDocHeader as _CAInvcgDocHeader on $projection.CAInvoicingDocument = _CAInvcgDocHeader.CAInvoicingDocument

{
      //INVDOCNO

      @UI.lineItem:       { position: 30 }
      @Consumption.semanticObject: 'CAInvoicingDocument'
  key _CAInvDocSource.CAInvoicingDocument,

      //SRCDOCNO

      @UI.lineItem:       { position: 20 }
  key _CAInvDocSource.CAInvcgSourceDocumentNumber,

      //SRCDOCCAT

      @UI.lineItem:       { position: 10 }
      @ObjectModel.text.element: 'CAInvcgSourceDocCatText'
  key _CAInvDocSource.CAInvcgSourceDocumentCat,

      @UI.hidden: true
      _CAInvcgSourceDocCat.CAInvcgSourceDocumentSemObj,

      //SRCDOCTYPE

      @ObjectModel.text.element: 'CAInvcgSourceDocTypeText'
      _CAInvDocSource.CAInvcgSourceDocumentType,

      //SIMULATED

      @UI.lineItem:       { position: 70 }
      _CAInvDocSource.CAInvcgIsDocumentSimulated,

      //PRELIMINARY

      @UI.lineItem:       { position: 80 }
      _CAInvDocSource.CAInvcgIsDocumentPreliminary,

      //LOGSYSTEM

      _CAInvDocSource.LogicalSystem,

      //APPLK

      _CAInvDocSource.CAApplicationArea,

      //INVOICED

      @UI.lineItem:       { position: 60 }
      _CAInvDocSource.CAInvcgIsDocumentPosted,

      //REVERSALDOC

      @Consumption.semanticObject: 'CAInvoicingDocument'
      _CAInvDocSource.CAInvcgReversalDocument,

      //REVERSEDDOC

      @Consumption.semanticObject: 'CAInvoicingDocument'
      _CAInvDocSource.CAInvcgReversedDocument,

      //CRDATE

      @UI.hidden: true
      case when _CAInvcgDocHeader.CAInvcgCreationDate is not initial
        then _CAInvcgDocHeader.CAInvcgCreationDate
        else _CAInvDocSource.CAInvcgCreationDate
      end                                                             as CAInvcgCreationDate,

      //CRTIME

      @UI.hidden: true
      case when _CAInvcgDocHeader.CAInvcgCreationTime is not initial
        then _CAInvcgDocHeader.CAInvcgCreationTime
        else _CAInvDocSource.CAInvcgCreationTime
      end                                                             as CAInvcgCreationTime,

      @UI.lineItem:       { position: 40 }
      case when _CAInvcgDocHeader.CAInvcgCreationDate is not initial
      then // datetime by invdoc_h

          cast( dats_tims_to_tstmp( _CAInvcgDocHeader.CAInvcgCreationDate,
                                    _CAInvcgDocHeader.CAInvcgCreationTime,
                                    abap_system_timezone($session.client, 'NULL'),
                                    $session.client,
                                    'NULL' ) as invdoc_crtsmp_kk)

      else // datetime by invdoc_s

          cast( dats_tims_to_tstmp( _CAInvDocSource.CAInvcgCreationDate,
                                    _CAInvDocSource.CAInvcgCreationTime,
                                    abap_system_timezone($session.client, 'NULL'),
                                    $session.client,
                                    'NULL' ) as invdoc_crtsmp_kk) end as CAInvcgCreationDateTime,

      @UI.hidden: true
      cast( '' as billdocno_kk )                                      as CABillgDocument,


      @UI.hidden: true
      _CAInvcgSourceDocCat._CAInvcgSourceDocCatText[1: Language=$session.system_language].CAInvcgSourceDocCatText,
      @UI.hidden: true
      _CAInvcgSourceDocType._CAInvcgSourceDocTypeText[1: Language=$session.system_language].CAInvcgSourceDocTypeText,

      // Make association public

      @ObjectModel.sort.enabled: false
      @ObjectModel.filter.enabled: false
      _CAInvcgDocHeader,      
      @ObjectModel.sort.enabled: false
      @ObjectModel.filter.enabled: false
      _CAInvcgSourceDocCat,      
      @ObjectModel.sort.enabled: false
      @ObjectModel.filter.enabled: false
      _CAInvcgSourceDocType
}