C_CAInvcgDocHeader

@AbapCatalog.sqlViewName: 'CCAINVDOC_H'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel:{
  usageType: {
    serviceQuality: #D,
    sizeCategory: #XL,
    dataClass: #TRANSACTIONAL
  }
}
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: [ '_CAInvcgUserContact' ]

@EndUserText.label: 'Fakturierungsbeleg Kopf'
define view C_CAInvcgDocHeader
  as select from I_CAInvcgDocHeader as _CAInvcgDocHeader

  // ADDITIONAL DATA

  association [0..1] to C_CAInvcgUserContact as _CAInvcgUserContact on  $projection.CreatedByUser = _CAInvcgUserContact.ContactCardID

  // fkeys (not part of basic view due to complexity)

  association [0..1] to I_CAPaymentMethod    as _CAPaymentMethod    on  $projection.CAPaymentCompanyCodeCountry = _CAPaymentMethod.Country
                                                                    and $projection.CAPaymentMethod             = _CAPaymentMethod.CAPaymentMethod
  // extension

  //  association [0..1] to E_CAInvcgDocHeader   as _Extension          on $projection.CAInvoicingDocument = _Extension.CAInvoicingDocument

{
      //INVDOCNO

  key _CAInvcgDocHeader.CAInvoicingDocument,

      //EXBEL

      _CAInvcgDocHeader.CAOfficialDocumentNumber,

      //GPART

      _BusinessPartner.FirstName,

      _BusinessPartner.LastName,

      @UI.hidden: true
      @Semantics: { name.givenName: true , contact.type: #PERSON }
      _BusinessPartner.BusinessPartnerFullName,

      cast( concat_with_space(_BusinessPartner._CurrentDefaultAddress._StandardAddress.StreetName,
                              _BusinessPartner._CurrentDefaultAddress._StandardAddress.HouseNumber, 1)
            as adress_gfn_kk preserving type )                    as StreetName,

      cast( concat_with_space(_BusinessPartner._CurrentDefaultAddress._StandardAddress.PostalCode,
                              _BusinessPartner._CurrentDefaultAddress._StandardAddress.CityName, 1)
            as city_gfn_kk preserving type )                      as AddressCityName,

      cast( _BusinessPartner._CurrentDefaultAddress._StandardAddress._Country._Text[1: Language=$session.system_language].CountryName
            as country_gfn_kk preserving type )                   as CountryName,


      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner' }}]
      @Consumption.semanticObject: 'CAContractPartner'
      _CAInvcgDocHeader.BusinessPartner,

      //VKONT

      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_ContractAccountValueHelp', element: 'ContractAccount' }}]
      @Consumption.semanticObject: 'ContractAccount'
      _CAInvcgDocHeader.ContractAccount,


      _ContractAccountHeader.ContractAccountName,

      //INV_TYPE

      _CAInvcgDocHeader.CAInvcgType,

      //INVPERIOD

      _CAInvcgDocHeader.CAInvcgDocPeriodDate,

      //BLDAT

      @Consumption.filter.selectionType: #INTERVAL
      _CAInvcgDocHeader.DocumentDate,

      //Amount and Currency

      _CAInvcgDocHeader.TransactionCurrency,

      _CAInvcgDocHeader.CAAmountInTransactionCurrency,

      //INV_PROCESS

      _CAInvcgDocHeader.CAInvcgProcess,

      //DOCTYPE

      _CAInvcgDocHeader.CAInvcgDocumentType,

      //MAZAE

      _CAInvcgDocHeader.CADunningCounter,

      //CFCSIMULATED

      _CAInvcgDocHeader.CAInvcgDocHasControlDoc,

      //FORM_ID

      _CAInvcgDocHeader.CAInvcgDocFormID,

      //FORMKEY

      _CAInvcgDocHeader.ApplicationForm,

      //PRINTDATE

      _CAInvcgDocHeader.CAInvcgDocumentPrintDate,

      //PRINTLOCK

      _CAInvcgDocHeader.CAInvcgDocIsLockedForPrinting,

      //FAEDN - Due date for net payment

      _CAInvcgDocHeader.CANetDueDate,

      //REVREASON - Reversal Reason

      _CAInvcgDocHeader.CAInvcgDocumentReversalReason,

      //INVOICED

      _CAInvcgDocHeader.CAInvcgIsDocumentPosted,

      //PRELIMINARY

      _CAInvcgDocHeader.CAInvcgIsDocumentPreliminary,

      //SIMULATED

      _CAInvcgDocHeader.CAInvcgIsDocumentSimulated,

      //BUDAT

      _CAInvcgDocHeader.CAPostingDate,

      //APPLK

      _CAInvcgDocHeader.CAApplicationArea,

      //TECHDOCTYPE

      _CAInvcgDocHeader.CAInvcgTechnicalDocumentType,

      //TARGPROCESS

      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgTargetProcVH', element: 'CAInvcgTargetProcess' }}]
      _CAInvcgDocHeader.CAInvcgTargetProcess,

      //MDCAT

      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAInvcgMasterDataTypeVH', element: 'CAInvcgMasterDataType' }}]
      _CAInvcgDocHeader.CAInvcgMasterDataType,

      //ABWVK

      @Consumption.semanticObject: 'ContractAccount'
      _CAInvcgDocHeader.AltvContractAcctForCollvBills,

      //ABWBL

      _CAInvcgDocHeader.CASubstituteDocumentNumber,

      //CRNAME

      @UI.hidden: true
      _CAInvcgDocHeader.CreatedByUser,

      //CRDATE

      @Consumption.filter.selectionType: #INTERVAL
      _CAInvcgDocHeader.CAInvcgCreationDate,

      //CRTIME

      _CAInvcgDocHeader.CAInvcgCreationTime,

      //CRMODE

      _CAInvcgDocHeader.CAInvcgDocCreationMode,

      //RECNUM

      _CAInvcgDocHeader.CAInvcgNmbrOfInvoicingDocItems,

      //BIT_NUMBER

      _CAInvcgDocHeader.CABllbleItmNumber,

      //INVRUNNO

      _CAInvcgDocHeader.CAInvcgDocInternalNumber,

      //FIKEY

      @Consumption.semanticObject: 'CAReconciliationKey'
      _CAInvcgDocHeader.CAReconciliationKey,

      //FAEDS

      _CAInvcgDocHeader.CACashDiscountDueDate,

      //SKTPZ

      _CAInvcgDocHeader.CACashDiscountRate,

      //PRLINV_CAT

      _CAInvcgDocHeader.CAInvcgPreliminaryCategory,

      //PRLINV_CNT

      _CAInvcgDocHeader.CAPrelimInvcgDocValue,

      //PRLINV_STATUS

      _CAInvcgDocHeader.CAPreliminaryInvcgDocStatus,

      //INV_CATEGORY

      _CAInvcgDocHeader.CAInvcgCategory,

      //REVERSALDOC

      //      @Consumption.semanticObject: 'CAInvoicingDocument'

      _CAInvcgDocHeader.CAInvcgReversalDocument,

      //REVERSEDDOC

      //      @Consumption.semanticObject: 'CAInvoicingDocument'

      _CAInvcgDocHeader.CAInvcgReversedDocument,

      //CORRCAT

      _CAInvcgDocHeader.CAInvcgCorrectionCategory,

      //PYMET

      @ObjectModel.foreignKey.association: '_CAPaymentMethod'
      _CAInvcgDocHeader.CAPaymentMethod,

      //NRZAS

      @Consumption.semanticObject: 'CAPaymentForm'
      _CAInvcgDocHeader.CAPaymentFormNumber,

      //ZLSCH

      _CAInvcgDocHeader.FormIDForAttachedPaymentMedium,

      //EXKID

      _CAInvcgDocHeader.CAKeyIdentification,

      //PTSRL

      _CAInvcgDocHeader.CAPartnerSettlementRule,

      //BUKRS

      _CAInvcgDocHeader.CompanyCode,

      //BUPLA

      _CAInvcgDocHeader.BusinessPlace,

      //VTREF

      _CAInvcgDocHeader.CAContract,

      @UI.hidden: true
      @ObjectModel: {
        readOnly: true,
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_CINV_VTREF_SEMOBJ'
      }
      cast ( '' as vtref_semobj_kk )                              as CAContractSemanticObject,

      //SUBAP

      _CAInvcgDocHeader.CASubApplication,

      //INVOICE_BASEDATE

      _CAInvcgDocHeader.CAInvcgBaseDate,

      //INVPERCAT

      _CAInvcgDocHeader.CAInvcgDocPeriodCategory,

      //INVPERIOD

      _CAInvcgDocHeader.CAInvcgDocPeriodStartDate,

      //CHGDOC_EX

      _CAInvcgDocHeader.CAInvcgDocHasChargeOrDiscItems,

      //BOLLOTAX

      _CAInvcgDocHeader.CAInvcgBolloTaxPostStatus,

      //XSUBINV

      _CAInvcgDocHeader.CAInvcgDocIsPartOfList,

      //XINVDOC_X

      _CAInvcgDocHeader.CAInvcgDocHasObjectRelation,

      //SEPA_PRENOT

      _CAInvcgDocHeader.CAInvcgDocHasSEPAPreNotif,

      //EXT_INVDOCNO

      _CAInvcgDocHeader.CAInvcgDocExternal,

      //ADJUSTMENTDOC

      _CAInvcgDocHeader.CAInvcgAdjustmentDocument,

      //ADJUSTEDDOC

      _CAInvcgDocHeader.CAInvcgAdjustedDocument,

      _ContractAccountPartner._CompCodeGroup._CompanyCode.Country as CAPaymentCompanyCodeCountry,

      _CAInvcgDocumentType._CAInvcgDocumentTypeText[1: Language=$session.system_language].CAInvcgDocumentTypeText,
      _CAInvcgProcess._CAInvcgProcessText[1: Language=$session.system_language].CAInvcgProcessText,
      _CAInvcgType._CAInvcgTypeText[1: Language=$session.system_language].CAInvcgTypeText,
      _CAInvcgCategory._CAInvcgCategoryText[1: Language=$session.system_language].CAInvcgCategoryText,
      _CAInvcgDocTechDocType._CAInvcgDocTechDocTypeText[1: Language=$session.system_language].CAInvcgDocTechDocTypeText,
      _CAInvcgTargetProc._CAInvcgTargetProcText[1: Language=$session.system_language].CAInvcgTargetProcText,
      _CAInvcgMasterDataType._CAInvcgMasterDataTypeText[1: Language=$session.system_language].CAInvcgMasterDataTypeText,
      _CAInvcgDocCreationMode._CAInvcgDocCreationModeText[1: Language=$session.system_language].CAInvcgDocCreationModeText,
      _CAInvcgPreliminaryCategory._Text[1: Language=$session.system_language].CAInvcgPreliminaryCategoryTxt,
      _CAPreliminaryInvcgDocStatus._Text[1: Language=$session.system_language].CAPreliminaryInvcgDocStatusTxt,
      _CAInvcgDocReversalReason._CAInvcgDocReversalReasonText[1: Language=$session.system_language].CAInvcgDocReversalReasonText,
      _CAInvcgCorrectionCat._CAInvcgCorrectionCatText[1: Language=$session.system_language].CAInvcgCorrectionCatText,
      _CAInvcgDocLockedforPrint._CAInvcgDocLockedForPrintText[1: Language=$session.system_language].CAInvcgDocLockedForPrintText,
      _CAInvcgPeriodCat._CAInvcgPeriodCatText[1: Language=$session.system_language].CAInvcgPeriodCatText,
      _CAInvcgDocChrgDiscItems._CAInvcgDocChrgDiscItemsText[1: Language=$session.system_language].CAInvcgDocChrgDiscItemsText,
      _CAInvcgBolloTaxPostStatus._CAInvcgBolloTaxPostStatText[1: Language=$session.system_language].CAInvcgBolloTaxPostStatText,
      _CAInvcgDocPartOfList._CAInvcgDocPartOfListText[1: Language=$session.system_language].CAInvcgDocPartOfListText,
      _CompanyCode.CompanyCodeName,

      // Make association public

      _ContractAccountPartner,
      _BusinessPartner,
      _ContractAccountHeader,
      _AltvContractAcctForCollvBills,
      _TransactionCurrency,
      _CAInvcgPreliminaryCategory,
      _CAPreliminaryInvcgDocStatus,
      _CAInvcgProcess,
      _CAInvcgType,
      _CAInvcgCategory,
      _CAInvcgDocTechDocType,
      _CAInvcgTargetProc,
      _CAInvcgMasterDataType,
      _CAInvcgDocCreationMode,
      _CAInvcgDocReversalReason,
      _CAInvcgReversalDocument,
      _CAInvcgReversedDocument,
      _CAInvcgCorrectionCat,
      _CAInvcgDocumentType,
      _CAInvcgDocLockedforPrint,
      _CAInvcgPeriodCat,
      _CAInvcgDocChrgDiscItems,
      _CAInvcgBolloTaxPostStatus,
      _CAInvcgDocPartOfList,
      _CAPaymentMethod,
      _CompanyCode,
      _ProviderContract,
      _CAReconciliationKey,

      _CAInvcgUserContact


}