C_BPAdditionalCustomer

@AbapCatalog.sqlViewName: 'CBPADDCUST'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'C view for BP Additional Customers'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel: {
    semanticKey: [ 'BusinessPartner', 'Customer' ],
    createEnabled,
    updateEnabled,
    deleteEnabled
}
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Additional Customer',
  typeNamePlural: 'Additional Customers',
  title:  { label:'Additonal Customer', value: 'CustomerForEdit' }
}

@VDM.viewType: #CONSUMPTION

define view C_BPAdditionalCustomer
  as select from I_BPAdditionalCustomerTP as BPAdditionalCustomer

  association [1..1] to C_BusinessPartnerCustomer      as _BusinessPartnerCustomer   on  $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner

  association [1..1] to C_BusinessPartner              as _BusinessPartner           on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [1..*] to C_BPAddlCustCompanyCode        as _BPAddlCustCompanyCode     on  $projection.BusinessPartner = _BPAddlCustCompanyCode.BusinessPartner
                                                                                     and $projection.Customer        = _BPAddlCustCompanyCode.Customer

  association [1..*] to C_BPAddlCustSalesArea          as _BPAddlCustSalesArea       on  $projection.BusinessPartner = _BPAddlCustSalesArea.BusinessPartner
                                                                                     and $projection.Customer        = _BPAddlCustSalesArea.Customer

  association [0..1] to I_Supplier_VH                  as _SupplierValueHelp         on  $projection.Supplier = _SupplierValueHelp.Supplier

  association [0..1] to I_Customer_VH                  as _AlternativePayerValueHelp on  $projection.AlternativePayerAccount = _AlternativePayerValueHelp.Customer

  association [0..1] to C_BPAddressValueHelp           as _BPAddressValueHelp        on  $projection.BusinessPartner = _BPAddressValueHelp.BusinessPartner
                                                                                     and $projection.AddressNumber   = _BPAddressValueHelp.AddressNumber

  association [1..*] to C_BPAddlCustTelNmbr            as _BPAddlCustTelNmbr         on  $projection.BusinessPartner = _BPAddlCustTelNmbr.BusinessPartner
                                                                                     and $projection.Customer        = _BPAddlCustTelNmbr.Customer

  association [1..*] to C_BPAddlCustMblPhNumber        as _BPAddlCustMblPhNumber     on  $projection.BusinessPartner = _BPAddlCustMblPhNumber.BusinessPartner
                                                                                     and $projection.Customer        = _BPAddlCustMblPhNumber.Customer

  association [1..*] to C_BPAddlCustFaxNumber          as _BPAddlCustFaxNumber       on  $projection.BusinessPartner = _BPAddlCustFaxNumber.BusinessPartner
                                                                                     and $projection.Customer        = _BPAddlCustFaxNumber.Customer

  association [1..*] to C_BPAddlCustWebsiteURL         as _BPAddlCustWebsiteURL      on  $projection.BusinessPartner = _BPAddlCustWebsiteURL.BusinessPartner
                                                                                     and $projection.Customer        = _BPAddlCustWebsiteURL.Customer

  association [1..*] to C_BPAddlCustEmailAddress       as _BPAddlCustEmailAddress    on  $projection.BusinessPartner = _BPAddlCustEmailAddress.BusinessPartner
                                                                                     and $projection.Customer        = _BPAddlCustEmailAddress.Customer

  association [0..*] to I_BillingBlockReasonText       as _BillingBlockReasonText    on  $projection.BillingIsBlockedForCustomer = _BillingBlockReasonText.BillingBlockReason

  association [0..*] to I_DeliveryBlockReasonText      as _DeliveryBlockReasonText   on  $projection.DeliveryIsBlocked = _DeliveryBlockReasonText.DeliveryBlockReason

  association [1..*] to I_BusPartAuthorizationGroupTxt as _AuthorizationGroupText    on  $projection.AuthorizationGroup              = _AuthorizationGroupText.AuthorizationGroup
                                                                                     and _AuthorizationGroupText.AuthorizationObject = 'CUST'

  association [0..*] to I_DeliveryDateTypeRuleText     as _DeliveryDateTypeRuleText  on  $projection.DeliveryDateTypeRule = _DeliveryDateTypeRuleText.DeliveryDateTypeRule
  association [0..*] to C_CommMethTextVhTemp           as _CommMethText             on  $projection.PrfrdCommMediumType = _CommMethText.CommunicationMediumType
  association [0..*] to C_BPLanguageTextValueHelp      as _LanguageText             on  $projection.CorrespondenceLanguage = _LanguageText.LanguageCode
{

  key BPAdditionalCustomer.BusinessPartner,
  key BPAdditionalCustomer.Customer,
      BPAdditionalCustomer.BusinessPartnerForEdit,
      BPAdditionalCustomer.CustomerForEdit,
      BPAdditionalCustomer.BPAssignmentReasonID,
      BPAdditionalCustomer.CustomerAccountGroup,
      @ObjectModel: {
                      foreignKey.association: '_AlternativePayerValueHelp'
                    }
      @Consumption.valueHelp: '_AlternativePayerValueHelp'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BPAdditionalCustomer.AlternativePayerAccount,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BPAdditionalCustomer.DataMediumExchangeIndicator,
      @ObjectModel: {
                         foreignKey.association: '_SupplierValueHelp'
                       }
      @Consumption.valueHelp: '_SupplierValueHelp'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BPAdditionalCustomer.Supplier,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BPAdditionalCustomer.CustomerClassification,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BPAdditionalCustomer.VATLiability,
      BPAdditionalCustomer.PostingIsBlocked,
      @ObjectModel.text.association: '_DeliveryBlockReasonText'
      BPAdditionalCustomer.DeliveryIsBlocked,
      @ObjectModel.text.association: '_BillingBlockReasonText'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BPAdditionalCustomer.BillingIsBlockedForCustomer,
      BPAdditionalCustomer.OrderIsBlockedForCustomer,
      @ObjectModel.text.association: '_AuthorizationGroupText'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BPAdditionalCustomer.AuthorizationGroup,
      @ObjectModel.foreignKey.association: '_BPAddressValueHelp'
      BPAdditionalCustomer.AddressNumber,
      @ObjectModel.readOnly: true
      BPAdditionalCustomer.StreetName,
      @ObjectModel.readOnly: true
      BPAdditionalCustomer.HouseNumber,
      @ObjectModel.readOnly: true
      BPAdditionalCustomer.PostalCode,
      @ObjectModel.readOnly: true
      BPAdditionalCustomer.CityName,
      @ObjectModel.readOnly: true
      BPAdditionalCustomer.Country,
      @ObjectModel.readOnly: true
      BPAdditionalCustomer.Region,
      @ObjectModel.readOnly: true
      BPAdditionalCustomer.POBoxPostalCode,
      @ObjectModel.readOnly: true
      BPAdditionalCustomer.POBox,
      @ObjectModel.readOnly: true
      @ObjectModel.text.association: '_LanguageText'
      BPAdditionalCustomer.CorrespondenceLanguage,
      @ObjectModel.readOnly: true
      @ObjectModel.text.association: '_CommMethText'
      BPAdditionalCustomer.PrfrdCommMediumType,
      @ObjectModel.text.association: '_DeliveryDateTypeRuleText'
      BPAdditionalCustomer.DeliveryDateTypeRule,
      BPAdditionalCustomer.DeletionIndicator,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartnerCustomer,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartner,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD]
      _BPAddlCustCompanyCode,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD]
      _BPAddlCustSalesArea,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPAddlCustTelNmbr,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPAddlCustFaxNumber,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPAddlCustWebsiteURL,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPAddlCustMblPhNumber,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPAddlCustEmailAddress,

      _SupplierValueHelp,
      _AlternativePayerValueHelp,
      _BPAddressValueHelp,
      _BillingBlockReasonText,
      _DeliveryBlockReasonText,
      _AuthorizationGroupText,
      _DeliveryDateTypeRuleText,
      _CustomerClassification,
      _CommMethText,
      _CustomerClassificationText,
      _LanguageText
}