I_CAINVCGDOCSOURCE

CDS View

Fakturierungsbelegquellen

I_CAINVCGDOCSOURCE is a CDS View in S/4HANA. Fakturierungsbelegquellen. It contains 12 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 12 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_CABillgDocInvcgDocSource view from CONSUMPTION Fakturierungsbeleg Quellen
C_CAInvcgDocSource view from CONSUMPTION Fakturierungsbeleg Quellen
R_CAInvcgDocSourceTP view_entity from TRANSACTIONAL Invoicing Document Source Item - TP

Fields (12)

KeyField CDS FieldsUsed in Views
KEY CAInvcgSourceDocumentCat CAInvcgSourceDocumentCat 2
KEY CAInvcgSourceDocumentNumber CAInvcgSourceDocumentNumber 2
KEY CAInvoicingDocument CAInvoicingDocument 2
CAApplicationArea CAApplicationArea 2
CAInvcgCreationDate CAInvcgCreationDate 1
CAInvcgIsDocumentPosted CAInvcgIsDocumentPosted 2
CAInvcgIsDocumentPreliminary CAInvcgIsDocumentPreliminary 2
CAInvcgIsDocumentSimulated CAInvcgIsDocumentSimulated 2
CAInvcgReversalDocument CAInvcgReversalDocument 2
CAInvcgReversedDocument CAInvcgReversedDocument 2
CAInvcgSourceDocumentType CAInvcgSourceDocumentType 2
LogicalSystem LogicalSystem 2 
@AbapCatalog.sqlViewName: 'ICAINVDOC_S'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Fakturierungsbelegquellen'
@VDM.viewType: #BASIC
@ObjectModel: {
  usageType: {
    serviceQuality: #A,
    sizeCategory: #XL,
    dataClass: #TRANSACTIONAL
  },
  modelingPattern: #NONE,
  supportedCapabilities: [
    #SQL_DATA_SOURCE,
    #CDS_MODELING_DATA_SOURCE,
    #CDS_MODELING_ASSOCIATION_TARGET
  ]
}
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_CAInvcgDocSource
  as select from dfkkinvdoc_s
  association [1..1] to I_CAInvcgDocHeader     as _CAInvcgDocHeader        on  $projection.CAInvoicingDocument = _CAInvcgDocHeader.CAInvoicingDocument
  association [0..1] to I_CAInvcgSourceDocCat  as _CAInvcgSourceDocCat     on  $projection.CAInvcgSourceDocumentCat = _CAInvcgSourceDocCat.CAInvcgSourceDocumentCat
  association [0..1] to I_CAInvcgSourceDocType as _CAInvcgSourceDocType    on  $projection.CAInvcgSourceDocumentType = _CAInvcgSourceDocType.CAInvcgSourceDocumentType
                                                                           and $projection.CAInvcgSourceDocumentCat  = _CAInvcgSourceDocType.CAInvcgSourceDocumentCat

  association [0..1] to I_CAApplicationArea    as _CAApplicationArea       on  $projection.CAApplicationArea = _CAApplicationArea.CAApplicationArea
  association [0..1] to I_CAInvcgDocHeader     as _CAInvcgReversalDocument on  $projection.CAInvcgReversalDocument = _CAInvcgReversalDocument.CAInvoicingDocument
  association [0..1] to I_CAInvcgDocHeader     as _CAInvcgReversedDocument on  $projection.CAInvcgReversedDocument = _CAInvcgReversedDocument.CAInvoicingDocument

{
      @ObjectModel.foreignKey.association: '_CAInvcgSourceDocCat'
  key cast(srcdoccat as srcdoccat_gfn_kk preserving type)         as CAInvcgSourceDocumentCat,
  key cast(srcdocno  as srcdocno_gfn_kk preserving type)          as CAInvcgSourceDocumentNumber,
      @ObjectModel.foreignKey.association: '_CAInvcgDocHeader'
  key invdocno                                                    as CAInvoicingDocument,
      @ObjectModel.foreignKey.association: '_CAInvcgSourceDocType'
      srcdoctype                                                  as CAInvcgSourceDocumentType,
      log_system                                                  as LogicalSystem,
      @ObjectModel.foreignKey.association: '_CAApplicationArea'
      applk                                                       as CAApplicationArea,
      invoiced                                                    as CAInvcgIsDocumentPosted,
      simulated                                                   as CAInvcgIsDocumentSimulated,
      cast(preliminary as inv_preliminary_gfn_kk preserving type) as CAInvcgIsDocumentPreliminary,
      @ObjectModel.foreignKey.association: '_CAInvcgReversalDocument'
      reversaldoc                                                 as CAInvcgReversalDocument,
      @ObjectModel.foreignKey.association: '_CAInvcgReversedDocument'
      cast(reverseddoc as inv_reverseddoc_gfn_kk preserving type) as CAInvcgReversedDocument,
      @Semantics.systemDate.createdAt: true
      crdate                                                      as CAInvcgCreationDate,
      @Semantics.systemTime.createdAt: true
      crtime                                                      as CAInvcgCreationTime,

      _CAInvcgSourceDocCat,
      _CAInvcgSourceDocType,
      _CAApplicationArea,
      _CAInvcgReversalDocument,
      _CAInvcgReversedDocument,
      _CAInvcgDocHeader
}

Learn More