I_MfgOrderOperationCompWithSts

@AbapCatalog.sqlViewName: 'IMFGORDOPCOMPWST'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_MRPController', '_ProductionSupervisor', '_LongText']
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order Component with Header Status'
// Mfg Order Operation Component view with additional header system status


define view I_MfgOrderOperationCompWithSts
  as select from           I_MfgOrderOperationComponent as comp
    inner join             I_OrderOperationBasic        as OrderOperationBasic on  OrderOperationBasic.OrderInternalID          = comp.OrderInternalBillOfOperations
                                                                               and OrderOperationBasic.OrderOperationInternalID = comp.OrderIntBillOfOperationsItem
    left outer to one join I_StatusObjectStatusBasic    as _isReleased         on  _isReleased.StatusObject     = comp.OrderObjectInternalID
                                                                               and _isReleased.StatusCode       = 'I0002'
                                                                               and _isReleased.StatusIsInactive = ''
    left outer to one join I_StatusObjectStatusBasic    as _isConfirmed        on  _isConfirmed.StatusObject     = comp.OrderObjectInternalID
                                                                               and _isConfirmed.StatusCode       = 'I0009'
                                                                               and _isConfirmed.StatusIsInactive = ''
    left outer to one join I_StatusObjectStatusBasic    as _isDeleted          on  _isDeleted.StatusObject     = comp.OrderObjectInternalID
                                                                               and _isDeleted.StatusCode       = 'I0013'
                                                                               and _isDeleted.StatusIsInactive = ''
    left outer to one join I_StatusObjectStatusBasic    as _isTechCompl        on  _isTechCompl.StatusObject     = comp.OrderObjectInternalID
                                                                               and _isTechCompl.StatusCode       = 'I0045'
                                                                               and _isTechCompl.StatusIsInactive = ''
    left outer to one join I_StatusObjectStatusBasic    as _isClosed           on  _isClosed.StatusObject     = comp.OrderObjectInternalID
                                                                               and _isClosed.StatusCode       = 'I0046'
                                                                               and _isClosed.StatusIsInactive = ''
    left outer to one join I_StatusObjectStatusBasic    as _isMarkedDel        on  _isMarkedDel.StatusObject     = comp.OrderObjectInternalID
                                                                               and _isMarkedDel.StatusCode       = 'I0076'
                                                                               and _isMarkedDel.StatusIsInactive = ''

  association [1..1] to I_MfgOrderOperationBySemKey as _MfgOrderOperationBySemKey on  $projection.ManufacturingOrder            = _MfgOrderOperationBySemKey.ManufacturingOrder
                                                                                  and $projection.ManufacturingOrderSequence    = _MfgOrderOperationBySemKey.ManufacturingOrderSequence
                                                                                  and $projection.ManufacturingOrderOperation_2 = _MfgOrderOperationBySemKey.ManufacturingOrderOperation
  association [0..1] to I_MRPController             as _MRPController             on  $projection.Plant         = _MRPController.Plant
                                                                                  and $projection.MRPController = _MRPController.MRPController
  association [0..1] to I_MaterialPlant             as _MaterialPlant             on  $projection.Plant    = _MaterialPlant.Plant
                                                                                  and $projection.Material = _MaterialPlant.Material
  association [0..1] to I_WBSElementBasicData       as _WBSElementBasic           on  $projection.WBSElementInternalID = _WBSElementBasic.WBSElementInternalID
{
      // Key

      @ObjectModel.foreignKey.association: '_Reservation'
  key comp.Reservation,
      @ObjectModel.text.element: ['BOMItemDescription']
  key comp.ReservationItem,
      @ObjectModel.foreignKey.association: '_ReservationDocRecordType'
  key comp.RecordType,

      // Order and operation data

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      comp.ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      comp.ManufacturingOrderType,
      @ObjectModel.foreignKey.association: '_MfgOrder'
      comp.ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      comp.ManufacturingOrderSequence,
      comp.OrderInternalBillOfOperations,
      comp.OrderIntBillOfOperationsItem,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ManufacturingOrderOperation_2'
      OrderOperationBasic.Operation                                               as ManufacturingOrderOperation,
      OrderOperationBasic.Operation_2                                             as ManufacturingOrderOperation_2, // no conv. exit

      OrderOperationBasic.OperationText,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      comp.ProductionPlant,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      comp.ProductionSupervisor,

      //Order Header Status

      @Semantics.booleanIndicator
      case when _isReleased.StatusCode     is null then '' else 'X' end           as OrderIsReleased,
      @Semantics.booleanIndicator
      case when _isConfirmed.StatusCode    is null then '' else 'X' end           as OrderIsConfirmed,
      @Semantics.booleanIndicator
      case when _isDeleted.StatusCode      is null then '' else 'X' end           as OrderIsDeleted,
      @Semantics.booleanIndicator
      case when _isTechCompl.StatusCode    is null then '' else 'X' end           as OrderIsTechnicallyCompleted,
      @Semantics.booleanIndicator
      case when _isClosed.StatusCode       is null then '' else 'X' end           as OrderIsClosed,
      @Semantics.booleanIndicator
      case when _isMarkedDel.StatusCode    is null then '' else 'X' end           as OrderIsMarkedForDeletion,

      // Date and Time

      @Semantics.businessDate.at: true
      comp.MatlCompRequirementDate,
      comp.MatlCompRequirementTime,

      // Attributes

      comp.BillOfMaterialItemNumber_2                                             as BillOfMaterialItemNumber,
      comp.ReservationIsFinallyIssued,
      @Semantics.booleanIndicator
      comp.MatlCompIsMarkedForDeletion,
      comp.MaterialComponentIsMissing,
      comp.IsBulkMaterialComponent,
      comp.MatlCompIsMarkedForBackflush,
      comp.MatlCompIsTextItem,
      comp.MaterialComponentIsPhantomItem,
      comp.MaterialCompIsVariableSized,
      comp.MatlCompIsConfigurable,
      comp.MaterialCompIsIntraMaterial,
      comp.MatlCompDiscontinuationType,
      comp.MatlCompIsFollowUpMaterial,

      // Long Text

      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      comp.LongTextLanguageCode,
      comp.LongTextExists,

      // Assignments

      @ObjectModel.foreignKey.association: '_RequirementType'
      comp.RequirementType,
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      comp.MaterialGroup,
      @ObjectModel.foreignKey.association: '_Material'
      comp.Material,
      @ObjectModel.foreignKey.association: '_Plant'
      comp.Plant,
      @ObjectModel.foreignKey.association: '_MRPController'
      cast(_MaterialPlant.MRPController as pph_dispo preserving type)             as MRPController,
      @ObjectModel.foreignKey.association: '_SalesOrder'
      comp.SalesOrder,
      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      comp.SalesOrderItem,
      @ObjectModel.foreignKey.association: '_WBSElementBasic'
      comp.WBSElementInternalID_2                                                 as WBSElementInternalID,
      comp.Assembly,

      // Assignments BOM

      comp.BillOfMaterialCategory,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'BillOfMaterialInternalID'
      cast(comp.BillOfMaterialInternalID as mpe_exec_stnum preserving type)       as BillOfMaterial,
      comp.BillOfMaterialInternalID_2                                             as BillOfMaterialInternalID,
      comp.BOMItemInternalChangeCount                                             as BOMItemInternalChangeCount,
      @ObjectModel.text.element: ['BOMItemDescription']
      comp.BOMItem                                                                as BillOfMaterialItemNodeNumber,
      @ObjectModel.foreignKey.association: '_BOMItemCategory'
      comp.BOMItemCategory                                                        as BillOfMaterialItemCategory,
      @Semantics.text: true
      comp.BOMItemDescription,
      @ObjectModel.foreignKey.association: '_BOMExplosion'
      comp.BOMExplosionDateID,

      // Goods Movement data

      comp.GoodsMovementIsAllowed,
      @ObjectModel.foreignKey.association: '_StorageLocation'
      comp.StorageLocation,
      comp.Batch,
      @ObjectModel.foreignKey.association: '_DebitCreditCode'
      comp.DebitCreditCode,
      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      comp.GoodsMovementType,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
      comp.InventorySpecialStockType,
      @ObjectModel.foreignKey.association: '_SupplyArea'
      comp.SupplyArea,
      comp.StockSegment,
      comp.RequirementSegment,

      // Assignments FI/CO

      @ObjectModel.foreignKey.association: '_BusinessArea'
      comp.BusinessArea,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      comp.CompanyCode,

      // Batch split data

      @ObjectModel.foreignKey.association: '_BatchSplitType'
      comp.BatchSplitType,
      comp.BatchMasterReservationItem,

      // Quantities and UoM

      comp.QuantityIsFixed,
      comp.IsNetScrap,
      @Aggregation.default: #MAX
      comp.ComponentScrapInPercent,
      @Aggregation.default: #MAX
      comp.OperationScrapInPercent,
      @Semantics.unitOfMeasure: true
      comp.BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      cast(comp.RequiredQuantity as requirementquantity preserving type)          as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      comp.WithdrawnQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      (comp.RequiredQuantity - comp.WithdrawnQuantity)                            as OpenQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      cast((comp.WithdrawnQuantity - comp.RequiredQuantity) as deviationquantity) as DeviationQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      comp.ConfirmedAvailableQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      comp.MaterialCompOriginalQuantity,

      // Alternative item data

      comp.MaterialCompIsAlternativeItem,
      comp.AlternativeItemGroup,
      comp.AlternativeMstrReservationItem,
      comp.OriginalReservation,
      comp.OriginalReservationItem,

      @Semantics.unitOfMeasure: true
      comp.EntryUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      @Aggregation.default: #SUM
      comp.GoodsMovementEntryQty,

      comp.EffectivityParameterVariant,

      comp.BillOfMaterialVariant,
      comp.BillOfMaterialVersion,
      comp.InheritedBOMItemNode,

      // Associations

      comp._Reservation,
      comp._ReservationItem,
      comp._ReservationDocRecordType,
      comp._ManufacturingOrder,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ManufacturingOrder'
      comp._MfgOrder,
      comp._MfgOrderSequence,
      _MfgOrderOperationBySemKey                                                  as _MfgOrderOperation,
      comp._MfgOrderComponentLongText,
      comp._MfgOrderCategory,
      comp._MfgOrderType,
      comp._ProductionPlant,
      comp._ProductionSupervisor,
      comp._RequirementType,
      comp._MaterialGroup,
      comp._Material,
      _MaterialPlant,
      comp._Plant,
      _MRPController,
      comp._StorageLocation,
      comp._Batch,
      comp._BatchSplitType,
      comp._DebitCreditCode,
      comp._GoodsMovementType,
      comp._InventorySpecialStockType,
      comp._SupplyArea,
      comp._BOMExplosion,
      comp._BOMItemCategory,
      comp._SalesOrder,
      comp._SalesOrderItem,
      _WBSElementBasic,
      comp._CompanyCode,
      comp._BusinessArea,
      comp._BaseUnit,
      comp._EntryUnit,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_MfgOrderComponentLongText'
      comp._LongText,
      comp._LongTextLanguage
};