C_BusPartRelationship

@AbapCatalog.sqlViewName: 'CBUPAREL2'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Consumption view for BUPA relationships'
@Metadata.allowExtensions: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #MASTER
}
@ObjectModel.type: #CONSUMPTION
@ObjectModel: {
    semanticKey: [ 'RelationshipNumber','BusinessPartner1', 'BusinessPartner2','ValidityEndDate'],
    createEnabled,
    updateEnabled,
    deleteEnabled,
    text.control: #ASSOCIATED_TEXT_UI_HIDDEN //texts will be shown together with the Code values. if the Code values are hidden, then texts wont be visible in UI.  no independent visibility for text fields

}
@VDM.viewType: #CONSUMPTION
@AbapCatalog.preserveKey:true 
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
define view C_BusPartRelationship as select from I_BusPartRelationshipTP_2 
association [1..1] to C_BusinessPartner         as _BusinessPartner         on  $projection.BusinessPartner1   = _BusinessPartner.BusinessPartner
association [0..1] to C_BPRelshpCompanyInterest as _BPRelshpCompanyInterest on  $projection.RelationshipNumber = _BPRelshpCompanyInterest.RelationshipNumber
                                                                            and $projection.BusinessPartner1   = _BPRelshpCompanyInterest.BusinessPartner1
                                                                            and $projection.BusinessPartner2   = _BPRelshpCompanyInterest.BusinessPartner2
                                                                            and $projection.ValidityEndDate    = _BPRelshpCompanyInterest.ValidityEndDate                                                                    
association [0..1] to I_BusPartRelshpCategoryVH as _BPRoleCategoryText      on $projection.RelationshipCategory = _BPRoleCategoryText.RelationshipCategory
                                                                            and $projection.BusPartRelshpIsRoleDefinition = _BPRoleCategoryText.BusPartRelshpIsRoleDefinition
                                                                            and $projection.BPRelshpCatIsInFwdDirection = _BPRoleCategoryText.BPRelshpCatIsInFwdDirection
                                      {
  key RelationshipNumber,
  key BusinessPartner1,
  key BusinessPartner2,
  key ValidityEndDate,
      @ObjectModel.text.element: ['BusPartRelshpCatDescription']
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: true
      RelationshipCategory,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      ValidityStartDate,
      RelationshipNumberForEdit,
      @ObjectModel.text.association: '_BusinessPartner1'
      BusinessPartner1ForEdit,
      @ObjectModel.text.association: '_BusinessPartner2'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: true
      BusinessPartner2ForEdit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: true
      ValidityEndDateForEdit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      IsStandardRelationship,
      BPRelationshipType,
      BusPartRelshpIsRoleDefinition,
      BPRelshpCatIsInFwdDirection,
      //Texts

      @ObjectModel.readOnly:true
      CreatedByUser,
      @ObjectModel.readOnly:true
      CreationDate,
      @ObjectModel.readOnly:true
      CreationTime,
      @ObjectModel.readOnly:true
      LastChangedByUser,
      @ObjectModel.readOnly:true
      LastChangeDate,
      @ObjectModel.readOnly:true
      LastChangeTime,      
      
      BPRelshpCoIntrstDataIsHidden,
      BPRelshpCntctPersnDataIsHidden,
      @ObjectModel.readOnly: true
      _BPRoleCategoryText.BusPartRelshpCatDescription,
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT]
      _BusinessPartner,
      @ObjectModel.association.type:[#TO_COMPOSITION_CHILD]
      _BPRelshpCompanyInterest,
      
      _BusinessPartner1,
      _BusinessPartner2,
      _BPRoleCategoryText
      
} where RelationshipCategory <> 'BUR001'