I_BUSPARTRELATIONSHIPTP_2

CDS View

BO View fot BUPA Relationship

I_BUSPARTRELATIONSHIPTP_2 is a CDS View in S/4HANA. BO View fot BUPA Relationship. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_BusPartRelationship view from CONSUMPTION Consumption view for BUPA relationships 
@AbapCatalog.sqlViewName: 'IBUPARELTP2'
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BO View fot BUPA Relationship'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #XXL,
  dataClass: #MASTER
}
@ObjectModel: {
    semanticKey: [ 'RelationshipNumber','BusinessPartner1', 'BusinessPartner2','ValidityEndDate'],
    createEnabled,
    updateEnabled,
    deleteEnabled
}

@ObjectModel.writeDraftPersistence: 'bupa_rel_d'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm : #SESSION_VARIABLE
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define view I_BusPartRelationshipTP_2 
  as select from I_BPRelationship_2
  association [1..1] to I_BusinessPartnerTP           as _BusinessPartner         on  $projection.BusinessPartner1     = _BusinessPartner.BusinessPartner
  association [0..1] to I_BPRelshpCompanyInterestTP_2 as _BPRelshpCompanyInterest on  $projection.RelationshipNumber   = _BPRelshpCompanyInterest.RelationshipNumber
                                                                                  and $projection.BusinessPartner1     = _BPRelshpCompanyInterest.BusinessPartner1
                                                                                  and $projection.BusinessPartner2     = _BPRelshpCompanyInterest.BusinessPartner2
                                                                                  and $projection.ValidityEndDate      = _BPRelshpCompanyInterest.ValidityEndDate
                                                                                                                                                                   
{
      //I_BPRelationship

  key RelationshipNumber,    
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
  key BusinessPartner1,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
  key BusinessPartner2,
  key    ValidityEndDate,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      RelationshipCategory, 
      ValidityStartDate,
      RelationshipNumber                     as RelationshipNumberForEdit,    
      BusinessPartner1                       as BusinessPartner1ForEdit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'      
      BusinessPartner2                       as BusinessPartner2ForEdit,
      ValidityEndDate                        as ValidityEndDateForEdit,
      IsStandardRelationship,
      BPRelationshipType,
      BusPartRelshpIsRoleDefinition,
      'X' as BPRelshpCatIsInFwdDirection,

      //Administrative Data

      CreatedByUser,
      CreationDate,
      CreationTime,
      LastChangedByUser,
      LastChangeDate,
      LastChangeTime,

      //Control fields

      cast(
        case
          when RelationshipCategory = 'BURC01'
            then ''
          else 'X'
        end as abap_boolean preserving type) as BPRelshpCoIntrstDataIsHidden,

      cast(
        case
          when RelationshipCategory = 'BUR001'
            then ''
          else 'X'
        end as abap_boolean preserving type) as BPRelshpCntctPersnDataIsHidden,

      /* Associations */
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _BusinessPartner,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPRelshpCompanyInterest,
       _BusinessPartner1,
       _BusinessPartner2
} where RelationshipCategory <> 'BUR001'

union all select from I_BPRelationship_2
association [1..1] to I_BusinessPartnerTP           as _BusinessPartner         on  $projection.BusinessPartner1 = _BusinessPartner.BusinessPartner
association [0..1] to I_BPRelshpCompanyInterestTP_2 as _BPRelshpCompanyInterest on  $projection.RelationshipNumber   = _BPRelshpCompanyInterest.RelationshipNumber 
                                                                                and $projection.BusinessPartner1     = _BPRelshpCompanyInterest.BusinessPartner1
                                                                                and $projection.BusinessPartner2     = _BPRelshpCompanyInterest.BusinessPartner2
                                                                                and $projection.ValidityEndDate      = _BPRelshpCompanyInterest.ValidityEndDate
                                                                                                                                                               
{//I_BPRelationship

  key RelationshipNumber,    
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
key  BusinessPartner2 as BusinessPartner1,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
  key  BusinessPartner1 as BusinessPartner2,
  key    ValidityEndDate,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      RelationshipCategory, 
      ValidityStartDate,
      RelationshipNumber                     as RelationshipNumberForEdit,    
      BusinessPartner2                       as BusinessPartner1ForEdit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'      
      BusinessPartner1                       as BusinessPartner2ForEdit,
      ValidityEndDate                        as ValidityEndDateForEdit,
      IsStandardRelationship,
      BPRelationshipType,
      BusPartRelshpIsRoleDefinition,
      cast(' ' as abap_boolean)              as BPRelshpCatIsInFwdDirection,

      //Administrative Data

      CreatedByUser,
      CreationDate,
      CreationTime,
      LastChangedByUser,
      LastChangeDate,
      LastChangeTime,

      //Control fields

      cast(
        case
          when RelationshipCategory = 'BURC01'
            then ''
          else 'X'
        end as abap_boolean preserving type) as BPRelshpCoIntrstDataIsHidden,

      cast(
        case
          when RelationshipCategory = 'BUR001'
            then ''
          else 'X'
        end as abap_boolean preserving type) as BPRelshpCntctPersnDataIsHidden,

      /* Associations */
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _BusinessPartner,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPRelshpCompanyInterest,       
       _BusinessPartner2 as _BusinessPartner1,
       _BusinessPartner1 as _BusinessPartner2
} where RelationshipCategory <> 'BUR001'

Learn More