I_JOURNALENTRY

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog: {
  sqlViewName: 'IFIJOURNALENT',
  preserveKey:true 
  }
@EndUserText.label: 'Journal Entry'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'AccountingDocument'
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@Analytics: { 
      dataCategory: #DIMENSION, 
      dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
          mapping: 
            [
              { 
                table: 'BKPF',
                role: #MAIN,
                viewElement: ['CompanyCode', 'FiscalYear', 'AccountingDocument'],
                tableElement: ['bukrs', 'gjahr', 'belnr']
              }
            ] 
         }
      }
    }
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true 
@Metadata.allowExtensions:true
//--[ GENERATED:012:29JlHNUf7jY4ip7HtmZN9m

@AccessControl.privilegedAssociations: ['_AccountingDocumentTypeText','_BusinessTransactionTypeText','_FinancialManagementAreaText','_LedgerText']
// ]--GENERATED


@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #EXTRACTION_DATA_SOURCE,
                                     #SQL_DATA_SOURCE]
@ObjectModel.sapObjectNodeType.name: 'JournalEntry'                                     
                                     
define view I_JournalEntry as select from P_BKPF_COM

/* *************************************************************
 *  association zur ID
 * *************************************************************
*/ 
 

  //--[ GENERATED:012:29JlHNUf7jY4ip7HtmZN9m

  association [0..*] to I_AccountingDocumentTypeText      as _AccountingDocumentTypeText on   $projection.AccountingDocumentType = _AccountingDocumentTypeText.AccountingDocumentType
  association [0..*] to I_BusTransactionTypeText      as _BusinessTransactionTypeText on   $projection.BusinessTransactionType = _BusinessTransactionTypeText.BusinessTransactionType
  association [0..*] to I_FinancialManagementAreaText      as _FinancialManagementAreaText on   $projection.FinancialManagementArea = _FinancialManagementAreaText.FinancialManagementArea
  association [0..*] to I_LedgerText      as _LedgerText on   $projection.Ledger = _LedgerText.Ledger
  // ]--GENERATED

  association [0..1] to I_CompanyCode                  as _CompanyCode                  on $projection.CompanyCode                     = _CompanyCode.CompanyCode
association [0..1] to I_FiscalYearForCompanyCode     as _FiscalYear                   on $projection.FiscalYear                      = _FiscalYear.FiscalYear
                                                                                     and $projection.CompanyCode                     = _FiscalYear.CompanyCode  
association [0..1] to I_AccountingDocumentType       as _AccountingDocumentType       on $projection.AccountingDocumentType          = _AccountingDocumentType.AccountingDocumentType
association [1..1] to I_Currency                     as _CompanyCodeCurrency          on $projection.CompanyCodeCurrency             = _CompanyCodeCurrency.Currency 
association [0..1] to I_Currency                     as _TransactionCurrency          on  $projection.TransactionCurrency            = _TransactionCurrency.Currency
association [0..1] to I_Currency                 as _AdditionalCurrency1      on $projection.AdditionalCurrency1      = _AdditionalCurrency1.Currency 
association [0..1] to I_Currency                 as _AdditionalCurrency2      on $projection.AdditionalCurrency2      = _AdditionalCurrency2.Currency
association [0..1] to I_FiscalYearPeriodForCmpnyCode as _FiscalPeriod                 on $projection.FiscalYear                      = _FiscalPeriod.FiscalYear
                                                                                     and $projection.FiscalPeriod                    = _FiscalPeriod.FiscalPeriod
                                                                                     and $projection.CompanyCode                     = _FiscalPeriod.CompanyCode  
association [0..1] to I_AccountingDocumentCategory   as _AccountingDocumentCategory   on $projection.AccountingDocumentCategory      = _AccountingDocumentCategory.AccountingDocumentCategory
association [0..1] to I_BusinessTransactionType      as _BusinessTransactionType      on $projection.BusinessTransactionType         = _BusinessTransactionType.BusinessTransactionType
association [0..1] to I_FinancialManagementArea      as _FinancialManagementArea      on $projection.FinancialManagementArea         = _FinancialManagementArea.FinancialManagementArea                                                                                                                                                                                                                                                            
association [0..1] to I_ReferenceDocumentType        as _ReferenceDocumentType        on $projection.ReferenceDocumentType           = _ReferenceDocumentType.ReferenceDocumentType
association [0..1] to I_LogicalSystem                as _LogicalSystem                on $projection.LogicalSystem                   = _LogicalSystem.LogicalSystem  
association [0..1] to I_LogicalSystem                as _RefDocumentLogicalSystem     on $projection.ReferenceDocumentLogicalSystem  = _RefDocumentLogicalSystem.LogicalSystem
association [0..1] to I_User                         as _User                         on  $projection.AccountingDocCreatedByUser     = _User.UserID                                                                                                                                                                                                                                                          
association [1..1] to I_Ledger                       as _Ledger                       on $projection.Ledger                          = _Ledger.Ledger
association [0..1] to I_LedgerGroup                  as _LedgerGroup                  on  $projection.LedgerGroup                    = _LedgerGroup.LedgerGroup
association [0..1] to I_CurrencyRole                 as _AdditionalCurrency1Role      on  $projection.AdditionalCurrency1Role        = _AdditionalCurrency1Role.CurrencyRole
association [0..1] to I_CurrencyRole                 as _AdditionalCurrency2Role      on  $projection.AdditionalCurrency2Role        = _AdditionalCurrency2Role.CurrencyRole
  
association [1..*] to I_JournalEntryItem             as _JournalEntryItem             on $projection.CompanyCode                = _JournalEntryItem.CompanyCode
                                                                                     and $projection.FiscalYear                 = _JournalEntryItem.FiscalYear
                                                                                     and $projection.AccountingDocument         = _JournalEntryItem.AccountingDocument
                                                                                     
association [0..*] to I_OperationalAcctgDocItem      as _OperationalAcctgDocItem      on $projection.CompanyCode                = _OperationalAcctgDocItem.CompanyCode
                                                                                     and $projection.FiscalYear                 = _OperationalAcctgDocItem.FiscalYear
                                                                                     and $projection.AccountingDocument         = _OperationalAcctgDocItem.AccountingDocument
                                                                                     
association [0..*] to I_AddlLedgerOplAcctgDocItem    as _AddlLedgerOplAcctgDocItem    on $projection.CompanyCode                = _AddlLedgerOplAcctgDocItem.CompanyCode
                                                                                     and $projection.FiscalYear                 = _AddlLedgerOplAcctgDocItem.FiscalYear
                                                                                     and $projection.AccountingDocument         = _AddlLedgerOplAcctgDocItem.AccountingDocument                                                                                                                                                                          
                                                                                         
{
    
      //--[ GENERATED:012:29JlHNUf7jY4ip7HtmZN9m

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_CompanyCode'
key bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_FiscalYear'
key gjahr as FiscalYear,
key belnr as AccountingDocument,

      //--[ GENERATED:012:29JlHNUf7jY4ip7HtmZN9m

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_AccountingDocumentTypeStdVH',
                     element: 'AccountingDocumentType' }
        }]
      @ObjectModel.text.association: '_AccountingDocumentTypeText'
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_AccountingDocumentType'
blart as AccountingDocumentType, 
bldat as DocumentDate,
budat as PostingDate,
@ObjectModel.foreignKey.association: '_FiscalPeriod'
cast( monat as fins_fiscalperiod ) as FiscalPeriod,
cpudt as AccountingDocumentCreationDate,
cputm as CreationTime,
cast ( aedat as fis_lastmanualchangedate preserving type )    as LastManualChangeDate,
cast ( upddt as fis_lastautomaticchangedate preserving type ) as LastAutomaticChangeDate,
case 
  when ( upddt is not initial  and upddt > aedat ) then upddt  
  when aedat is not initial then cast ( aedat as ttet_dt_chg_date preserving type )
  else cast ( cpudt as ttet_dt_chg_date preserving type )
end as LastChangeDate,
wwert as ExchangeRateDate,
usnam as AccountingDocCreatedByUser,
tcode as TransactionCode,
bvorg as IntercompanyTransaction,
xblnr as DocumentReferenceID,
dbblg as RecurringAccountingDocument,
stblg as ReverseDocument,
stjah as ReverseDocumentFiscalYear,
bktxt as AccountingDocumentHeaderText,

@ObjectModel.foreignKey.association: '_TransactionCurrency'
@Semantics.currencyCode:true
waers as TransactionCurrency,
//@Aggregation.default: #NOP


cast(abs(kursf) as fis_absolute_exchangerate preserving type) as AbsoluteExchangeRate,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'AbsoluteExchangeRate'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'AbsoluteExchangeRate'
kursf as ExchangeRate,
@Semantics.booleanIndicator:true
cast(case when kursf < 0 then 'X' 
          when kursf > 0 then ' ' end as fis_indirect_quotation preserving type) as ExchRateIsIndirectQuotation,
cast(case when kursf < 0 then division(1,abs(kursf),5) 
          when kursf > 0 then kursf end as fis_effective_exchangerate) as EffectiveExchangeRate,

//@Semantics.currencyCode:true

//kzwrs as GroupCurrency,

//kzkrs as GroupCurrencyExchangeRate,


@ObjectModel.foreignKey.association: '_AccountingDocumentCategory'
bstat as AccountingDocumentCategory,
xnetb as NetAmountIsPosted,
//frath,

xrueb as JrnlEntryIsPostedToPrevPeriod,
      //--[ GENERATED:012:29JlHNUf7jY4ip7HtmZN9m

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_BusTransTypeStdVH',
                     element: 'BusinessTransactionType' }
        }]
      @ObjectModel.text.association: '_BusinessTransactionTypeText'
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_BusinessTransactionType'
glvor as BusinessTransactionType,
grpid as BatchInputSession,
//dokid,

//arcid,

//iblar,

@ObjectModel.foreignKey.association: '_ReferenceDocumentType'
awtyp as ReferenceDocumentType,
awkey as OriginalReferenceDocument,
      //--[ GENERATED:012:29JlHNUf7jY4ip7HtmZN9m

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_FinMgmtAreaStdVH',
                     element: 'FinancialManagementArea' }
        }]
      @ObjectModel.text.association: '_FinancialManagementAreaText'
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_FinancialManagementArea'
fikrs as FinancialManagementArea,

@ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
@Semantics.currencyCode:true
hwaer as CompanyCodeCurrency,
@Semantics.currencyCode:true
hwae2 as AdditionalCurrency1,
@Semantics.currencyCode:true
hwae3 as AdditionalCurrency2,

//kurs2 as AdditionalCrcy1ExchangeRate,

//kurs3 as AdditionalCrcy2ExchangeRate,


//basw2,

//basw3,

//umrd2,

//umrd3,

//@Semantics.booleanIndicator 

xstov as ReversalIsPlanned,
stodt as PlannedReversalDate,
//@Semantics.booleanIndicator 

xmwst as TaxIsCalculatedAutomatically,

@Analytics.internalName: #LOCAL
curt2 as AdditionalCurrency1Role,
@Analytics.internalName: #LOCAL
curt3 as AdditionalCurrency2Role,
//kuty2 as AddtionalCrcy1ExchangeRateType,

//kuty3 as AddtionalCrcy2ExchangeRateType,

//@Semantics.booleanIndicator 

xsnet as TaxBaseAmountIsNetAmount,
ausbk as SourceCompanyCode,
//xusvr,

//duefl,

@ObjectModel.foreignKey.association: '_LogicalSystem'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'ReferenceDocumentLogicalSystem'
awsys as LogicalSystem,
@ObjectModel.foreignKey.association: '_RefDocumentLogicalSystem'
@Analytics.internalName: #LOCAL
cast(awsys as fis_awsys preserving type) as ReferenceDocumentLogicalSystem,
//@Aggregation.default: #NOP


cast(abs(txkrs) as fis_absolute_txkrs_bkpf preserving type) as TaxAbsoluteExchangeRate,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'TaxAbsoluteExchangeRate'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'TaxAbsoluteExchangeRate'
txkrs as TaxExchangeRate,
@Semantics.booleanIndicator:true
cast(case when txkrs < 0 then 'X' 
          when txkrs > 0 then ' ' end as fis_tax_indirect_quotation preserving type) as TaxExchRateIsIndirectQuotation,
cast(case when txkrs < 0 then division(1,abs(txkrs),5) 
          when txkrs > 0 then txkrs end as fis_tax_effective_exchangerate) as TaxEffectiveExchangeRate,
          
cast(abs(ctxkrs) as ctrycrcytxabsoluteexchangerate preserving type) as CtryCrcyTxAbsoluteExchangeRate,

cast(case when ctxkrs < 0 then division(1,abs(ctxkrs),5) 
          when ctxkrs > 0 then ctxkrs end as ctrycrcytaxeffctvexchangerate) as CtryCrcyTaxEffctvExchangeRate,          

//lotkz,

//xwvof,

stgrd as ReversalReason,
cast(ppnam as fis_ppnam preserving type ) as ParkedByUser,
ppdat as ParkingDate,
pptme as ParkingTime,
brnch as Branch,
numpg as NmbrOfPages,
//@Semantics.booleanIndicator 

adisc as IsDiscountDocument,
xref1_hd as Reference1InDocumentHeader,
xref2_hd as Reference2InDocumentHeader,
reindat as InvoiceReceiptDate,
      //--[ GENERATED:012:29JlHNUf7jY4ip7HtmZN9m

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_LedgerStdVH',
                     element: 'Ledger' }
        }]
      @ObjectModel.text.association: '_LedgerText'
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_Ledger'      
rldnr as Ledger,
ldgrp as LedgerGroup,
//propmano,

cast(xblnr_alt as fis_xblnr_alt_alpha preserving type ) as AlternativeReferenceDocument,
vatdate as TaxReportingDate,
fulfilldate as TaxFulfillmentDate,
doccat as AccountingDocumentClass,
//xsplit,

//cash_alloc,

//follow_on,

//xreorg,

//subset,

kurst as ExchangeRateType,
cast(abs(kursx) as marketdataabsoluteexchangerate preserving type) as MarketDataAbsoluteExchangeRate,

cast(case when kursx < 0 then division(1,abs(kursx),5) 
          when kursx > 0 then kursx end as mktdataeffectiveexchangerate) as MktDataEffectiveExchangeRate,
//kur2x,

//kur3x,

//xmca,

//resubmission,

logsystem_sender as SenderLogicalSystem,
bukrs_sender as SenderCompanyCode,
belnr_sender as SenderAccountingDocument,
gjahr_sender as SenderFiscalYear,
aworg_rev as ReversalReferenceDocumentCntxt,
awref_rev as ReversalReferenceDocument,
//ccins,

//ccnum,

penrc as LatePaymentReason,
knumv as SalesDocumentCondition,
//@Semantics.booleanIndicator 

xreversing as IsReversal,
//@Semantics.booleanIndicator 

xreversed as IsReversed,
glbtgrp as GLBusinessTransactionGroup,
@Analytics.internalName: #LOCAL
co_valdt as CostAccountingValuationDate, 

TAX_COUNTRY_HD as TaxCountry,
last_change_datetime as JournalEntryLastChangeDateTime,

P_BKPF_COM.reprocessing_status_code as JournalEntryReprocessingStatus,

// .INCLUDE FAC_BKPF_EXT_GLO  STRU  0 0 Document Header: Extension include for globalisation

glo_ref1_hd as JrnlEntryCntrySpecificRef1,
glo_dat1_hd as JrnlEntryCntrySpecificDate1,
glo_ref2_hd as JrnlEntryCntrySpecificRef2,
glo_dat2_hd as JrnlEntryCntrySpecificDate2,
glo_ref3_hd as JrnlEntryCntrySpecificRef3,
glo_dat3_hd as JrnlEntryCntrySpecificDate3,
glo_ref4_hd as JrnlEntryCntrySpecificRef4,
glo_dat4_hd as JrnlEntryCntrySpecificDate4,
glo_ref5_hd as JrnlEntryCntrySpecificRef5,
glo_dat5_hd as JrnlEntryCntrySpecificDate5,
glo_bp1_hd as JrnlEntryCntrySpecificBP1,
glo_bp2_hd as JrnlEntryCntrySpecificBP2,

whtdate as WithholdingTaxReportingDate,

_CompanyCode,
_FiscalYear,
_AccountingDocumentType,
_CompanyCodeCurrency,
_TransactionCurrency,
_AdditionalCurrency1,
_AdditionalCurrency2,
_FiscalPeriod,
_AccountingDocumentCategory,
_BusinessTransactionType,
_FinancialManagementArea,
_ReferenceDocumentType,
_User,
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: '_RefDocumentLogicalSystem'
_LogicalSystem,
_RefDocumentLogicalSystem,
_Ledger,
_LedgerGroup,
_AdditionalCurrency1Role,
_AdditionalCurrency2Role,

_JournalEntryItem,
_OperationalAcctgDocItem,
_AddlLedgerOplAcctgDocItem,

                                                                                   
      //--[ GENERATED:012:29JlHNUf7jY4ip7HtmZN9m

      @Consumption.hidden: true
      _AccountingDocumentTypeText,
      @Consumption.hidden: true
      _BusinessTransactionTypeText,
      @Consumption.hidden: true
      _FinancialManagementAreaText,
      @Consumption.hidden: true
      _LedgerText
      // ]--GENERATED


}