@AbapCatalog.sqlViewName: 'CBUSINESSPARTNER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Business Partner'
@Metadata.allowExtensions: true
@ObjectModel.compositionRoot: true
@ObjectModel: {
semanticKey: ['BusinessPartner'],
createEnabled,
updateEnabled,
deleteEnabled
}
@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.draftEnabled: true
@ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN //texts will be shown together with the Code values. if the Code values are hidden, then texts wont be visible in UI. no independent visibility for text fields
@Search.searchable: true
@UI.headerInfo:{
typeName: 'Business Partner',
typeNamePlural: 'Business Partners',
imageUrl: 'BusinessPartnerImageURL',
title: { value: 'BusinessPartnerName'},
description: { value: 'BusinessPartnerForEdit' }
}
@VDM.viewType: #CONSUMPTION
define view C_BusinessPartner
as select from I_BusinessPartnerTP as BusinessPartner
association [0..*] to C_Businesspartnersupplierco as _BusinessPartnerSupplierCo on $projection.BusinessPartner = _BusinessPartnerSupplierCo.BusinessPartner
association [0..1] to C_BusinessPartnerSuplr as _BusinessPartnerSupplier on $projection.BusinessPartner = _BusinessPartnerSupplier.BusinessPartner
association [0..*] to C_BusinessPartnerPurgOrg as _BusinessPartnerPurgOrg on $projection.BusinessPartner = _BusinessPartnerPurgOrg.BusinessPartner
association [0..*] to C_BusinessPartnerSupplierRole as _BusinessPartnerSuplrRole on $projection.BusinessPartner = _BusinessPartnerSuplrRole.BusinessPartner
association [0..*] to C_BusinessPartnerRole as _BusinessPartnerRole on $projection.BusinessPartner = _BusinessPartnerRole.BusinessPartner
association [1..1] to C_BusinessPartnerCust as _BusinessPartnerCustomer on $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner
association [1..*] to C_BusinessPartnerAddress as _BusinessPartnerAddress on $projection.BusinessPartner = _BusinessPartnerAddress.BusinessPartner
association [1..*] to C_BusinessPartnerBank as _BusinessPartnerBank on $projection.BusinessPartner = _BusinessPartnerBank.BusinessPartner
association [1..*] to C_Businesspartnertaxnumber as _BusinessPartnerTaxNumber on $projection.BusinessPartner = _BusinessPartnerTaxNumber.BusinessPartner
association [1..*] to C_BusinessPartnerContact as _BusinessPartnerContact on $projection.BusinessPartner = _BusinessPartnerContact.BusinessPartner
association [1..*] to C_BusinessPartnerCustCo as _BusinessPartnerCustomerCo on $projection.BusinessPartner = _BusinessPartnerCustomerCo.BusinessPartner
association [1..*] to C_BusinessPartnerSalesArea as _BusinessPartnerSalesArea on $projection.BusinessPartner = _BusinessPartnerSalesArea.BusinessPartner
association [1..*] to C_BusinessPartnerCustomerRole as _BusinessPartnerCustRole on $projection.BusinessPartner = _BusinessPartnerCustRole.BusinessPartner
association [1..1] to C_BusinessPartnerAddress as _BusinessPartnerAddrFilter on $projection.BusinessPartner = _BusinessPartnerAddrFilter.BusinessPartner
and _BusinessPartnerAddrFilter.StandardUsage = 'X'
association [1..*] to C_PaymentCard as _PaymentCard on $projection.BusinessPartner = _PaymentCard.BusinessPartner
association [1..*] to C_BuPaIdentification as _BPIdentificationNumbers on $projection.BusinessPartner = _BPIdentificationNumbers.BusinessPartner
association [1..*] to C_BuPaIndustry as _BPIndustry on $projection.BusinessPartner = _BPIndustry.BusinessPartner
association [1..*] to C_BPUnloadingPoint as _BusinessPartnerUnloadingPoint on $projection.BusinessPartner = _BusinessPartnerUnloadingPoint.BusinessPartner
association [1..*] to C_BPSiteReceivingPoint as _BPCustReceivingPoint on $projection.BusinessPartner = _BPCustReceivingPoint.BusinessPartner
association [1..*] to C_BPCustRcvgPtAddrDepdntInfo as _BPCustRcvgPtAddrDepdntInfo on $projection.BusinessPartner = _BPCustRcvgPtAddrDepdntInfo.BusinessPartner
association [1..*] to C_CustomerDepartment as _CustomerDepartment on $projection.BusinessPartner = _CustomerDepartment.BusinessPartner
association [0..*] to C_BPCustDepartmentAddrDepdnt as _BPCustDepartmentAddrDepdnt on $projection.BusinessPartner = _BPCustDepartmentAddrDepdnt.BusinessPartner
association [1..*] to C_BPSupplierTaxGrouping as _BPSupplierTaxGrouping on $projection.BusinessPartner = _BPSupplierTaxGrouping.BusinessPartner
association [1..*] to C_BPCustomerTaxGrouping as _BPCustomerTaxGrouping on $projection.BusinessPartner = _BPCustomerTaxGrouping.BusinessPartner
association [1..*] to C_BusinessPartnerCustomerTxt as _BusinessPartnerCustomerTxt on $projection.BusinessPartner = _BusinessPartnerCustomerTxt.BusinessPartner
association [0..1] to I_BPGenderValueHelp as _GenderValueHelp on $projection.GenderCodeName = _GenderValueHelp.GenderCodeName
association [0..*] to C_BPGroupingTextVhTemp as _BPGroupingText on $projection.BusinessPartnerGrouping = _BPGroupingText.BusinessPartnerGrouping
association [0..*] to C_BPCatHelpTextVhTemp as _BPCatHelpText on $projection.BusinessPartnerCategory = _BPCatHelpText.BusinessPartnerCategory
association [0..*] to C_LegalFormTextVHTemp as _LegalFormText on $projection.LegalForm = _LegalFormText.LegalForm
association [0..*] to I_BPGenderValueHelpText as _BPGenderText on $projection.GenderCodeName = _BPGenderText.GenderCodeName
association [1..*] to I_BusPartAuthorizationGroupTxt as _AuthorizationGroupText on $projection.AuthorizationGroup = _AuthorizationGroupText.AuthorizationGroup
and _AuthorizationGroupText.AuthorizationObject = 'BUPA'
association [1..*] to C_BusinessPartnerSupplierText as _BusinessPartnerSupplierTxt on $projection.BusinessPartner = _BusinessPartnerSupplierTxt.BusinessPartner
association [0..*] to C_BusPartRelationship as _BusPartRelationship on $projection.BusinessPartner = _BusPartRelationship.BusinessPartner1
association [1..*] to C_BPAddressIndependentPhone as _BPAddressIndependentPhone on $projection.BusinessPartner = _BPAddressIndependentPhone.BusinessPartner
and $projection.IndependentAddressID = _BPAddressIndependentPhone.AddressID
association [1..*] to C_BPAddressIndependentMobile as _BPAddressIndependentMobile on $projection.BusinessPartner = _BPAddressIndependentMobile.BusinessPartner
and $projection.IndependentAddressID = _BPAddressIndependentMobile.AddressID
association [1..*] to C_BPAddressIndependentEmail as _BPAddressIndependentEmail on $projection.BusinessPartner = _BPAddressIndependentEmail.BusinessPartner
and $projection.IndependentAddressID = _BPAddressIndependentEmail.AddressID
association [0..1] to I_Globalcompany as _TradingPartnerValueHelp on $projection.TradingPartner = _TradingPartnerValueHelp.Company
association [1..*] to C_BusinessPartnerLongText as _BusinessPartnerLongText on $projection.BusinessPartner = _BusinessPartnerLongText.BusinessPartner
association [1..*] to I_BusinessPartnerCustomerVH as _BusinessPartnerCustomerVH on $projection.BusinessPartner = _BusinessPartnerCustomerVH.BusinessPartner
association [1..*] to I_BusinessPartnerSupplierVH as _BusinessPartnerSupplierVH on $projection.BusinessPartner = _BusinessPartnerSupplierVH.BusinessPartner
association [1..*] to I_BusinessPartnerCustSuplrVH as _BusinessPartnerCustSuplrVH on $projection.BusinessPartner = _BusinessPartnerCustSuplrVH.BusinessPartner
association [0..*] to C_BPCustAddrDepdntInformation as _BPCustAddressDependentInfo on $projection.BusinessPartner = _BPCustAddressDependentInfo.BusinessPartner
association [0..*] to C_BPDataController as _BPDataController on $projection.BusinessPartner = _BPDataController.BusinessPartner
association [1..*] to C_BPAdditionalSupplier as _BPAdditionalSupplier on $projection.BusinessPartner = _BPAdditionalSupplier.BusinessPartner
association [1..*] to C_BPAdditionalCustomer as _BPAdditionalCustomer on $projection.BusinessPartner = _BPAdditionalCustomer.BusinessPartner
association [0..*] to C_BPCustUnldgPtAddrDepdntInfo as _BPCustUnldgPtAddrDepdnt on $projection.BusinessPartner = _BPCustUnldgPtAddrDepdnt.BusinessPartner
association [0..*] to C_BusPartAddrDepdntTaxNmbr as _BusinessPartnerTaxNumberAdr on $projection.BusinessPartner = _BusinessPartnerTaxNumberAdr.BusinessPartner
association [0..*] to C_CustAddrDepdntExtIdentifier as _CustAddrDepdntExtIdentifier on $projection.BusinessPartner = _CustAddrDepdntExtIdentifier.BusinessPartner
association [0..*] to C_BPAddrDepdntIntlLocNumber as _BusinessPartnerAddrDepILN on $projection.BusinessPartner = _BusinessPartnerAddrDepILN.BusinessPartner
association [0..*] to I_BusPartBirthDateStatusText as _BirthDateStatusTxt on $projection.BusinessPartnerBirthDateStatus = _BirthDateStatusTxt.BusinessPartnerBirthDateStatus
association [0..1] to C_BPEmplWorkplaceAddr as _BPEmplWorkplaceAddr on $projection.BusinessPartner = _BPEmplWorkplaceAddr.BusinessPartner
association [0..*] to I_BusinessPartnerTypeText as _BusinessPartnerTypeText on $projection.BusinessPartnerType = _BusinessPartnerTypeText.BusinessPartnerType
{
@ObjectModel.readOnly: true
key BusinessPartner.BusinessPartner,
@ObjectModel.readOnly: true
@Semantics.name.fullName: true
BusinessPartner.FullName, //businesspartnername is used instead
@ObjectModel.text.association: '_BPGroupingText'
BusinessPartner.BusinessPartnerGrouping,
@ObjectModel: {
text.association: '_BusinessPartnerTypeText'
}
BusinessPartner.BusinessPartnerType,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.text.element:'FullName'
BusinessPartner.BusinessPartnerForEdit,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@EndUserText.label: 'Date Founded'
BusinessPartner.OrganizationFoundationDate,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@EndUserText.label: 'Liquidation Date'
BusinessPartner.OrganizationLiquidationDate,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.text.association: '_BPCatHelpText'
BusinessPartner.BusinessPartnerCategory,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.FormOfAddressPerson,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.FormOfAddressOrganization,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.FirstName,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.LastName,
BusinessPartner.Name,
BusinessPartner.AdditionalName,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.OrganizationBPName1,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.OrganizationBPName2,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.OrganizationBPName3,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.OrganizationBPName4,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.text.association: '_LegalFormText'
@EndUserText.label: 'Legal Form'
BusinessPartner.LegalForm,
// @ObjectModel: {
// foreignKey.association: '_IndustryValueHelp'
// }
// @Consumption.valueHelp: '_IndustryValueHelp'
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.Industry,
@ObjectModel.foreignKey.association: '_GenderValueHelp'
@ObjectModel.mandatory: 'undefined'
@ObjectModel.text.association: '_BPGenderText'
BusinessPartner.GenderCodeName,
@ObjectModel.mandatory: 'undefined'
@EndUserText.label: 'Academic Title'
BusinessPartner.AcademicTitle,
// @feature: 'SW:ZNO_LIGHTWEIGHT_SWITCH'
BusinessPartner.BirthDate,
// @ObjectModel.text.association: '_BirthDateStatusTxt'
BusinessPartner.BusinessPartnerBirthDateStatus,
BusinessPartner.BusinessPartnerBirthplaceName,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as Role,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as CityName,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as StreetName,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as CountryName,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as PostalCode,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as IndustrySector,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as HouseNumber,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as Region,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as BPIdentificationNumber,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as BPIdentificationType,
BusinessPartner.BPLastNameSearchHelp,
BusinessPartner.BPFirstNameSearchHelp,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as DataControllerName,
@ObjectModel.virtualElement
@ObjectModel.readOnly: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BPSUPLR_ROLE_CALC_EXIT'
@ObjectModel.filter.transformedBy: 'ABAP:CL_FILTER_BUSINESSPARTNERROLE'
cast( ' ' as abap.sstring( 260 ) ) as BPTaxNumber,
BusinessPartner.BusinessPartnerUUID,
@ObjectModel: {
readOnly: true,
text.element: [ 'CreatedByUserName' ]
}
@Semantics.user.createdBy: true
BusinessPartner.CreatedByUser,
BusinessPartner.CreationTime,
@ObjectModel: {
readOnly: true,
text.element: [ 'LastChangedByUserName' ]
}
BusinessPartner.LastChangedByUser,
@ObjectModel.readOnly: true
BusinessPartner.LastChangeDate,
BusinessPartner.LastChangeTime,
@ObjectModel.readOnly: true
BusinessPartner.CreationDate,
@ObjectModel.readOnly: true
_LastChangedByUser.UserDescription as LastChangedByUserName,
@ObjectModel.readOnly: true
_CreatedByUser.UserDescription as CreatedByUserName,
BusinessPartner.SearchTerm1,
BusinessPartner.SearchTerm2,
BusinessPartner.BusinessPartnerIsBlocked,
BusinessPartner.IsNaturalPerson,
@ObjectModel.text.association: '_AuthorizationGroupText'
BusinessPartner.AuthorizationGroup,
BusinessPartner.IsBusinessPurposeCompleted,
BusinessPartner.BusinessPartnerName, //BP ID + BP name
@ObjectModel.foreignKey.association: '_TradingPartnerValueHelp'
BusinessPartner.TradingPartner,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_MULTI_ADDR_BF_CALC_EXIT'
cast(' ' as abap_boolean preserving type) as BPCustMultiAddrIsActive,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_MULTI_ADDR_BF_CALC_EXIT'
cast(' ' as abap_boolean preserving type) as BPTaxNmbrMultiAddrIsActive,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_MULTI_ADDR_BF_CALC_EXIT'
cast(' ' as abap_boolean preserving type) as BPIntlLocNmbrMultiAddrIsActive,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_MLTASEXIST_CALC_EXIT'
cast(' ' as abap_boolean preserving type) as IsMultipleAccountAssignment,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_ADRDEPD_EXISTS_CALC_EXIT'
cast(' ' as abap_boolean preserving type) as BPIsMltplAddrDepdntDataPresent,
BusinessPartner.BusinessPartnerIDByExtSystem,
BusinessPartner.IsMarkedForArchiving,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.InternationalLocationNoPart1,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.InternationalLocationNoPart2,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@EndUserText.label: 'Check Digit'
BusinessPartner.InternationalLocationNoPart3,
BusinessPartner.IndependentAddressID,
////////////// Start of Datacontroller 10+1 fields - Not to be consumed by any other views//////////
@UI.hidden:true
@Consumption.hidden:true
BusinessPartner.DataControllerSet,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController1,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController2,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController3,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController4,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController5,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController6,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController7,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController8,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController9,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController10,
////////////// End of Datacontroller 10+1 fields//////////
BusinessPartner.BPDataControllerIsNotRequired,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
@UI.fieldGroup: [
{value: '.PostingIsBlocked',qualifier: 'blockdata',groupLabel:'Customer Status',label:'Posting Block',importance: #HIGH},
{value: '.DeliveryIsBlocked',qualifier: 'blockdata',groupLabel:'Customer Status',label:'Delivery Block',importance: #HIGH},
{value: '.BillingIsBlockedForCustomer',qualifier: 'blockdata',groupLabel:'Customer Status',label:'Billing Block',importance: #HIGH}
]
_BusinessPartnerCustomer,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerAddress,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_PaymentCard,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerBank,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerTaxNumber,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerContact,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerCustomerCo,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerSalesArea,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerRole,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerCustRole,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
@UI.fieldGroup: [
{ value: '.PaymentIsBlockedForSupplier',qualifier: 'blockdata2',groupLabel:'Supplier Status',label:'Payment Block',position: 2,importance: #HIGH},
{ value: '.PurchasingIsBlocked',qualifier: 'blockdata2',groupLabel:'Supplier Status',label:'Central Purchasing Block',position: 3,importance: #HIGH},
{ value: '.PostingIsBlocked',qualifier: 'blockdata2',groupLabel:'Supplier Status',label:'Central Posting Block',position: 4,importance: #HIGH }
]
_BusinessPartnerSupplier,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerPurgOrg,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerSuplrRole,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPIdentificationNumbers,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPIndustry,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerUnloadingPoint,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPCustReceivingPoint,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPCustRcvgPtAddrDepdntInfo,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_CustomerDepartment,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPCustDepartmentAddrDepdnt,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerSupplierCo,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPSupplierTaxGrouping,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPCustomerTaxGrouping,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerCustomerTxt,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerLongText,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPCustAddressDependentInfo,
_AcademicTitleValueHelp,
@Consumption.hidden: true
_GenderValueHelp,
_AcademicTitleText,
@Consumption.filter.hidden: true
@UI.fieldGroup: [{value: '.StreetName',qualifier: 'stdaddress1',groupLabel:'Standard Address - 1',position: 1,label:'Street',importance: #HIGH},
{value: '.CustomerSupplierStreetName',qualifier: 'stdaddress1',groupLabel:'Standard Address - 1',position: 2,label:'Street',importance: #HIGH},
{value: '.HouseNumber',qualifier: 'stdaddress1',groupLabel:'Standard Address - 1',position: 3,label:'House Number',importance: #HIGH},
{value: '.PostalCode',qualifier: 'stdaddress1',groupLabel:'Standard Address - 1',position: 4,label:'Postal Code',importance: #HIGH},
{value: '.CityName',qualifier: 'stdaddress1',groupLabel:'Standard Address - 1',position: 5,label:'City',importance: #HIGH},
{value: '.CustomerSupplierCityName',qualifier: 'stdaddress1',groupLabel:'Standard Address - 1',position: 6,label:'City',importance: #HIGH}]
_BusinessPartnerAddrFilter,
_BPGroupingText,
_BPCatHelpText,
_LegalFormText,
_BPGenderText,
_BirthDateStatusTxt,
_AuthorizationGroupText,
_TradingPartnerValueHelp,
_BusinessPartnerCustomerVH,
_BusinessPartnerSupplierVH,
_BusinessPartnerCustSuplrVH,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MD_BP_ROOT_CALC_EXIT'
cast( '' as abap.sstring( 260 ) ) as BusinessPartnerImageURL,
/*@ObjectModel.readOnly: true
_BusinessPartnerAddrFilter.AddressLine1Text, //to display standard address in the header
@ObjectModel.readOnly: true
_BusinessPartnerAddrFilter.AddressLine2Text, //to display standard address in the header*/ //FormattedPostalAddress from adress view is used in header
/* @ObjectModel.readOnly: true
_BusinessPartnerAddrFilter.InternationalPhoneNumber,
@ObjectModel.readOnly: true
_BusinessPartnerAddrFilter.EmailAddress,
@ObjectModel.readOnly: true
_BusinessPartnerAddrFilter.FormattedPostalAddress,*/
@ObjectModel.readOnly: true
BPHasEmployeeRoles,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerSupplierTxt,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusPartRelationship,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPAddressIndependentPhone,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPAddressIndependentMobile,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPAddressIndependentEmail,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
//@feature: 'SW:ZNO_LIGHTWEIGHT_SWITCH'
_BPDataController,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPAdditionalSupplier,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPAdditionalCustomer,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPCustUnldgPtAddrDepdnt,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerTaxNumberAdr,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_CustAddrDepdntExtIdentifier,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BusinessPartnerAddrDepILN,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPEmplWorkplaceAddr,
_BusinessPartnerTypeText //2202 Classical BuPa Enhancements
}